REKENING ;REKENINGEN [ 12/17/2001   4:35 PM ]
 d ^cA604
 s r=$$SELECT(0,"","Test : ")
 W !,r," ",$G(^KR1(r)),@F2,!
 q
 ;
SELECT(IsBoekR,DefREK,Titel) 
 New X,Y,Tekst,REKNr,Rek,TRek,TRekN
 Set IsBoekR=$G(IsBoekR)
 Set:'$L($G(DefREK)) DefREK=$G(sRef("REK"))
 If $L(DefREK),'$D(^KAR(DefREK_" ")) Set DefREK=""
 If DefREK,'$$CHECK(DefREK,IsBoekR) Set DefREK=""
 If '$L($G(Titel)) Set Titel="Rekening : "
 Do ADD^vhScherm(21,24)
 Set REKNr=""
SEL2 
 #define LegeLijn "&S"
 New OrderInstellingenService,VoorkeuzeRekeningen,ItemNr
 Set OrderInstellingenService = ##class(APPS.OV.impl.OrderInstellingenService).%New()
 #dim VoorkeuzeRekeningen As %ListOfObjects = OrderInstellingenService.GeefVoorkeuzeBoekhoudkundigeRekeningen()
 Set VoorkeuzeRekeningenIt = ##class(TECH.ListIterator).%New(VoorkeuzeRekeningen)
 Set VoorkeuzeRekeningPopup = ""
 #dim ItemNr As %Integer = 0
 Set VoorkeuzeRekeningPopup($increment(ItemNr)) = "Opnieuw`Selecteer een rekening of kies Andere."
 Set VoorkeuzeRekeningPopup($increment(ItemNr)) = $$$LegeLijn
 While VoorkeuzeRekeningenIt.HasNext()
 {
	#dim VoorkeuzeRekening As APPS.OV.impl.data.VoorkeuzeBoekhoudkundigeRekening = VoorkeuzeRekeningenIt.Next()
	Set VoorkeuzeRekeningPopup($increment(ItemNr)) = VoorkeuzeRekening.Nummer_"`"_VoorkeuzeRekening.Nummer_ " "_VoorkeuzeRekening.Naam
 }
 Set VoorkeuzeRekeningPopup($increment(ItemNr)) = $$$LegeLijn
 Set VoorkeuzeRekeningPopup($increment(ItemNr)) = "Andere`Andere ..." 
 
 Set Rek=$$WILD^vhPOPUP("C;C","O1-","Voorkeuze boehoudkundige rekening",.VoorkeuzeRekeningPopup)
 If Rek = "Opnieuw" Goto SEL2
 If Rek = "Andere" {
	 Set Rek=$$ASK^vhINP(Titel,20,DefREK,"Ingave rekening dmv. naam of nummer")
 }
 Quit:Rek="-"!(Rek=".") Rek
 Set Rek=$$UPTRIMAN^vhRtn1(Rek)
 If Rek=""!zb Do LIST("") Goto SEL2:'REKNr,EXIT
 If Rek?.N,$D(^KAR(Rek_" ")) Set REKNr=Rek Goto SEL2:'$$CHECK(Rek,IsBoekR),EXIT
 Set TRek=$O(^KR1(Rek))
 If $E(TRek,1,$L(Rek))'=Rek Goto SEL2
 If $E($O(^KR1(TRek)),1,$L(Rek))'=Rek Set REKNr=$P(TRek," ",2) Goto SEL2:'$$CHECK(REKNr,IsBoekR),EXIT
 Do LIST(Rek)
 Goto SEL2:'REKNr,EXIT
EXIT Quit REKNr
 
CHECK(REKNr,IsBoekR) 
 Quit:'IsBoekR 1
 Quit '$L($P(^KAR(REKNr_" ",0),D,13))
 
LIST(Kode) 
 New Y,X
 Set TRek=Rek
 If '$L(Rek)  Set Rek="ZZZZZ"
 Set Y="5\\Selecteer een rekening\\MORE^REKENING\REKENING\K"
 X "Set Y(0)=$$"_$P(Y,"\",5)_"(0,3)"
 Quit:'Y(0)
 Do ^POP
 Set:X REKNr=+^KAR($P(Y(X)," ",2)_" ",0)
 Quit
MORE(Max,Len,Ref) 
 If Max>200 w *7 Quit Max
 Set Count=0
 If Max,TRek="" Quit Max
 For  Set TRek=$O(^KR1(TRek)) Quit:TRek=""!($E(TRek,1,$L(Rek))'=Rek)  Set TRekN=$P(TRek," ",2) Set:$S('IsBoekR:1,1:'$L($P(^KAR(TRekN_" ",0),D,13))) Count=Count+1,Y(Max+Count)=TRek Quit:Count>Len
 Set:$E(TRek,1,$L(Rek))'=Rek TRek=""
 Quit Max+Count
 ;
COMPRES(RekNm,REKNr) 
 New I,Out
 Set Out="" For I=1:1:$L(RekNm) If $E(RekNm,I)'?1P Set Out=Out_$E(RekNm,I)
 Quit Out_" "_$G(REKNr)
 ;
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
RAADPL(REKNr,Screen,NoMod) 
 Set:'$D(Screen) Screen=""
 New (%ZR,%ZM,Q,QL,QM,QN,QO,QRVG,QT,QTU,QU,QW,QZ,D,DT,TD,DD,DM,DJ,F70,F71,U,boot,cs,master,workst,io,QP,QD,%Q1,REKNr,Screen,NoMod,sProgLog,RK)
 Xecute F71
 Set LScreen=Screen,Aktie=""
 If '$D(^KAR(REKNr_" ")) Quit LScreen_D_Aktie
 Set EXTERN=1,PARAM=REKNr_D_Screen
 Do ^RPLREK
 Set Aktie=$G(Aktie),LScreen=$G(LScreen)
 Set Aktie=$S(Aktie="(":"P",Aktie=")":"N",1:"")
 Quit LScreen_D_D_Aktie
 ;
WIJZIG(REKNr,Screen,Element) 
 Set:'$D(Screen) Screen="" Set:'$D(Element) Element=""
 Lock  ZD
 New (%ZR,%ZM,Q,QL,QM,QN,QO,QRVG,QT,QTU,QU,QW,QZ,D,DT,TD,DD,DM,DJ,F70,F71,U,boot,cs,master,workst,io,QP,QD,%Q1,REKNr,Screen,Element,sProgLog,RK)
 Xecute F71
 Set LScreen=$G(Screen),LElement=$G(Element),Aktie=""
 If '$D(^KAR(REKNr_" ")) Quit LScreen_D_LElement_D_Aktie
 Set EXTERN=1
 Do KW^KA200
 Set Aktie=$S(Aktie="(":"P",Aktie=")":"N",1:"")
 Lock  ZD
 Quit LScreen_D_LElement_D_Aktie
 ;
 ; Selekteer rekening
KAR(Node) 
 If Node=5 Do  Quit  ; wijzigen en verwijderen rekening
 .Set K=$$SELECT() Set:K="." K="-"
 .If K'="-" Set (K,I1)=^KR1(K),R=$D(^KAR(K))
 .Set FP=2101 Write @F,@F1 Quit
 Set K="-"
 Quit
 ;