ZBCHKVRIJ ;KONTROLE VAN BESTANDEN (Vrijgave orders en leveringen) ;ZBCHK; [ 07/02/93  8:28 AM ]
 ;
 New R,KLNr,ORDNr,BONNr,MailId
 Set KLNr=""
 For  Set KLNr=$O(^VRIJGAVE(KLNr)) Quit:KLNr=""  Do
 . Set MailId=$G(^VRIJGAVE(KLNr,"O")),ORDNr=""
 . If MailId,$O(^VRIJGAVE(KLNr,"O",""))="" Write !,$ZR,!,"Mail ?" Quit
 . For  Set ORDNr=$O(^VRIJGAVE(KLNr,"O",ORDNr)) Quit:ORDNr=""  Do
 . . Set R=$G(^KOD(KLNr,"F",ORDNr,1))
 . . Quit:$P(R,D,23)
 . . Write !,$ZR,?30,"<-- ",$S($L(R):"is gesloten",1:"bestaat niet meer")
 Set KLNr=0
 For  Set KLNr=$O(^KOD(KLNr)) Quit:KLNr=""  Do
 . Set ORDNr=""
 . For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 . . Set R=^KOD(KLNr,"F",ORDNr,1)
 . . Quit:$P(R,D,23)'=1  Quit:$D(^VRIJGAVE(KLNr,"O",ORDNr))
 . . Write !,$ZR,?30,"<-- kan niet gesloten worden"
 Set KLNr=""
 For  Set KLNr=$O(^VRIJGAVE(KLNr)) Quit:KLNr=""  Do
 . Set MailId=$G(^VRIJGAVE(KLNr,"B")),BONNr=""
 . If MailId,$O(^VRIJGAVE(KLNr,"B",""))="" Write !,$ZR,!,"Mail ?" Quit
 . For  Set BONNr=$O(^VRIJGAVE(KLNr,"B",BONNr)) Quit:BONNr=""  Do
 . . Set R=$G(^KUL(KLNr,"F",BONNr))
 . . Set:R="" R=$G(^ORDW("D",BONNr))
 . . If $P(R,D)'=KLNr Write !,$ZR,?30,"<-- Klant?" Quit
 . . If $P(R,D,20)'="K" Write !,$ZR,?30,"<-- Status?" Quit
 Set BONNr=""
 For  Set BONNr=$O(^ORDW("D",BONNr)) Quit:BONNr=""  Do
 . Set R=^ORDW("D",BONNr)
 . Quit:$P(R,D,20)'="K"
 . Set KLNr=$P(R,D)
 . Quit:$D(^VRIJGAVE(KLNr,"B",BONNr))
 . Write !,$ZR,?30,"<-- kan niet naar het WMS"
 Quit