cAFO1	;Outputformaten ;%AFO1 ; [ 01/25/02  1:51 PM ]
	;
T0	;Outputformaten ;
	;
T0F	;Formats externes ;
	;
T0E	;Outputformaten ;
	;
T0D	;Outputformaten;
	;
	;-------------------------------------------------------------------
	; banknummer
BANK(K)
	S $ZT="TRAP^cAN000"
	N I,R,RL I $L(K) D
	. I $$IBAN^cAFI2(K) D  Q
	.. S R=K,K=""
	.. F I=1:4 Q:$L($E(R,I,(I+3)))=0   S K=$G(K)_$E(R,I,(I+3))_" "
	. S R=$P(K,"-"),RL=$P($G(@("^"_Q_"BA(39)")),D,3)
	. S:RL'?1.3U RL="BE" S:R'?1.3U R=RL I R?1.3U,R=RL,$D(^BA(6,R,2)) X "S K="_^(2)
	Q K
	;
	;-------------------------------------------------------------------
	; betalingstermijn
BET(K)
	S $ZT="TRAP^cAN000"
	N U3
	I K="" S U3=$P("contant#comptant#contant#in cash","#",QTU)
	I $L(K) S U3=K S:QT="F" U3=$TR(K,"DECW","JFDT")
	Q U3
	;
	;-------------------------------------------------------------------
	; BTW-nummer
BTW(K)
	S $ZT="TRAP^cAN000"
	N R,RL I $L(K) D
	. S R=$E(K,1,2),RL=$P($G(@("^"_Q_"BA(39)")),D,4)
	. S:RL'?2U RL="BE" S:R'?2U R=RL I R?2U,$D(^BA(5,R,2)) X "S K="_^(2)
	Q K
	;
	;-------------------------------------------------------------------
	; reconstructie "wat geprint"                 *** buiten gebruik ***
DLOG(R)
	S $ZT="TRAP^cAN000"
	N U3,UI1
	S R=^(R),U3=K,UI1=I1 I $L($P(R,D,10,99)) X $P(R,D,10,99)
	S K=$E(U3,1,$P(R,D,9))
	Q K
	;
	;-------------------------------------------------------------------
	; 1=ja / 0=neen
JN(K)
	S $ZT="TRAP^cAN000"
	N R
	S R=$P($P("neen#non#nein#no\ja#oui#ja#yes",D,K+1),"#",QTU)
	Q R
	;
	;-------------------------------------------------------------------
	; nummer, naam, adres, woonplaats of "geen"
KL(DMS,KC,OPTIE)
	; '$G(OPTIE): nr, naam, adres, woonplaats
	; OPTIE=1   : naam
	; OPTIE=2   : nr, naam
	S $ZT="TRAP^cAN000"
	N R,UQC,USC,UTOP
	S R=$$Z I $L(KC) D
	. D DMS^cAN000("UQC","USC",DMS)
	. I '$G(OPTIE) D TOP(UQC,USC,KC,1,101,102,105,107)
	. I $G(OPTIE)=1 D TOP(UQC,USC,KC,1,102)
	. I $G(OPTIE)=2 D TOP(UQC,USC,KC,1,101,102)
	. S R=UTOP(1.1)
	Q R
	;
	;-------------------------------------------------------------------
	; omschrijving kode of "geen"
KO(UQC,USC,UI1)
	S $ZT="TRAP^cAN000"
	N U3,UREF
	S U3=$$Z
	I $L(UI1) S UI1=$P(UI1," ")_" ",U3=UI1_"?" I $D(^DMC(UQC,USC)) D
	. S UREF=^DMC(UQC,USC,"DATA","REF") I $D(@UREF) S U3=$P(@UREF,D)
	Q U3
	;
	;-------------------------------------------------------------------
	; omschrijving kode of "geen"                 *** niet meer gebr.***
KODE(USC,UI1)
	S $ZT="TRAP^cAN000"
	N U3,UREF
	S U3=$$Z
	I $L(UI1) S UI1=$P(UI1," ")_" ",U3=UI1_"?" I $D(^DMC(0,USC)) D
	. S UREF=^DMC(0,USC,"DATA","REF")
	. I $D(@UREF) S U3=$P(@UREF,D)
	Q U3
	;
	;-------------------------------------------------------------------
	; omschrijving ISO-landcode
LAND(K)
	S $ZT="TRAP^cAN000"
	N L,R,TF,TL,UC
	S TF=$P(@("^"_Q_"BA(39)"),D,2),TL=$P(^(39),D,15),UC=$P(^(39),D,16)
	I TF="" S TF="N"    ; taalcode firma
	I TL="" S TL=TF     ; taalcode printen landcode
	S L=$G(^ISO(0,"ISO.LAND",+K,0))
	S R=$P(L,D,$S(TL="F":12,TL="D":22,TL="E":32,1:2))
	I R="" S R=$P(L,D,$S(TF="F":12,TF="D":22,TF="E":32,1:2))
	I R="" S R=$P(L,D,2)
	I UC S R=$$UC^cAFA1(R)
	Q R
	;
	;-------------------------------------------------------------------
	; niveau (0 = oper.   1 = b.g.   2 = verw.)
NIV(K)
	S $ZT="TRAP^cAN000"
	N R
	S R=$P($P("operationeel#opérationel#operationel#operational\buiten gebruik#hors usage#ausser Gebrauch#out of use\verwijderd#annulé#verwijderd#removed",D,K+1),"#",QTU)
	Q R
	;
	;-------------------------------------------------------------------
	; 0=onderdrukken / 1=weergeven
OW(K)
	S $ZT="TRAP^cAN000"
	N R
	S R=$P($P("onderdrukken#supprimer##suppress\weergeven#afficher##represent",D,K+1),"#",QTU)
	Q R
	;
	;-------------------------------------------------------------------
	; omschrijving in de taal van de gebruiker of geen        *** BG ***
PR(DMS,KC)
	S $ZT="TRAP^cAN000"
	N R,RQ2,UDD,UI1,UREF,UQC,USC
	D DMS^cAN000("UQC","USC",DMS)
	S R="" I $L(UQC),$L(USC),$D(^DMC(UQC,USC)) D
	. S UDD=^DMC(UQC,USC,"DATA"),UREF=^("DATA","REF"),RQ2=$G(^("OUD"))
	. I KC="" S R=$$Z
	. I $L(KC) S R=KC_" ?" D
	.. I UDD=1 S UI1=$G(@RQ2@(KC))
	.. I UDD=2 S UI1=KC_" "
	.. I UDD>2 S UI1=KC
	.. I $L(UI1),$D(@UREF) D
	... S R=$P(@UREF@(0),D,QTU-1*10+2)
	Q R
	;
	;-------------------------------------------------------------------
	; ruwe inhoud veld tonen
RAW(K)	
	S $ZT="TRAP^cAN000"
	S K="`"_$TR(K," ",$C(U("D","RT")))_"´" I K="" S K="<leeg>"
	Q K
	;
	;-------------------------------------------------------------------
	; opzetten UTOP
TOP(UQC,USC,KC,V,B1,B2,B3,B4,B5,B6,B7,B8,B9)
	S $ZT="TRAP^cAN000"
	N R,UDD,UI1,UREF
	S (UTOP(+V),UTOP(V+.1))="" I $L(UQC),$L(USC),$D(^DMC(UQC,USC)) D
	. S UDD=^(USC,"DATA"),UREF=^("DATA","REF"),UI1=KC I UDD<3 D
	.. I UDD=1 N Q2 S Q2=^("OUD"),UI1=$G(@Q2@(KC))
	.. I UDD=2 S UI1=KC_" "
	. S UTOP(+V)=$P(^DMC(UQC,USC,"TAAL",$E(QT_"N")),D),UTOP(V+.1)=KC_" ?"
	. I $L(UI1),UDD<5 S UTOP(V+.1)=$P($G(@UREF@(B1\100-1)),D,B1#100) D
	.. F R=2:1:9 Q:'$D(@("B"_R))  S UTOP(V+.1)=UTOP(V+.1)_" "_$P($G(^(@("B"_R)\100-1)),D,@("B"_R)#100)
	. I $L(UI1),UDD=5 S UTOP(V+.1)=$P($G(@UREF),D,B1#100) D
	.. F R=2:1:9 Q:'$D(@("B"_R))  S UTOP(V+.1)=UTOP(V+.1)_" "_$P($G(^(UI1)),D,@("B"_R)#100)
	. S UTOP(+V)=$$UC^cAFA1($E(UTOP(+V)))_$E(UTOP(+V),2,999)
	Q
	;
	;-------------------------------------------------------------------
	; 'R of onbestaand : "zonder"
	; R=1 : Alle
Z(R)
	S $ZT="TRAP^cAN000"
	S R=$P($P("zonder\aucun(e)\ohne\none#alle\tous\alle\all","#",$G(R)+1),D,QTU)
	Q R
	;
ZZ	; 22.06.04 - 16 u 32 * V8