cABVBK1	;Functies Class Definition ; cABVBK1
	;
T1	;
T2	;Sleutel bij de talen is niet ingevuld, opslaan onmogelijk.;
T3	;Fout bij openen taal ;Fout bij wijzigen taal ;
T4	;Persistent;
T6	;Klasse;Groep;Interne naam;
T8	;Taal;
T9	;Combinatie Groep en Interne naam is niet uniek.;
T10	;Klasse is verwijderd;
T11	;Afwijking verschilt van de ingegeven afwijking : ;
T12	;Er zijn nog afwijkingen voor deze klasse.;Klasse kan niet verwijderd worden.
T13	;Unieke sleutel;Q;Unieke index;
T14	;Property ";" niet kunnen aanmaken;
T15	;Index ";" niet kunnen aanmaken;
	;
T1E	;
T2E	;Key in languages is empty, save impossible.;
T3E	;Error creating language ;Error changing language ;
T4E	;Persistent;
T6E	;Class;Group;Internal name;
T8E	;Language;
T9E	;Combination Group and Internal name is not unique.;
T10E	;Class has been deleted;
T11E	;Deviation is different from the input : ;
T12E	;There are deviations for this class.;Class cannot be deleted.;
T13E	;Primary key;Q;Unique index;
T14E	;Failed to create property ";";
T15E	;Failed to create index ";";
	;
YZ	Q
	;
	;Berekende property
C107GET(B107,QT,ALL)	
	S $ZT="^dmERROR"
	N R,U,D
	S U=";",D="\"
	D QT^cAFVBO01
	I $G(ALL) S R=$TR($P($T(@("T4"_QT)),U,2,2),U,D) G C107GETZ
	S R=$P($T(@("T4"_QT)),U,B107+2)
C107GETZ	Q R
	;
CHKDEL(Q,UI1)	; test of er nog copies zijn van het origineel
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("UI1")
	S OK=1
	I $L($$UI1^cAFA1("DC",133,UI1)) S OK="0\"_$P($T(@("T12"_QT)),U,2) G CHKDELY
CHKDELY	I 'OK S OK=OK_$c(13,10)_$P($T(@("T12"_QT)),U,3)
CHHDELZ	Q OK
	;
	;DC.Taal : mtemp opbouwen
BTEMP(GRIDID,DCID,COPY)	
	; GRIDID: volgnr van de grid : indien '' : volgnummer ophalen
	; DCID : intern nr van ^^DDC(0,"KLASSE" waaruit data moet opgehaald worden
	; COPY : Het gaat om het kopiëren van een klasse
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^cAFVBA01("GRIDID,DCID,COPY")	
	;
	F i="GRIDID","DCID","COPY" S @i=$G(@i)
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON") S OK=GRIDID
	;
	D DMS^cAN000("UQC","USC","DC.TAAL",1) I '$L(UQC)!'$L(USC) G BTEMPZ
	S UREF=^DMC(UQC,USC,"DATA","REF")
	S TKI1=""
	F  S TKI1=$O(^DTEXT(0,"TEXT.9000",TKI1)) Q:TKI1=""  D     ; aflopen taalcodes
	. S TKB=^(TKI1,0)
	. I $P(TKB,D,30) Q  ; BG of verwijderd
	. S TK=TKI1 ;$P(TKB,D)
	. S UI1=DCID_" "_TK
	. S B(1)=$G(@UREF@(0))
	. S B=$S(COPY=1:"",1:$S($L(B(1)):UI1,1:""))_D_TK    ; key (ingevuld als rec. bestaat)_D_taalcode
	. S $P(B,D,3)=$P(B(1),D,3) 	      ; Groep
	. S $P(B,D,4)=$P(B(1),D,4)    	      ; Externe naam
	. S $P(B,D,5)=$P(B(1),D,5)    	      ; Omschrijving 
	. S $P(B,D,6)=$P(B(1),D,6)    	      ; SQLTabel
	. S UI1T=$P(B,D) I '$L(UI1T) S UI1T=" "_TK
	. S ^mtemp99(GRIDID,"COMMON",UI1T,0)=B
BTEMPZ	Q OK
	;
	; gewijzigde rij in VB.NET opslaan in de mtemp 
SAVEROW(SELECTEDID,GROEP,EXTNAAM,OMSCHR,SQLTAB)	
	N (SELECTEDID,GROEP,EXTNAAM,OMSCHR,SQLTAB)
	S $ZT="^dmERROR",OUT=1,D="\",U=";"
	I SELECTEDID="" G SAVEROWZ
	S GRIDID=$P(SELECTEDID,"||")
	S SELECTEDID=$P(SELECTEDID,"||",2)	
	S $P(^mtemp99(GRIDID,"COMMON",SELECTEDID,0),D,3)=$G(GROEP)
	S $P(^mtemp99(GRIDID,"COMMON",SELECTEDID,0),D,4)=$G(EXTNAAM)
	S $P(^mtemp99(GRIDID,"COMMON",SELECTEDID,0),D,5)=$G(OMSCHR)
	S $P(^mtemp99(GRIDID,"COMMON",SELECTEDID,0),D,6)=$G(SQLTAB)
SAVEROWZ	Q OUT
	;
	;	
STEMP(GRIDID,DCID)	; Drukken op OK-button (DDIC-DefPerTaalGrid), opslaan van de mtemp in de ^DDC
	; GRIDID: volgnr van de grid : indien '' : volgnummer ophalen
	; DCID : intern nr van ^DDC(0,"KLASSE"
	; 
	; Q, QT en QU komen vanuit Methode via de methodgenerator
	; 
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("GRIDID,DCID")
	S OK=1
	I '$L($G(GRIDID)) G STEMPZ
	I '$L($G(DCID)) S OK="0\"_$P($T(@("T2"_QT)),U,2) G STEMPZ
	S I1=""
STEMPA	S I1=$O(^mtemp99(GRIDID,"COMMON",I1)) I I1="" G STEMPZ
	S B=^(I1,0)
	S UI1=$P(B,D)     ; key
	S TK=$P(B,D,2)    ; taalkode
	S B(101)=DCID,B(102)=TK            
	S B(103)=$P(B,D,3) 	   ; Groep
	S B(104)=$P(B,D,4) 	   ; Externe naam
	S B(105)=$P(B,D,5) 	   ; Omschrijving
	S B(106)=$P(B,D,6) 	   ; SQLTabel
	K TAB
	I $L($P(B,D)) G STEMPC
STEMPB	; openen
	; B(101), B(102) omvormen naar TAB(1), TAB(2) ...
	S UI1=B(101)_" "_B(102)
	S I="" F  S I=$O(B(I)) Q:I=""  S $P(TAB(I\100),D,I#100)=B(I)
	D P^cAN220("DC.TAAL","",UI1,"TAB","") I K="-" S OK="0\"_$P($T(@("T3"_QT)),U,2)_TK G STEMPZ
	G STEMPA
STEMPC	; wijzigen	
	S UI1=$P(B,D)
	M TAB=B
	D B^cAN220("DC.TAAL","",UI1,"TAB") I K="-" S OK="0\"_$P($T(@("T3"_QT)),U,3)_TK G STEMPZ
	G STEMPA
STEMPZ	Q OK
	;
	;
HDRDC(NR,GROEP,INTNAAM)	; header Class definition
	N HNR,HGROEP,HINTNAAM
	S $ZT="^dmERROR"
	S U=";"
	D QT^cAFVBO01
	I '$L(NR),('$L(GROEP)),('$L(INTNAAM)) D  G HDRDCA
	. S HNR=..DCId,HINTNAAM=..B101
	. S HGROEP="" I $L(..B103) S HGROEP=..B103.B101
	S HNR=NR,HGROEP=GROEP,HINTNAAM=INTNAAM
HDRDCA	S OUT="\\\"_$P($T(@("T6"_QT)),U,2)_";"_HNR_" "_HGROEP_" "_HINTNAAM_"; \\\"
HDRDCZ	Q OUT
	;
HDRDCL()	; header Class definition-DefPerTaal-logging
	N OUT
	S $ZT="^dmERROR"
	D QT^cAFVBO01
	;
	S GROEP="" I $L(..B101.B103) S GROEP=..B101.B103.B101
	S OUT=$$HDRDC(..B101.DCId,GROEP,..B101.B101)
	S OUT=OUT_"\"_$P($T(@("T8"_QT)),";",2)_";"
	S R=$$DATA^cAFVBO01("DTEXT",0,"TEXT.9000",..B102,100+(QTU*10-8))
	;X "S R=..B102."_$P("OmschrijvingNederlands#OmschrijvingFrans#OmschrijvingEngels#OmschrijvingDuits","#",QTU)
	S OUT=OUT_R_";"
HDRDCLZ 	Q OUT
	;	
CHKUNIQ(GROUP,CLASS,AFW,UI1)	;Controleren of Groep+Interne naam klasse+afwijking uniek is
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("GROUP,CLASS,AFW,UI1")
	D QT^cAFVBO01
	S R=$$UI1OP^cAFA1("DC","M1","1\1\\"_$G(UI1),GROUP,CLASS,AFW)
	S OUT=1 I $L(R) S OUT="0\"_$P($T(@("T9"_QT)),U,2)
CHKUNIQZ	Q OUT
	;
BTEMPSEL(GRIDID,DCIDS)	
	; Input: GRIDID
	; 	DCIDS: Geselecteerde klasseids gescheiden door "\"
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^cAFVBA01("GRIDID,DCIDS")
	D QT^cAFVBO01
	;
	F i="GRIDID","DCIDS" S @i=$G(@i)
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON") S OK=GRIDID
	;
	D DMS^cAN000("UQC","USC","DC",1) I '$L(UQC)!'$L(USC) G BTEMPSELZ
	S UREF=^DMC(UQC,USC,"DATA","REF")
	;
	F PC=1:1:$L(DCIDS,D) D
	. S UI1=$P(DCIDS,D,PC) I '$L(UI1) Q
	. S N=$G(@UREF@(0)) I '$L(N) Q
	. I $P(N,D,30)=2 Q
	. S $P(N,D,3)=$$DATA^cAFVBO01("DKODE",0,"CODE.9022",$P(N,D,3),101) ;Klassegroep
	. S ^mtemp99(GRIDID,"COMMON",UI1,0)=$P(N,D,1,3)
	. S ^mtemp99(GRIDID,"COMMON",UI1,1)=0 ; Record al verwerkt (=nee)
	. S $P(^mtemp99(GRIDID,"COMMON",UI1,0),D,5)=$$BG^cAFVBO01(0,QT)
	;
BTEMPSELZ	Q OK
	;
BDDP(GRIDID,AFW)	
	; Input: GRIDID: Gridid van de geselecteerde klassen
	; 	AFW: Afwijking
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("GRIDID,AFW")
	D QT^cAFVBO01
	;
	S OK=1
	F i="GRIDID","AFW" S @i=$G(@i)
	I '$L(GRIDID) G BDDPZ
	;
	D DMS^cAN000("UQC","USC","DC",1) I '$L(UQC)!'$L(USC) G BDDPZ
	S UREF=^DMC(UQC,USC,"DATA","REF")
	S MTEMP="^mtemp99(GRIDID,""COMMON"",DCID)"
	;
	S DCID="" F  S DCID=$O(^mtemp99(GRIDID,"COMMON",DCID)) Q:'$L(DCID)  D
	. I $G(^(DCID,1)) Q          ; Record is reeds verwerkt
	. S UI1=DCID,N=$G(@UREF@(0)) 
	. I ('$L(N))!$P(N,D,30)=2 S $P(@MTEMP@(0),D,4)=$P($T(@("T10"_QT)),U,2),OK=0 Q ; Record is verwijderd
	. I $L($G(AFW)),$L($P(N,D,32)),$P(N,D,32)'=AFW S $P(@MTEMP@(0),D,4)=$P($T(@("T11"_QT)),U,2)_AFW,OK=0 Q  ; afwijking is verschillend
	. S ORIDCID=DCID
	. I $L($P(N,D,33)) S ORIDCID=$P(N,D,33) ; Origineel klasseid
	. S RES=$$BUILD^cABVBP2(ORIDCID,AFW)
	. I 'RES S $P(@MTEMP@(0),D,4)=$P(RES,D,2),OK=0 Q
	. S $P(@MTEMP@(1),D)=1,$P(@MTEMP@(0),D,5)=$$BG^cAFVBO01(1,QT) ; Record aanduiden als verwerkt
	. S $P(@MTEMP@(0),D,4)="" ; Eventuele vorige fout verwijderen
	;
BDDPZ	Q OK
	;
BUILD(GRIDID,QQ,SWKLA,SWKLC,SWDMA,DMATYPE,UQA,USA,SWUPD,TAAL)	  ; aanmaken einddefinitie en/of klasse, DMA
	; Input: GRIDID: Gridid van de geselecteerde klassen
	; 	QQ: Q-waarde
	; 	SWKLA: Klasse aanmaken? 1=ja,0=neen
	; 	SWKLC: Klasse compileren? 1=ja,0=neen
	; 	SWDMA: DMA aanmaken? 1=ja,0=neen
	; 	DMATYPE: Hoe DMA aanmaken (0,1 of 2)
	; 	UQA: Specifieke UQA
	; 	USA: Specifieke USA
	; 	SWUPD: Update grids en forms 0=neen,1=test,2=ja
	; 	TAAL : zie beschrijving in BUILD^cABVBP3
	; 	
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("GRIDID,QQ,SWKLA,SWKLC,SWDMA,DMATYPE,UQA,USA,SWUPD,TAAL")
	D QT^cAFVBO01
	;
	S OK=1
	F i="GRIDID","QQ","SWKLA","SWKLC","SWDMA","DMATYPE","UQA","USA","SWUPD" S @i=$G(@i)
	I '$L(GRIDID) G BUILDZ
	;
	W !,"Aanmaken einddefinitie"
BUILDA	S OK=$$BDDP(GRIDID,"")
	I 'OK G BUILDZ
	;
	I '$L(QQ),'SWUPD G BUILDZ   ; geen klasse en/of DMA aanmaken/wijzigen
	;
	S MTEMP="^mtemp99(GRIDID,""COMMON"",DCID)"
	S DCID="" F  S DCID=$O(^mtemp99(GRIDID,"COMMON",DCID)) Q:'$L(DCID)  D
	. S $P(@MTEMP@(1),D)=0,$P(@MTEMP@(0),D,5)=$$BG^cAFVBO01(0,QT) ; Record aanduiden als niet verwerkt
	;
	W !,"Aanmaken klassen - DMA"
	S OK=$$BUILD^cABVBP1(GRIDID,QQ,SWKLA,SWKLC,SWDMA,DMATYPE,UQA,USA,SWUPD,TAAL)
	;
BUILDZ	Q OK
	;
CREDEF(DCID,DDID)	; Creëert default properties en index voor een nieuwe klasse
	; Input: DCID: Klasse id
	; 	DDID: Data dict. van de primary key
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("DCID,DDID")
	D QT^cAFVBO01
	;
	S OK=1
	F i="DCID","DDID" S @i=$G(@i)
	I '$L(DCID) G CREDEFZ  ; Stoppen indien geen klasse id doorgegeven
	I '$L(DDID) G CREDEFZ  ; Stoppen indien geen data dict. id doorgegeven
	;
	D DMS^cAN000("UQC","USC","DC",1) I '$L(UQC)!'$L(USC) G CREDEFZ
	S UREF=^DMC(UQC,USC,"DATA","REF"),UI1=DCID
	I '$D(@UREF) G CREDEFZ  ; Stoppen indien geen geldig klasse id doorgegeven
	S NODE0=@UREF@(0),NODE1=@UREF@(1)
	S IDQ=$P(NODE1,D,5) ; Zit Q in de key?
	S dmQ49=$P(NODE1,D,9)  ; dmQ49=1 ?
	;
CREDEFA	; Aanmaken properties
	;
	; Gemeenschappelijk gedeelte voor de properties
	S $P(GTAB(1),D)=DCID                           ; UI1 Klasse
	S $P(GTAB(1),D,6)=0                            ; Niet berekend
	S $P(GTAB(1),D,9)=0                            ; Niet transient
	S $P(GTAB(1),D,32)=$P(NODE0,D,32)              ; (Eventuele) Afwijking
	;
	; Uniek ID
CREDEFB	S TAB(1)=GTAB(1)
	S IDUI1=$$NR^cABVBK10(Q,"DC.PROP",DCID,$P(NODE0,D,32))
	S $P(TAB(1),D,2)=$P(IDUI1," ",2)              ; Volgnummer
	S $P(TAB(1),D,3)=$P(NODE0,D)_"Id"             ; Interne naam property
	S $P(TAB(1),D,4)=$$SIG^cAFA1("DD",DDID,102)   ; Commentaar
	S $P(TAB(1),D,5)=DDID                         ; Referentie naar data dict.
	S $P(TAB(1),D,7)=3                            ; Subscript nummer drie
	D P^cAN220("DC.PROP","",IDUI1,"TAB","")
	I $L(K) S OK="0\"_$P($T(@("T14"_QT)),U,2)_$P(TAB(1),D,3)_$P($T(@("T14"_QT)),U,3)
	;
	; Q (Company Id)
CREDEFC	I 'IDQ G CREDEFD
	S TAB(1)=GTAB(1)
	S QUI1=$$NR^cABVBK10(Q,"DC.PROP",DCID,$P(NODE0,D,32))
	;S DDQ=$$UI1^cAFA1("DD",101,"Q")
	S DDQ=10054
	S $P(TAB(1),D,2)=$P(QUI1," ",2)               ; Volgnummer
	S $P(TAB(1),D,3)="Q"			 ; Interne naam property
	S $P(TAB(1),D,4)=$$SIG^cAFA1("DD",DDQ,102)    ; Commentaar
	S $P(TAB(1),D,5)=DDQ                          ; Referentie naar data dict.
	S $P(TAB(1),D,7)=1                            ; Subscript nummer één
	D P^cAN220("DC.PROP","",QUI1,"TAB","")
	I $L(K) S OK="0\"_$P($T(@("T14"_QT)),U,2)_$P(TAB(1),D,3)_$P($T(@("T14"_QT)),U,3)
	;
CREDEFD	I 'dmQ49 G CREDEFE
	S TAB(1)=GTAB(1)
	S QUI1=$$NR^cABVBK10(Q,"DC.PROP",DCID,$P(NODE0,D,32))
	;S DDQ=$$UI1^cAFA1("DD",101,"Vennootschap")
	S DDQ=10054
	S $P(TAB(1),D,2)=$P(QUI1," ",2)               ; Volgnummer
	S $P(TAB(1),D,3)="B149"			 ; Interne naam property
	S $P(TAB(1),D,4)=$$SIG^cAFA1("DD",DDQ,102)    ; Commentaar
	S $P(TAB(1),D,5)=DDQ                          ; Referentie naar data dict.
	S $P(TAB(1),D,10)=149                         ; B-index
	D P^cAN220("DC.PROP","",QUI1,"TAB","")
	I $L(K) S OK="0\"_$P($T(@("T14"_QT)),U,2)_$P(TAB(1),D,3)_$P($T(@("T14"_QT)),U,3)
	;
CREDEFE	 ; Loggingdata
	;  Kort gesloten door KU op 28.12.05  : wordt opgezet bij aanmaken klasse
	; S TAB(1)=GTAB(1)
	; S LOGUI1=$$NR^cABVBK10(Q,"DC.PROP",DCID,$P(NODE0,D,32))
	; S DDLOG=$$UI1^cAFA1("DD",101,"LoggingData")
	; S $P(TAB(1),D,2)=$P(LOGUI1," ",2)             ; Volgnummer
	; S $P(TAB(1),D,3)="LoggingData"                ; Interne naam property
	; S $P(TAB(1),D,4)=$$SIG^cAFA1("DD",DDLOG,102)  ; Commentaar
	; S $P(TAB(1),D,5)=DDLOG                        ; Referentie naar data dict.
	; S $P(TAB(1),D,6)=1                            ; Berekend
	; S QQ="" I $L($G(^cLOG(boot,"Q",cs))) S QQ=$P(^(cs),D,2) I '$L(QQ) S QQ=$P(^(cs),D)
	; S:'$L($G(QQ)) QQ="EA"
	; S QQ=""""_QQ_"""" I $P(NODE1,D,5) S QQ="{Q}"
	; S DMS=""""_$P(NODE1,D)_"""",ID="{"_$P(NODE0,D)_"Id}" 
	; S CODE="S {LoggingData}=$$LOGDATA^cAFVBO01("_QQ_","_DMS_","_ID_")"
	; S $P(TAB(3),D)=CODE                           ; Code berekend veld
	; D P^cAN220("DC.PROP","",LOGUI1,"TAB","")
	; I $L(K) S OK="0\"_$P($T(@("T14"_QT)),U,2)_$P(TAB(1),D,3)_$P($T(@("T14"_QT)),U,3)
	;
CREDEFF	; Aanmaken unieke index	 
	;
	K TAB
	S INDUI1=$$NR^cABVBK10(Q,"DC.IND",DCID,$P(NODE0,D,32)) 
	S $P(TAB(1),D)=DCID                           ; UI1 Klasse
	S $P(TAB(1),D,2)=$P(INDUI1," ",2)             ; Volgnummer
	S $P(TAB(1),D,3)="K"_$P(NODE0,D)_"Id"	 ; Interne naam index
	S $P(TAB(1),D,4)=$P($T(@("T13"_QT)),U,4)      ; Commentaar
	S $P(TAB(1),D,5)=1                            ; IsKey = ja
	S $P(TAB(1),D,6)=1                            ; Uniek = ja
	S $P(TAB(1),D,32)=$P(NODE0,D,32)              ; (Eventuele) Afwijking
	I IDQ D
	. S $P(TAB(2),D)=QUI1                         ; UI1 van Q-property
	. S $P(TAB(2),D,2)=IDUI1                      ; UI1 van Id-property
	I 'IDQ S $P(TAB(2),D)=IDUI1                   ; UI1 van Q-property
	D P^cAN220("DC.IND","",INDUI1,"TAB","")
	I $L(K) S OK="0\"_$P($T(@("T15"_QT)),U,2)_$P(TAB(1),D,3)_$P($T(@("T15"_QT)),U,3)
	;
CREDEFZ	Q OK
	;
SUPVV(DCID)	; Heeft klasse vrije velden?
	N R,PROP
	S $ZT="^dmERROR"
	;
	S R=0
	S PROP=$O(^DDC(0,"KLASSE.PROP",DCID_" z"),-1)
	I $P(PROP," ")'=DCID G SUPVVZ
	;
	S R=$$ISVV^cABVBP17(PROP,2)
	;	
SUPVVZ	Q R
	;
UPDI	F I1="DC","DC.TAAL","DC.PROP","DC.PROP.TAAL","DC.IND","DC.METH","DC.APPL","DC.APPL.TAAL" D S1^cAN002(0,I1,24)
UPDIZ	Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09