cA517(QU,SWMAN)	;Beheer wachtwoord ;%A517 ; [ 02/08/01  9:48 AM ]
	;
	; SWMAN = "O" of "W" : openen of wijzigen van een gebruiker
	;
T0	; Beheer wachtwoord ;
T1	;Huidig wachtwoord\;
T2	;Nieuw wachtwoord;"Minimum "_LENGT_" karakters";
T3	;"tik uw code nogmaals in ter bevestiging";
T4	;Uw initialen : ;
T5	;Wachtwoord;Laatste wijz.;
T6	;Wachtwoord werd reeds door u gebruikt;
T7	;Wachtwoord is niet wijzigbaar;
	;
T0F	; Gestion code d'accès ;
T1F	;Code d'acces actuel\;
T2F	;Nouveau code d'accès;""_LENGT_" caractères au moins";
T3F	;"Réentrez votre code d'accès pour confirmer";
T4F	;Vos initiales : ;
T5F	;Mot de passe;Dern.modific.;
T6F	;Ce mot de passe a été déjà utilisé;
T7F	;Le mot de passe n'est pas modifiable;
	;
T0E	; Password ;
T1E	;Present password\;
T2E	;New password;"At least "_LENGT_" characters";
T3E	;"confirm your password by typing it again";
T4E	;Your initials : ;
T5E	;Password;Last modif.;
T6E	;You have already used this password;
T7E	;Password cannot be modified;
	;
T0D	; Verwaltung Losungswort ;
T1D	;Heutiges Losungswort\;
T2D	;Neues Losungswort;"Minimum "_LENGT_" Charaktere";
T3D	;"Führen Sie nochmals ihren Code ein zur Bestätigung";
T4D	;Ihre Initialen : ;
T5D	;Losungswort;Letzte Änderung;
T6D	;Losungswort ist schon bei Ihnen gebraucht;
T7D	;Losungswort ist nicht änderbar;
	;
1	N UI1,UQC,USC,SW3,NWW,UFU,U2,ULOG,UQA,USA,LENGT,PW
	I '$L($G(SWMAN)) N A,B,K
	S io=$G(io,$$IO^cQ5)
	S UQA=$$SIG^cAFA1("PAR","LOGIN",115) I '$L(UQA) S UQA=0
	S USA=$$SIG^cAFA1("PAR","LOGIN",116) I '$L(USA) S USA="USR"
	D P^cA612(2,1,20,80,1,0,1,1,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
	G YZ:'$D(QU),YZ:QU'?1.UN,YZ:QU="SU"
	S FP=403 W /CUP(FP\100,FP#100),$P($T(@("T4"_QT)),U,2),QU
	D DMS^cAN000("UQC","USC","USR") I '$L(UQC)!'$L(USC) G YZ
	S UI1=$$UR^cAFA1("USR",101,QU)
	I $L($G(SWMAN)) G 11
	I 'UI1 G YZ
	S SW3=2
	K B D R^cAN000 M A=B
	; indien wachtwoord niet wijzigbaar
	I '$L($G(SWMAN)),'$P(B(2),D,29),$P(B(2),D,30) S K=$P($T(@("T7"_QT)),U,2) D TXT^cAFA1(250) G YZ
11	S PW=$$SRCH(UI1,.PW)
	S LENGT=$P(B(2),D,22) I 'LENGT S LENGT=$$SIG^cAFA1("PAR","LOGIN",107)
	;
2	; oud wachtwoord
	S K="" I $L($G(SWMAN)) G 29
	I $L($P(A(1),D,17)) S R="K\22\3\"_$P($T(@("T1"_QT)),U,2)_"\30\\",$P(R,D,16)=1 D R0 G YZ:K="-"
	I $L($P(A(1),D,17)),$$SCR^cA50011(K)'=$P(A(1),D,17) S K=$$F^cA5001(Q,QU,QT,K,UI1,2,io) G 2
29	S FP=603 W /CUP(FP\100,FP#100),$P($P($T(@("T1"_QT)),U,2),D)," : ",$TR($J("",30)," ","*")
	;
3	; nieuw wachtwoord
	S R="K\22\3\"_$P($T(@("T2"_QT)),U,2)_D_$P($T(@("T2"_QT)),U,3)_"\30\\($L(K)'<LENGT&($$SCR^cA50011(K)'=$P(A(1),D,17)))!(K=""-"")!('$L(K)&$L($G(SWMAN)))",$P(R,D,16)=1 D R0 G YZ:K="-"&'$L($P(A(1),D,17)),YZ:K="-"&$L($G(SWMAN)),1:K="-"
	I $L(K),$D(PW($$SCR^cA50011(K))) S K=$P($T(@("T6"_QT)),U,2) D TXT^cAFA1(250) G 3  ; is pasw. verschillend van laatste xx paswoorden,
	S NWW=K
	S FP=803 W /CUP(FP\100,FP#100),/ED,$P($P($T(@("T2"_QT)),U,2),D)," : ",$TR($J("",$P(B(2),D,22))," ","*")
	;
4	; bevestiging
	S R="K\22\3\"_$P($T(@("T2"_QT)),U,2)_D_$P($T(@("T3"_QT)),U,2)_"\30\\NWW=K!(K=""-"")",$P(R,D,16)=1 D R0 G 3:K="-"
	S NWW=K
	I $L(K) S NWW=$$SCR^cA50011(K)
	I $L($G(SWMAN)) S K=NWW,$P(B(1),D,17)=K G YZ
	;
5	S OK=0 I $L($$SIG^cAFA1("PAR","LOGIN",113)) X $$SIG^cAFA1("PAR","LOGIN",113) I OK G YZ
	D W^cAN220(USA,UQA,UI1,117,NWW)  ; wijz. wachtwoord
	D W^cAN220(USA,UQA,UI1,224,DT)  ; wijz. datum aanpassing
	I $P(B(2),D,29) D W^cAN220(USA,UQA,UI1,229,"")  ; te wijzigen bij volgende log-in op 'neen' zetten
	;
YZ	D C^cA612 Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
EXT(Q,UI1,NWW,DAT,QU)	; extern wijzigen (moet gejobd worden)
	; UI1 = internnr. initialen
	; NWW = nieuw wachtwoord (gescrambled)
	; DAT = datum
	D
	. N Q,UI1,NWW,DAT,QU
	. D ^cA604
	S UQA=$$SIG^cAFA1("PAR","LOGIN",115) I '$L(UQA) S UQA=0
	S USA=$$SIG^cAFA1("PAR","LOGIN",116) I '$L(USA) S USA="USR"
	D W^cAN220(USA,UQA,UI1,117,NWW)  ; wijz. wachtwoord
	D W^cAN220(USA,UQA,UI1,224,DT)  ; wijz. datum aanpassing
	I $$SIG^cAFA1("USR",UI1,229) D W^cAN220(USA,UQA,UI1,229,"")  ; te wijzigen bij volgende log-in op 'neen' zetten
	Q
	;
SRCH(UI1QU,PW)	; opzoeken laatste xx paswoorden
	N K,I,DLOG
	I '$L($G(UI1QU)) G SRCHZ
	D DMS^cAN000("UQC","USC","USR") I '$L(UQC)!'$L(USC) G SRCHZ
	S DLOG=$G(^DMC(UQC,USC,"LOGGING")) I '$L(DLOG) G SRCHZ
	S I="",PW=$$SIG^cAFA1("PAR","LOGIN",106) I 'PW G SRCHZ
	F  S I=$O(@DLOG@(UI1QU,I),-1) Q:I=""  S K=^(I) I PW,$P(K,D,2)=117 F J=4 I $L($P(K,D,J)),'$D(PW($P(K,D,J))) S PW($P(K,D,J))="",PW=PW-1
SRCHZ	Q $G(PW)
	;
ZZ	; 22.06.04 - 16 u 32 * V8