cANIMP12	;Beheer Excel lay-outs; cANIMP10
	;
T0	;Beheer Excel lay-outs ;
T1	;Omschrijving                      Commentaar;
T2	;------------                      ----------;
T3	;Kolom;
T4	;xx[] = wijzigen kolom xx   [] = bijvoegen kolom   ;D[] = detail;.[] = vervolg;
T5	;Vx[] = verwijderen kolom;
T6	;Te verwijderen kolom;
T7	;Verwijderen kolom ;",[] = hernemen   V[] = DEFINITIEF verwijderen";
T8	;Geen betekenis;
	;
T0F	;Gestion mise en pages Excel ;
T1F	;Description                       Rubrique;
T2F	;------------                      --------;
T3F	;Colonne;
T4F	;xx[] = modifier colonne xx   [] = ajouter colonne   ;D[] = détail;.[] = suite;
T5F	;Vx[] = annuler colonne x;
T6F	;Colonne à annuler;
T7F	;Annulation colonne ;",[] = reprendre   V[] = annulation DEFINITIVE";
T8F	;Sans signification;
	;
1	W /CUP(1,1),/WCMD,/CUP(1,KMAX-$L(OM)-1),OM
10	W /CUP(2,6),$P($T(@("T1"_QT)),U,2),/CUP(3,6),$P($T(@("T2"_QT)),U,2)
11	S J2=1
13	S LN=LMIN+2 W /CUP(LN,1),/WCMD
15	F UZB=J2:1 Q:'$D(@UREF@(UZB))  D  S LN=LN+1 Q:LN>LMAX
	. W /CUP(LN,1),$J(UZB,3),". ",$P(@UREF@(UZB),D)
	. S COM=$$COM(UQAA,USAA,$P(@UREF@(UZB),D,2),$P(@UREF@(UZB),D,10),$P(@UREF@(UZB),D,11))
	. W /CUP(LN,40),COM
17	S SWV=0 I $D(@UREF@(UZB+1)) S SWV=1,J2=UZB
19	I '$D(@UREF@(1)) G YZ:K="-",3
	I KEU="Y" G 3^cANIMP14
	;
	; vraagstelling
2	S R="K\22\3\"_$P($T(@("T3"_QT)),U,2)_"\C1\3\INPUT\\\\1" D R0
21	G YZ:K="-"!(K=","),11:K="D",13:K=".",3:K="",4:K,5:$E(K)="V",2
	;
	; openen
3	S UZB=$O(@UREF@(""),-1)+1
31	D ^cANIMP13 G 1
	;
	; wijzigen
4	I '$D(@UREF@(+K)) G 2
41	S UZB=+K D ^cANIMP13 G 1
	;
	; verwijderen
5	S UZB=+$E(K,2,3) I UZB,$D(@UREF@(UZB)) G 53
51	S R="UZB\22\3\"_$P($T(@("T6"_QT)),U,2)_"\\2\\K=""-""!(K="","")!(K?.N)" D R0 G 2:K="-"!(K=","),51:'$D(@UREF@(+UZB))
53	S R="K\22\3\"_$P($T(@("T7"_QT)),U,2)_UZB_D_$P($T(@("T7"_QT)),U,3)_"\1\\""-,V""[K&$L(K)\\\1" D R0 I K'="V" S (UZB,SWV)=0 G 51
55	K @UREF@(UZB)
57	F  S UZB=$O(@UREF@(UZB)) Q:UZB=""  D
	. M @UREF@(UZB-1)=@UREF@(UZB) K @UREF@(UZB)
59	G 1
	;
YZ	G Y^cANIMP11
	;
C1	W !?2,$P($T(@("T4"_QT)),U,2),$P($T(@("T4"_QT)),U,3+SWV),!?2,$P($T(@("T5"_QT)),U,2) Q
	;
INPUT	;K="-"!(K=",")!(K="D")!(K="."&SWV)!(K?.N)!(K?1"V".N)
	;
COM(UQA,USA,BIND,DMS,BIND2)	;  Opzoeken Commentaar via B-index en DMA
	N BLZ,RUBR,SWOK,R,UQC,USC,I1
	S $ZT="TRAP^cAN000"
	S SWOK=0
	S R=""
	I '$L(BIND) S R=$P($T(@("T8"_QT)),U,2) G COMZ
	S BLZ=0
	F  S BLZ=$O(^DMA(UQA,USA,BLZ)) Q:BLZ=""  D  Q:SWOK
	. S RUBR=""
	. F  S RUBR=$O(^DMA(UQA,USA,BLZ,RUBR)) Q:RUBR=""  D  Q:SWOK
	.. I $P($G(^(RUBR,16)),D)=BIND S R=$P(^(1),D,QTU) S SWOK=1
	I '$L(DMS) G COMZ
	D DMS^cAN000("UQC","USC",DMS)
	I '$L(UQC)!'$L(USC) G COMZ
	S I1="",SWOK=0
	F  S I1=$O(^DMC(UQC,USC,"INDEX",I1)) Q:I1=""  D  Q:SWOK
	. I $P(^(I1),D)'=BIND2 Q
	. S SWOK=1
	. S R=R_" / "_^(I1,"TAAL",$S(QT="":"N",1:QT))
COMZ	Q R
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
ZZ	; 23.06.05 - 17 u 03 * V8.04