cAB1212	;Beheer RK-waarden synoniemen; %AB123 [ 03/29/01  9:30 AM ]
	G YZ
	;
T0	;Beheer ^DMC;
T1	;Beheer RK-waarden synoniemen;
T2	;RK-waarde   Xecute                                    Hoofdprg   Scroll;
T3	;Keuze\"[] = toevoegen   xx[] = wijzigen   V[] = verwijderen";
T4	;Wijzigen RK-waarde;
T5	;Keuze\"0[] = hoofdprogramma   1[] = scroll";
T6	;RK-waarde       : ;
T7	;Hoofdprg/scroll : ;
T8	;Execute         : ;
T9	;Nummer element;
T10	;RK-waarde werd reeds gebruikt;
T11	;RK-waarde;
T12	;Hoofdprg/scroll\"0[] = hoofdprogramma   1[] = scroll";
T13	;Xecute werd reeds gebruikt voor deze RK-waarde;
T14	;Er kunnen geen RK-waarden worden verwijderd;
T15	;Te verwijderen RK-waarde;
T16	;Verwijderen RK-waarde;
T17	;Verwijderen\"V[] = verwijderen   ,[] = hernemen";
	;
	;  Beheer RKW-waarden synoniemen
S7	N RKW,RKSTRING,DELV,DELH,KRUIS,RIJ,I,EXE,HPRSCR S $ZT="TRAP^cAN000"
S7A	D P^cA612(3,1,19,80,1,0,0,1,$P($T(@("T1"_QT)),U,2),0,1,0,0,0)
S7B	D SCHRIJF    
S7C	S R="KEUZE\22\3\"_$P($T(@("T3"_QT)),U,2)_"\2\\(K?.N)!(""V-""[K)\\\1" D R0 G S7Z:K="-"
S7D	I KEUZE="" D TOEV^cAB1213 G S7B
S7E	I KEUZE?.N,(RKSTRING'[K) G S7C
S7F	I KEUZE?.N,$D(^DMC(UQC,USC,"SYN",0,0,KEUZE,0))&($D(^DMC(UQC,USC,"SYN",0,0,KEUZE,1))) S R="HPRSCR\22\3\"_$P($T(@("T5"_QT)),U,2)_"\1\\(""01-""[K)&($L(K))\\\1" D R0 G S7C:K="-"
S7G	I KEUZE?.N  D WIJZ(KEUZE,$G(HPRSCR)) G S7B
S7H	I KEUZE="V" D VERW G S7B
S7Z	D C^cA612 Q
	;
	;  Wijzigen van de xecute
EXE(RKW,HPRSCR,EXE)	
	N IN S $ZT="TRAP^cAN000"
	S IN=EXE
	S IN=$$I^cAB1(IN,"Xecute")
	I IN="-" G EXEZ
	S EXE=IN
	S ^DMC(UQC,USC,"SYN",0,0,RKW,HPRSCR)=EXE
EXEZ	Q EXE
	;
	;  Wijzigen van de swich hoofdprogramma/scroll
HPRSCR(RKW,HPRSCR,EXE)	
	N IN S $ZT="TRAP^cAN000"
	S IN=HPRSCR
HPRSCRA	S R="IN\22\3\"_$P($T(@("T12"_QT)),U,2)_"\1\\(""01-""[K)\\\\\1" D R0 G HPRSCRZ:K="-"
	I IN'=HPRSCR,$D(^DMC(UQC,USC,"SYN",0,0,RKW,IN)) S K=$P($T(@("T13"_QT)),U,2) D TXT^cAFA1(250) G HPRSCRA
	S ^DMC(UQC,USC,"SYN",0,0,RKW,IN)=EXE
	K ^DMC(UQC,USC,"SYN",0,0,RKW,HPRSCR)
	S HPRSCR=IN
HPRSCRZ	Q HPRSCR
	;
	;  Wijzigen van de RK-waarde
RK(RKW,HPRSCR,EXE)	
	N IN S $ZT="TRAP^cAN000"
	S IN=RKW
RKA	S R="IN\22\3\"_$P($T(@("T11"_QT)),U,2)_"\\2\\K?.N!(""-""[K)\\\\\1" D R0 G RKZ:K="-"
	I IN'=RKW,$D(^DMC(UQC,USC,"SYN",0,0,IN,HPRSCR)) S K=$P($T(@("T10"_QT)),U,2) D TXT^cAFA1(250) G RKA
	S ^DMC(UQC,USC,"SYN",0,0,IN,HPRSCR)=EXE
	K ^DMC(UQC,USC,"SYN",0,0,RKW,HPRSCR)
	S RKW=IN
RKZ	Q RKW
	;
	;  Teken van het scherm van een bepaalde RK-waarde
RKSCH	W /CUP(1,1),@F1
	W /CUP(2,2),"1. ",$P($T(@("T6"_QT)),U,2),RKW
	W /CUP(3,2),"2. ",$P($T(@("T7"_QT)),U,2),$S(HPRSCR=0:"hoofdprg",1:"scroll")
	W /CUP(4,2),"3. ",$P($T(@("T8"_QT)),U,2),$E(EXE,1,54)
RKSCHZ	Q
	;
	;  Tonen op het scherm van de verschillende RK-waarden
SCHRIJF	W /CUP(2,1),@F1
	S DELV="/cDR(1),/cDR(3),/cDR(0)"
	S DELH="/cDR(1),/cDR(2),/cDR(0)"
	S KRUIS="/cDR(1),/cDR(12),/cDR(0)"
	S RIJ=3
	W /CUP(RIJ,5),/SGR(1),$P($T(@("T2"_QT)),U,2),/SGR(0),/WCMD
	D STREEP
	S RIJ=RIJ+1
	F I=5:1:75 W /CUP(RIJ,I),@DELH
	W /CUP(RIJ,15),@KRUIS
	W /CUP(RIJ,57),@KRUIS
	W /CUP(RIJ,68),@KRUIS
	S RIJ=RIJ+1 S RKW=0,RKSTRING=""
	F  S RKW=$O(^DMC(UQC,USC,"SYN",0,0,RKW)) Q:RKW=""  D
	. S RKSTRING=RKSTRING_RKW_D
	. I $D(^DMC(UQC,USC,"SYN",0,0,RKW,0))  D
	.. W /CUP(RIJ,5),RKW
	.. S EXE=^DMC(UQC,USC,"SYN",0,0,RKW,0)
	.. W /CUP(RIJ,17),$E(EXE,1,39)
	.. W /CUP(RIJ,62),"+"
	.. D STREEP
	.. S RIJ=RIJ+1
	. I $D(^DMC(UQC,USC,"SYN",0,0,RKW,1))  D
	.. W /CUP(RIJ,5),RKW
	.. S EXE=^DMC(UQC,USC,"SYN",0,0,RKW,1)         
	.. W /CUP(RIJ,17),$E(EXE,1,39)
	.. W /CUP(RIJ,72),"+"
	.. D STREEP
	.. S RIJ=RIJ+1
SCHRIJFZ	Q
	;
STREEP	W /CUP(RIJ,15),@DELV
	W /CUP(RIJ,57),@DELV
	W /CUP(RIJ,68),@DELV
STREEPZ	Q
	;
	;  Verwijderen van een RK-waarde
VERW	N RKW,VOLGNR,HPRSCR S $ZT="TRAP^cAN000"
	S RKW=""
	I $O(^DMC(UQC,USC,"SYN",0,0,RKW))="" S K=$P($T(@("T14"_QT)),U,2) D TXT^cAFA1(250) G VERWZ
VERWA	S R="RKW\22\3\"_$P($T(@("T15"_QT)),U,2)_"\\2\\((K?.N)!(""-""[K))&($L(K))\\\1" D R0 G VERWZ:K="-"
	I RKSTRING'[K G VERWA
	I $D(^DMC(UQC,USC,"SYN",0,0,RKW,0))&($D(^DMC(UQC,USC,"SYN",0,0,RKW,1))) S R="HPRSCR\22\3\"_$P($T(@("T5"_QT)),U,2)_"\1\\(""01-""[K)&($L(K))\\\1" D R0 G VERWA:K="-"
	D P^cA612(15,0,7,80,1,0,1,0,$P($T(@("T16"_QT)),U,2),0,1,1,0,0)
	I '$L($G(HPRSCR)) S HPRSCR="" S HPRSCR=$O(^DMC(UQC,USC,"SYN",0,0,RKW,HPRSCR))
	S EXE=^DMC(UQC,USC,"SYN",0,0,RKW,HPRSCR)
	D RKSCH
	S R="VERWR\22\3\"_$P($T(@("T17"_QT)),U,2)_"\1\\$L(K)&("",V-""[K)\\\1" D R0
	I VERWR="-" D C^cA612 G VERWA
	I VERWR="," D C^cA612 G VERWZ
	I VERWR="V" K ^DMC(UQC,USC,"SYN",0,0,RKW,HPRSCR) D C^cA612
VERWZ	Q
	;
	;  Wijzigen van een RKW-waarde
WIJZ(RKW,HPRSCR)	
WIJZA	N I1,EXE,KEUZE S $ZT="TRAP^cAN000"
	D P^cA612(15,0,7,80,1,0,1,0,$P($T(@("T4"_QT)),U,2),0,1,1,0,0)
	I '$L($G(HPRSCR)) S HPRSCR="" S HPRSCR=$O(^DMC(UQC,USC,"SYN",0,0,RKW,HPRSCR))
	S EXE=^DMC(UQC,USC,"SYN",0,0,RKW,HPRSCR)
WIJZB	D RKSCH
	S R="KEUZE\22\3\"_$P($T(@("T9"_QT)),U,2)_"\\1\\(""123-""[K)&($L(K))" D R0 G WIJZZ:K="-"
	I KEUZE=1 S RKW=$$RK(RKW,HPRSCR,EXE) G WIJZB 
	I KEUZE=2 S HPRSCR=$$HPRSCR(RKW,HPRSCR,EXE) G WIJZB
	I KEUZE=3 S EXE=$$EXE(RKW,HPRSCR,EXE) G WIJZB
WIJZZ	D C^cA612 Q
	;
YZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q
	;
ZZ	; 18.05.01 - 11 u 18 * V7.86