cAB1	;Beheer ^DMx ;%AB1 ; [ 25/02/2002 - 11:43:20 - 58860,42200 ]
	G 1
	;
T1	;  1. Beheer ^DMA;^cAB10;
T2	;  2. Beheer ^DMH;^cAB11;
T3	;  3. Beheer ^DMC;^cAB12;
T4	;  4. Beheer ^DMS;W^cAN200("DMS","DAM","","DAM");
T5	;  5. Beheer ^DMM;^cAB13;
T6	;  6. Global search;^cGSE;%GCHANGE;
T7	;  7. Global editor;^cI30;
T8	;  8. Global lister;^cGL;%G;
T9	;  9. Global copy;^cGCOPY;%GCOPY;
T10	; 10. Global compare;^cICGCMP;%GCMP;
T11	; 11. Raadplegen ^ERROR;^cABERR;
T12	; 12. Beheer menu;^cAB30;
T13	; 13. Interne programma's;^cABI0;
T14	; 14. Herrekenen indexen ^DMS;S1^cAN002("DAM","DMS");
T15	; 15. Controle indexbestanden;^cAB20;
T16	; 16. Routine search;^cRSE;cIRFIND;
T17	; 17. Routine editor;^cE;SYN^cABR;
T18	; 18. Routine print;^cI25;PRINT^cABR;
T19	; 19. Routine copy;^cA338,^cRCOPY,^cA339;
T20	; 20. Routine compare;^cRCMP;%RCMP;
T21	; 21. Export / Import;^cABIE;
T22	; 22. Routine search (MGR);^cQMSMSW,^cRSE,^cQMSMSW;ZZ;
T23	; 23. Routine copy   (MGR);^cA338,^cQMSMSW,^cRCOPY,^cQMSMSW,^cA339;ZZ;
T98	;Serverinfo;Job/Poort;Datum/Tijd;Taalcode;
T99	;Nummer element\"H[] = halt   X[] = xecute   M[] = menu uitvoeren   Q[] = andere Q-waarde        N[] = ned.   F[] = frans    E[] = engels           D[] = duits";
	;
	; Tonen van variabelen
S1	W:I>1 ", " W J,"="
	I $E(J)="$" W $C(34),@J,$C(34)
	E  W $C(34),$G(@J,"?"),$C(34)
S1Z	Q
	;
	; Tonen van variabelen
S2	W /CUP(16,3),$ZV,/CUP(17,1),@F1
	W /CUP(17,2),@F6,$P($T(T98),U,2),@F9,/CUP(17,15),": " F I=1:1 S J=$P("boot\cs",D,I) Q:J=""  D S1
	W /CUP(18,2),@F6,$P($T(T98),U,3),@F9,/CUP(18,15),": " F I=1:1 S J=$P("$J\io\$I",D,I) Q:J=""  D S1
	W /CUP(19,2),@F6,$P($T(T98),U,4),@F9,/CUP(19,15),": " F I=1:1 S J=$P("$H\DT\TD",D,I) Q:J=""  D S1
	W /CUP(20,2),@F6,$P($T(T98),U,5),@F9,/CUP(20,15),": " F I=1:1 S J=$P("QT\QTU",D,I) Q:J=""  D S1
S2Z	Q
	;
	; Titel
1	S $ZT="TRAP^"_$T(+0),boot=$G(boot),D="\" I boot="" D MASTER^cQ5
	I $G(io),'$D(^cLOG(boot,"DEV",io)) S ^(io)="RW" ; VJ 21.10.02
11	S Q=$P($G(Q,$G(^cLOG(boot,"Q",$ZU(5)),"EA")),D) D ^cA604,E^cA612,B^cA612
12	S QT=$S($G(QT)?1U:QT,1:""),QTU=$F("FDE",QT)
13	S QU=$G(QU) D T^cA612($P($T(+1),U,2)_"["""_$ZU(5)_"""]",1,0,7,0,1)
15	W @F1,/CUP(1,70),@F4,"Q=""",Q,""" ",@F5
17	I $G(QU)="" S R="QU\22\3\QU\""XX[] = initialen""\3\\K?1.3A\\\1" D R0,^cAN325(QU)
	D USR^cA5000(QU)
19	D T^cA612($P($T(+1),U,2)_"["""_$ZU(5)_"""]",1,0,7,0,1)
	;
	; Mogelijkheden
2	F I=1:1:30 S J=$P($T(@("T"_I)),U,2) I $L(J) D
	. I $ZV'["MSM",I>21,I<24 Q
	. W /CUP($S(I<11:I,1:I-10)+2,$S(I<11:1,1:41)),J
21	S OPENDMS=1,QL=$G(QL) W /WWR(1) D S2
	;
	; Nummer element
3	S R="U1\22\3\"_$P($T(T99),U,2)_"\2\\\\\1\\\1\60" D R0 G YZ:K="-"
	I K="" D ^cA106,^cA105 G 21
30	I K="H" D  H 0 H
	. D E^cA612
	. I $G(io),$D(^cLOG(boot,"DEV",io)) S K=$P(^(io),D) I $L(K),$L($G(^cLOG(0,"LOGOUT",K))) X ^(K)
31	I K="M" S $ZT="" D ^cA508 G 1
32	I K="N" S QT="" G 1
33	I K="F" S QT=K G 1
	I K="E" S QT=K G 1
	I K="D" S QT=K G 1
34	I K="Q" S R="Q\22\3\Q\""XX[] = Q-waarde""\3\\K?1.3A\\\1" D R0 G 1
35	I K="X" S R="X\22\3\Xecute\\60" D R0,E^cA612 X:$L($TR(X,"-,^ ")) X_"  W !,""<>"" R K" G 1
	I K="G" D E^cA612,^cABG G 1
37	I K,K<24 S I=$T(@("T"_(+K))) D  S:K=""!($ZV["MSM") K=$P(I,U,3) D E^cA612,@K H 1 G 1
	. S K=$P(I,U,4) I $L(K),K'="ZZ",K'["^" S K="^"_K ; %-programma's Caché
39	G 3
	;
YZ	D C^cA612 Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
I(I,T)	; vraagstelling via tekstvenster (I=input ; T=titel)
	N RR,RR1
	F RR1=1:1 S RR(RR1)=$E(I,1,78),I=$E(I,79,999) Q:I=""
	D BT^cAN210("TXT","DAM",0,0,"RR")
	N O S O="",RR1="" F  S RR1=$O(RR(RR1)) Q:RR1=""  S O=O_RR(RR1)
IZ	Q O
	;
	; error-trap
TRAP	G ^cA403
	Q
	;
ZZ	; 04.04.05 - 14 u 29 * V8.03