cAFVBF02	;Ophalen omzetschermen, openstaande facturen ; cAFVBF02 [ 03/23/00  4:03 PM ]
	;
T1	;Totaal;Kwartaal;
T2	;Klant;Leverancier; bestaat niet.;
T3	;Firmacode is niet ingevuld.;
T4	;Select Text01, Text02, Text03, Text04, Text05, Text06, Text07, Text08, Text09, Text10, Text11, Text12 from Tech.Temp where +Text01 >= 10 and GridId = 
	;
T1F	;Total;Trimestre;
T2F	;Client;Fournisseur; n'existe pas.;
T3F	;Code d'entreprise n'est pas rempli.;
	;
T1E	;Total;Quarter;
T2E	;Customer;Supplier; does'nt exist.;
T3E	;Company Id is required.;
	;
YZ	Q
	;
BTEMP(I3,JRTEL,SRT,OMSCH,WAARDE)	
	S $P(^mtemp99(GRIDID,"COMMON",I3,0),D,1,2)=SRT_D_OMSCH
	I SRT'<10 S $P(^(0),D,JRTEL+2)=WAARDE Q
	S $P(^(2),D,JRTEL)=WAARDE
	Q
	;
BTMPOF(GRIDID,Q,USC,UI1)	  ; ophalen openstaande facturen
	; Q   = Q-waarde
	; USC = USC : bv KL.A
	; UI1 = key (intern nummer uit DKL)
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^dmTOOL("GRIDID,USC,UI1")     ; initialisatie variabelen + exclusieve new : N (%dmINIT,%Q1,D,DD,...A,B)
	D QT^cAFVBO01
	S D="\",U=";"
	S REF=$S(USC="KL.A":"DKL",1:"DLE")
	I '$L($G(Q)) S OK="0\"_$P($T(@("T3"_QT)),U,2) G BTMPOFZ
	S Q=$$DATA^cAFVBO01(REF,Q,USC,UI1,149)
	S UI1=$$DATA^cAFVBO01(REF,Q,USC,UI1,150) I '$L(UI1) S OK="0\"_$P($T(@("T2"_QT)),U,USC="LE"+2)_$P($T(@("T2"_QT)),U,4) G BTMPOFZ
	S USC=$P(USC,".")
	S GRIDID=$G(GRIDID)
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON") S OK=GRIDID
	S FNR=9999,KC=$P(UI1," ",2)
	F  S FNR=$O(@("^"_Q_USC_"(UI1,FNR)")) Q:FNR=""!(FNR>999999)  I FNR?6N D
	. S B=^(FNR)
	. S SAL=$P(B,D,5)-($S($P(B,D)="C":-1,1:1)*$P($G(@("^"_Q_"PV"_$S(USC="KL":"F",1:"A")_"(FNR,KC)")),D,2))
	. I 'SAL Q   ;  Enkel de openstaande facturen tonen
	. ; Berekenen veld overdue
	. S $P(B,D,41)=($$DH^cAFD1($P(B,D,3))>+$H)
	. ; Berekenen veld OverdueAmmountAccounting
	. I $P(B,D,41)=1 S $P(B,D,42)=""
	. I $P(B,D,41)=0 S $P(B,D,42)=$P(B,D,10)
	. ; Berekenen veld DateReleve
	. I $L($P(B,D,18)) S $P(B,D,43)=$P($G(^DATA(Q,"REL.H",$P(B,D,18),0)),D,3) 
	. I '$L($P(B,D,18)) S $P(B,D,43)=""
	. ; Berekenen DueDateReleve
	. I $L($P(B,D,18)) S $P(B,D,44)=$P($G(^DATA(Q,"REL.H",$P(B,D,18),0)),D,4) 
	. I '$L($P(B,D,18)) S $P(B,D,44)=""
	. I $P(B,D)="C" S $P(B,D,4)=-$P(B,D,4),$P(B,D,5)=-$P(B,D,5),$P(B,D,6)=-$P(B,D,6),$P(B,D,10)=-$P(B,D,10),$P(B,D,42)=-$P(B,D,42)
	. S K=$S($L($P(B,D,11))=8:"i",$P(B,D,8)="":"",$P(B,D,8):$P(B,D,8)#10,1:$TR($P(B,D,8),"0"," "))
	. S $P(B,D)=$TR($P(B,D),"W",$P("W#T","#",QTU))
	. S $P(B,D,8)=K  ; 
	. ; I $P(B,D,11)?2N1"."2N1"."2N S $P(B,D,45)=$P(B,D,11)
	. S ^mtemp99(GRIDID,"COMMON",FNR,0)=B
	. ; bedrag factuur in VM, openstaand in VM, korting contant in VM, openstaand in munt BH, vervallen in munt BH
	. S ^(2)=$P(B,D,4)_D_$P(B,D,5)_D_$P(B,D,6)_D_$P(B,D,10)_D_$P(B,D,42)
	. ; factuurdatum, vervaldatum, datum relevé,vervaldatum relevé, vervaldatum domiciliering
	. S ^(3)=$P(B,D,2)_D_$P(B,D,3)_D_$P(B,D,43)_D_$P(B,D,44)_D_$P(B,D,11)
BTMPOFZ	Q OK
	;
INH(R)	Q $S(R:$J(R,0,TAB(0,0,1)),1:"") ; afronden K
	;
OMZ(GRIDID,Q,USC,UI1)	  ; berekenen omzetschermen
	; Q   = Q-waarde
	; USC = USC : bv KL.A
	; UI1 = key (intern nummer uit DKL)
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^dmTOOL("GRIDID,USC,UI1")     ; initialisatie variabelen + exclusieve new : N (%dmINIT,%Q1,D,DD,...A,B)
	D QT^cAFVBO01
	S D="\",U=";",JR=DJ
	D BTMPCOM^cAFVBF03 I 'OK G OMZZ
	S OK=$P(OK,D)_D_$P($T(T4),U,2)_GRIDID
	D ^cT489  ; ophalen boekjaren
	S BBJR=J4,EBJR=J1
	S AJR=JR-J1
	I KM1(J1)#J1=KM1(J1) S AJR=AJR+1
	; Munt
	S I=$$MNTW^cAFE1(Q,DJ)
	S TAB(0,0,0)=$P(I,D)                    ; munt
	S TAB(0,0,1)=$P(I,D,3)                  ; aantal dec
	S TAB(0,0,2)=$$RAP^cAFO2                ; rap.periode als cijfer
	S BJR=JR,EJR=JR-AJR
	; Kalender maanden 
	F i=1:1:12 D 
	. S I=$G(^cBA(2,$E(QT_"N"),i)),I=$$UC^cAFA1($E(I))_$$LC^cAFA1($E(I,2,99))
	. S TAB(0,"KJM",i)=I						; Maanden
	. S TAB(0,"KJM-AFK",i)=$E(I,1,3)					; Maanden afgekort
	. S TAB(0,"KJM-LUC",i)=$S(QT="E":$E(I,1,3),1:$$LC^cAFA1($E(I,1,3)))	; Maanden afgekort met lower\upper case
	; Kalender kwartalen
	S KW=1 F i=1:3:12 S TAB(0,"KJKW",KW)=TAB(0,"KJM-AFK",i)_" - "_TAB(0,"KJM-LUC",i+2),KW=KW+1
	; Kalender sommatie kwartalen
	S TAB(0,"KJKW","1+2")=TAB(0,"KJM-AFK",1)_" - "_TAB(0,"KJM-LUC",6)
	S TAB(0,"KJKW","3+4")=TAB(0,"KJM-AFK",7)_" - "_TAB(0,"KJM-LUC",12)
	S TAB(0,"KJKW","1+2+3")=TAB(0,"KJM-AFK",1)_" - "_TAB(0,"KJM-LUC",9)
	S TAB(0,"KJKW","TOT")=TAB(0,"KJM-AFK",1)_" - "_TAB(0,"KJM-LUC",12)
	S TAB(0,"KJKW","TOTRAP")=TAB(0,"KJM-AFK",1)_" - "_TAB(0,"KJM-LUC",TAB(0,0,2))
	; Boekjaar kwartalen
	S KW=1,EBM=+$P(KM1(J4),".",2) F i=EBM:3 Q:KW>4  S TAB(0,"BJKW",KW)=TAB(0,"KJM-AFK",i)_" - "_TAB(0,"KJM-LUC",$S(i<=10:i+2,1:i-10)),KW=KW+1 S:(i>=10) i=i-12 
	; Boekjaar sommatie kwartalen
	S TAB(0,"BJKW","1+2")=TAB(0,"KJM-AFK",EBM)_" - "_TAB(0,"KJM-LUC",$S(EBM+5>12:(EBM+5)#12,1:EBM+5))
	S TAB(0,"BJKW","3+4")=TAB(0,"KJM-AFK",$S(EBM+6>12:(EBM+6)#12,1:EBM+6))_" - "_TAB(0,"KJM-LUC",$S(EBM+11>12:(EBM+11)#12,1:EBM+11))
	S TAB(0,"BJKW","1+2+3")=TAB(0,"KJM-AFK",EBM)_" - "_TAB(0,"KJM-LUC",$S(EBM+8>12:(EBM+8)#12,1:EBM+8))
	S TAB(0,"BJKW","TOT")=TAB(0,"KJM-AFK",EBM)_" - "_TAB(0,"KJM-LUC",$S(EBM+11>12:(EBM+11)#12,1:EBM+11))
	S TAB(0,"BJKW","TOTRAP")=TAB(0,"KJM-AFK",EBM)_" - "_TAB(0,"KJM-LUC",TAB(0,0,2))
	;
	S JRTEL=0 I BBJR>=DJ S JRTEL=1	   ; GM 18.02.05 JRTEL+1 indien BBJR niet kleiner dan DJ
	S HJRTEL=JRTEL,J1=UI1
	F JR=BJR:-1:EJR D
	. S TOT="",TEL=1
	. D BTEMP("KJM00",JRTEL,10,TAB(0,0,0),JR)
	. D BTEMP("KJK00",JRTEL,11,TAB(0,0,0),JR)
	. F i=1:1:12 D
	.. S R1=DJ-JR,R2=i+1,R3=USC D ^cANT25
	.. S TOT=TOT+K
	.. ; per maand kalenderjaar
	.. D BTEMP("KJM"_$TR($J(i,2)," ",0),JRTEL,0,TAB(0,"KJM",i),$$INH(K))
	.. ; per kwartaal
	.. I '(i#3) D
	... ; per kwartaal kalenderjaar
	... D BTEMP("KJK"_$TR($J(TEL,2)," ",0),JRTEL,1,TAB(0,"KJKW",TEL),$$INH(TOT))
	... S TOT=0,TEL=TEL+1
	. ; totaal maanden kalenderjaar
	. S R1=DJ-JR,R2="2\3\4\5\6\7\8\9\10\11\12\13",R3=USC D ^cANT25
	. D BTEMP("KJM99",JRTEL,0,"","")
	. D BTEMP("KJM999",JRTEL,0,$P($T(@("T1"_QT)),U,2),$$INH(K))
	. D BTEMP("KJK10",JRTEL,1,"","")
	. ; som kwartalen kalenderjaar
	. S R1=DJ-JR,R2="01 |06 ",R3=USC D 3^cANT25     ; 1+2
	. D BTEMP("KJK12",JRTEL,1,TAB(0,"KJKW","1+2"),$$INH(K))
	. S R1=DJ-JR,R2="07 |12 ",R3=USC D 3^cANT25     ; 3+4
	. D BTEMP("KJK34",JRTEL,1,TAB(0,"KJKW","3+4"),$$INH(K))
	. S R1=DJ-JR,R2="01 |09 ",R3=USC D 3^cANT25     ; 1+2+3
	. D BTEMP("KJK8123",JRTEL,1,"","")
	. D BTEMP("KJK9123",JRTEL,1,TAB(0,"KJKW","1+2+3"),$$INH(K))
	. S R1=DJ-JR,R2="01 |12 ",R3=USC D 3^cANT25     ; Totaal
	. D BTEMP("KJK99",JRTEL,1,"","")
	. D BTEMP("KJK999",JRTEL,1,TAB(0,"KJKW","TOT"),$$INH(K))
	. ; per kwartaal kalenderjaar en volgens rapporteringsmaand
	. S R1=DJ-JR,R2="01 |"_$E(100+$$RAP^cAFO2,2,3),R3=USC D 3^cANT25
	. D BTEMP("KJK001",JRTEL,1,TAB(0,"KJKW","TOTRAP"),$$INH(K))
	. ;
	. D BTEMP("KJK00101",JRTEL,1,"","")
	. S JRTEL=JRTEL+1
	; per kwartaal boekjaar
	S JRTEL=HJRTEL
	F JR=BBJR:-1:EBJR D
	. D BTEMP("BJK00",JRTEL,12,TAB(0,0,0),JR)
	. F KW=1:1:4 D
	.. S R1=JRTEL-1,R2=KW,R3=USC D 4^cANT25
	.. D BTEMP("BJK"_$TR($J(KW,2)," ",0),JRTEL,2,TAB(0,"BJKW",KW),$$INH(K))
	. ; per kwartaal boekjaar en volgens rapporteringsmaand
	. S R1=JRTEL-1,(MND,R2)=$$RAP^cAFO2,R3=USC D 5^cANT25
	. D BTEMP("BJK001",JRTEL,2,TAB(0,"BJKW","TOTRAP"),$$INH(K))
	. D BTEMP("BJK00101",JRTEL,2,"","")
	. D BTEMP("BJK10",JRTEL,2,"","")
	. S R1=JRTEL-1,R2="1\2",R3=USC D 4^cANT25        ; 1+2
	. D BTEMP("BJK12",JRTEL,2,TAB(0,"BJKW","1+2"),$$INH(K))
	. S R1=JRTEL-1,R2="3\4",R3=USC D 4^cANT25        ; 3+4
	. D BTEMP("BJK34",JRTEL,2,TAB(0,"BJKW","3+4"),$$INH(K))
	. S R1=JRTEL-1,R2="1\2\3",R3=USC D 4^cANT25      ; 1+2+3
	. D BTEMP("BJK8123",JRTEL,2,"","")
	. D BTEMP("BJK9123",JRTEL,2,TAB(0,"BJKW","1+2+3"),$$INH(K))
	. S R1=JRTEL-1,R2=0,R3=USC D 2^cANT25            ; Totaal
	. D BTEMP("BJK99",JRTEL,2,"","")
	. D BTEMP("BJK999",JRTEL,2,TAB(0,"BJKW","TOT"),$$INH(K))
	. S JRTEL=JRTEL+1
OMZZ	Q OK
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09