cAN1012	;Productenscroll ;%AN101 ; [ 03/22/01  10:34 AM ]
	G 1
	;
T0	;Productenscroll ;
	;
T0F	;'Scroll' de produits ;
	;
T0E	;Productscroll ;
	;
	; ophalen parameters
1	N I,INIT,INIT1,LEN,OMS,PAR,PDP,SCR,TAB,MNT
11	S PAR=@("^"_Q_$G(UPRDMS,"PR")_"(0,19)"),OMS=^(90)
13	S LEN=$P(PAR,D,36),PDP=$P(PAR,D,2),MNT=$P(PAR,D,61)
15	I $D(UPRM) D                                           ; vanuit %FN
	. S RSCONF=$P(UPRM,D,46),SCR=$P(UPRM,D,58)
	. S MNT=$P($G(U5),D,18)
	I '$L(MNT) S MNT=$$BF^cAFA1
	S PDP=$$DECVM^cAFE5(MNT)  ; naar analogie met prijslijst
16	I '$D(UPRM) D                                          ; raadplegen
	. S RSCONF=$P(PAR,D,17),SCR=$P(PAR,D,24)
17	I RSCONF=2 S RSCONF=RSCONF(70)
19	S I=0 F  S I=$O(@("^"_Q_"BA(""%H"",2,I)")) Q:I=""  D   ; incl/excl
	. S K=^(I),TAB($P(K,D,3))=$P(K,D,2)
	;
	; productcode & omschrijving
2	S K=$E($P(@RSREF@(0),D)_$J("",LEN),1,LEN)_" "
21	S OMS=$P(OMS,D,QTU),OMS=$P(^(OMS\100-1),D,OMS#100)
23	I OMS="" S OMS=$P(^(0),D,2)
25	S K=K_OMS
27	S INIT="UI" I $D(^DATA(0,"USR")) S INIT="USR"
29	S INIT1=$$UI1^cAFA1(INIT,101,QU)
	;
	; samenstellen K = lijn in de scroll
3	I SCR=1 D
	. S K=$E(K_$J("",40),1,40)_" "
	. D S1(114,7)            ; stock
	. D S2(107,9,TAB(107))   ; verk.prijs
	. D S1(117,7)            ; besteld
	. D S1(309,7)            ; orders
32	I SCR=2 D
	. S K=$E(K_$J("",39),1,39)_" "
	. S OMS=$P(@RSREF@(0),D,6)
	. I $L(OMS) S OMS=$E(OMS,1,2)_"."_$E(OMS,3,4)_"."_$E(OMS,5,6)
	. S K=K_$E(OMS_$J("",8),1,8)_" "
	. D S1(114,5)            ; stock
	. D S2(107,7,TAB(107))   ; verk.prijs
	. D S1(117,5)            ; besteld
	. D S1(309,5)            ; orders
33	I SCR=3 D
	. S K=$E(K_$J("",48),1,48)_" "
	. D S1(114,5)            ; stock
	. D S2(107,7,TAB(107))   ; verk.prijs
	. D S1(117,5)            ; besteld
	. D S1(309,5)            ; orders
34	I SCR=4 D
	. S K=$E(K_$J("",40),1,40)_" "
	. D S1(114,5)            ; stock
	. D S2(107,7,0)          ; verk.prijs
	. D S2(107,7,1)          ; INCL.BTW
	. D S1(117,5)            ; besteld
	. D S1(309,5)            ; orders
35	I SCR=5 D
	. S K=$E(K_$J("",40),1,40)_" "
	. D S1(114,7)            ; stock
	. I $$SIG^cAFA1(INIT,INIT1,218) S K=K_$J("",9)
	. E  D S2(119,9,0,"A")   ; aank.prijs
	. D S1(117,7)            ; besteld
	. D S1(309,7)            ; orders
36	I SCR=6 D
	. S K=$E(K_$J("",32),1,32)_" "
	. S OMS=$P(@RSREF@(4),D)
	. S K=K_$E(OMS_$J("",15),1,15)_" "
	. D S1(114,5)            ; stock
	. D S2(107,7,TAB(107))   ; verk.prijs
	. D S1(117,5)            ; besteld
	. D S1(309,5)            ; orders
37	I SCR=7 D  G YZ
	. S K=$E(K_$J("",40),1,40)_" "
	. D S3(312,10)           ; formaat
	. D S3(212,2)            ; eenheid
	. D S2(107,9,TAB(107))   ; verk.prijs
	. D S3(104,3)            ; kort.code
	. D S3(417,1)            ; status
	. D S1(324,5)            ; datum volgende levering
38	I SCR=8 D
	. N KLSTK
	. S K=$E(K_$J("",40),1,40)_" "
	. D S1(114,6)            ; stock
	. S KLSTK=$$KLSTK^cAFA3($G(UI1))
	. S K=K_$J(KLSTK,6)_" "  ; klantenstock
	. D S2(107,7,TAB(107))   ; verk.prijs
	. D S1(117,5)            ; besteld
	. D S1(309,5)            ; orders
	;
	; E = equivalente producten
4	S K=$E(K_$J("",76),1,76),OMS=" "
41	F I=1:1:5 I $P($G(@RSREF@(3)),D,I) S OMS="E" Q
43	S K=K_OMS
	;
	; R = vervangend product
5	S K=$E(K_$J("",77),1,77),OMS=" "
51	I $P($G(@RSREF@(0)),D,23) S OMS="R"
53	S K=K_OMS
	;
YZ	Q
	;
	; element rechts uitlijnen
S1(I,L)	S OMS=$P(@RSREF@(I\100-1),D,I#100),K=K_$J(OMS,L)_" "
S1Z	Q
	;
	; prijs, excl/incl, (afronden op PDP)
S2(I,L,INCL,SP)	
	S OMS=$P(@RSREF@(I\100-1),D,I#100)
	I '$L(OMS) G S2Y
	S OMS=$$EP^cAFA30(Q,OMS,INCL,$P(^(0),D,5),"",$G(MNT),I,$G(SP,"V"),$G(UPRDMS,"PR"))
	S OMS=$$OUT^cAFE5(OMS,PDP,$G(SP,"V"),$G(UPRDMS,"PR"),1)
	S OMS=$TR($$IPL^cAFO3($P(OMS,D),0,$P(OMS,D,2),1),",",".")
	; I INCL D
	; . N R S R=$P(^(0),D,5)#10 I '$D(PBTW(R)) D S1^cA305
	; . S R=$G(PBTW(R#10))+100/100,OMS=$J(OMS*R,0,QD)
	; ;S K=K_$S(OMS:$J(OMS,L,PDP),1:$J("",L))_" "
S2Y	S K=K_$S(OMS:$J(OMS,L),1:$J("",L))_" "
S2Z	Q
	;
	; element links uitlijnen
S3(I,L)	S OMS=$P(@RSREF@(I\100-1),D,I#100),K=K_$E(OMS_$J("",L),1,L)_" "
S3Z	Q
	;
ZZ	; 30.03.01 - 13 u 39 * V7.85