cAFI9	;Inputcontroles back-ground-jobs; cAFI9
	;
	G YZ
	;
T0	;Inputcontroles back-ground-jobs;
	;
T0F	;Inputcontroles back-ground-jobs;
	;
DAG(FREQ,DAG)	;  Inputcontrole dag
	N R
	S $ZT="TRAP^cAN000"
	S R=0
	I FREQ'=7&(FREQ'=14)&(FREQ'=30) D
	. I DAG="" S R=1
	I FREQ=7!(FREQ=14) D
	. I "0123456"[DAG S R=1
	. I '$L(DAG) S R=0
	I FREQ=30 D
	. I DAG>0&(DAG<32) S R=1
	. I DAG=99 S R=1
DAGZ	Q R
	;
FREQ(K)	;  Inputcontrole frequentie
	N R
	S $ZT="TRAP^cAN000"
	S R=0
	I "-,"[K&$L(K)!(";1;2;7;14;30;"[(U_(+K)_U))!(K>30&(K#60=0)&(K'>43200))!(K>58000) S R=1
FREQZ	Q R
	;
NSPC(K)	;  Inputcontrole op namespace(s)
	N R,STRING,I
	S $ZT="TRAP^cAN000"
	S R=1
	I '$L(K) S R=0 G NSPCZ
	I K="*" G NSPCZ
	S STRING=$$NSPC^cAFA9
	S STRING=U_$TR(STRING," ",U)_U
	F I=1:1:$L(K," ") D
	. I STRING'[(U_$P(K," ",I)_U) S R=0
NSPCZ	Q R
	;
PRIO(K)	;  Inputcontrole op prioriteit
	N R
	S $ZT="TRAP^cAN000"
	S R=0
	I '$L(K) G PRIOZ
	I K=0!(K=1)!(K="1-") S R=1
PRIOZ	Q R
	;
QWRD(K)	;  Inputcontrole op geldige Q-waarde
	N R,qq
	S $ZT="TRAP^cAN000"
	I '$L(K) S R=0 G QWRDZ
	S R=1
	S K=$$UC^cAFA1(K)
	S qq=^cLOG(boot,"Q",cs)
	S qq=U_$TR(qq,"\",U)_U
	I qq'[(U_K_U) S R=0
QWRDZ	Q R
	;
UUR(K)	;  Inputcontrole op geldig uur (Van: 00:00 tot 23:59)
	N R
	S $ZT="TRAP^cAN000"
	S R=0
	I '$L(K) G UURZ
	I K?2N1":"2N&($P(K,":")<24)&($P(K,":",2)<60) S R=1
	I K?2N1"."2N&($P(K,".")<24)&($P(K,".",2)<60) S R=1
UURZ	Q R
	;
YZ	Q
	;
ZZ	; 12.11.02 - 15 u 51 * V7.93