cANTA79	;Saldo raadplegen rekening-analytische rekening ;cANTA79 ;
	;
T0	;Saldo raadplegen rekening-analytische rekening  ;
	;
T0F	;Consultation solde du compte-compte analytique ;
	;
	;CANTA79.int wordt opgeroepen door velden van ^DMA(0,"AR.ARA.BUD") ["RIPA1"]
	; R1 =  Aanduiding van boek/kalenderjaar
	; R2 =  nummer van de te berekenen maand - formaat voor meerdere maanden zoals TOTAAL: 1\2\3\....\11\12
	; R3 =  steeds "AR" , z.b.   
	; R4 =  B-Beginsaldo (Realisatie) ; G-beGinsaldo (Budget) ; D-beginsalDo (Evaluatie) ; S-Saldo (Realisatie) ; T-budgeT ; E-Evaluatie
	;
	; per kalenderjaar/maand (DMA schermen 1/8 , 2/8 , 3/8 , 7/8 , 8/8)
1	S $ZT="TRAP^cAN000"
11	N R,RS0,SALDO,UI1AR,UI1ARA S K=0 I $L($G(J1)),$D(R1),$D(R2),$D(R4) S UI1AR=$P(J1," ")_" ",UI1ARA=$P(J1," ",2)_" " F R=1:1:$L(R2,D) D S1
12	G Y
	;
S1	S RS0=(DJ-R1)*100+$P(R2,D,R) 
S1A	S SALDO="" S:("ES"[R4) SALDO=$$GDBHSAL("CUM.AR.ARA",RS0,UI1AR,UI1ARA)
S1B	S:$L(SALDO) K=K+SALDO
S1C	S SALDO="" S:("ET"[R4) SALDO=$$GDBHSAL("BUD.AR.ARA",RS0,UI1AR,UI1ARA)
S1D	S:$L(SALDO) K=(R4="T")*2-1*SALDO+K
S1Z	Q
	;
	; per boekjaar : (R2 : z.b.)  Beginsal. (R4:B,G,D)  en Tot sal. (R4:S/T/E)  (DMA schermen 4/8 , 5/8 , 6/8)
2	S $ZT="TRAP^cAN000"
21	N RS0,SALDO,BEGSALDO,UI1AR,UI1ARA S K=0 I $L($G(J1)),$D(R1),$D(R4) S UI1AR=$P(J1," ")_" ",UI1ARA=$P(J1," ",2)_" " D ^cT489 D S2
22	G Y
	;
S2	S RS=DJ-R1
	; S BEGSALDO="" S:("BDSE"[R4) BEGSALDO=$$GDBHBEG("CUM.AR.ARA",RS,UI1AR,UI1ARA)
S2A	S BEGSALDO="" S:("BDSE"[R4) BEGSALDO=$$SALDO^cTA180(Q,UI1AR,UI1ARA,0,$G(KM1(RS)),"CUM.AR.ARA",0)
S2B	S:$L(BEGSALDO) K=BEGSALDO
	; S BEGSALDO="" S:("GDTE"[R4) BEGSALDO=$$GDBHBEG("BUD.AR.ARA",RS,UI1AR,UI1ARA)
S2C	S BEGSALDO="" S:("GDTE"[R4) BEGSALDO=$$SALDO^cTA180(Q,UI1AR,UI1ARA,0,$G(KM1(RS)),"BUD.AR.ARA",0)
S2D	S:$L(BEGSALDO) K=((R4="T")!(R4="G"))*2-1*BEGSALDO+K
S2E	F RS0=$G(KM1(RS)):0.01:$G(KM2(RS)) D 
S2F	. S RS0=$E((RS0_0),1,7) I (RS0#1)>.12 S RS0=RS0+.88
S2G	. S SALDO="" S:("SE"[R4) SALDO=$$GDBHSAL("CUM.AR.ARA",RS0*100,UI1AR,UI1ARA)
S2H	. S:$L(SALDO) K=K+SALDO
S2I	. S SALDO="" S:("TE"[R4) SALDO=$$GDBHSAL("BUD.AR.ARA",RS0*100,UI1AR,UI1ARA)
S2J	. S:$L(SALDO) K=(R4="T")*2-1*SALDO+K
S2Z	Q
	;
	; per kwartaal boekjaar : Saldo Kwartaal 1 tot 4 + subtotalen  (DMA schermen 4/8 , 5/8 , 6/8)
4	S $ZT="TRAP^cAN000"
41	N R,RS,RSB,RSE,RS0,SALDO,UI1AR,UI1ARA S K=0 I $L($G(J1)),$D(R1),$D(R2),$D(R4) S UI1AR=$P(J1," ")_" ",UI1ARA=$P(J1," ",2)_" " D ^cT489 F R=1:1:$L(R2,D) D S4
42	G Y
	;
S4	S RS=DJ-R1 
S4A	S RSB=($P(R2,D,R)-1)*.03+$G(KM1(RS)) S RSB=$E((RSB_0),1,7) I (RSB#1)>.12 S RSB=RSB+.88
S4B	S RS0=RSB
S4C	S RSE=($P(R2,D,R)-1)*.03+$G(KM1(RS))+.02 S RSE=$E((RSE_0),1,7) I (RSE#1)>.12 S RSE=RSE+.88 
S4D	I RS0'>RSE,RS0'>$G(KM2(RS)) D
S4E	. S SALDO="" S:("SE"[R4) SALDO=$$GDBHSAL("CUM.AR.ARA",RS0*100,UI1AR,UI1ARA)
S4F	. S:$L(SALDO) K=K+SALDO
S4G	. S SALDO="" S:("TE"[R4) SALDO=$$GDBHSAL("BUD.AR.ARA",RS0*100,UI1AR,UI1ARA)
S4H	. S:$L(SALDO) K=(R4="T")*2-1*SALDO+K
S4I	. S RS0=RS0+.01 S RS0=$E((RS0_0),1,7) I (RS0#1)>.12 S RS0=RS0+.88 
S4J	. G S4D
S4Z	Q
	;
	; Saldo t.e.m. referentie-maand (R2=$$RAP^cAFO2), (R4:S/T/E) (DMA schermen 4/8 , 5/8 , 6/8)  
5	S $ZT="TRAP^cAN000"
51	N RS,RSE,RS0,SALDO,BEGSALDO,UI1AR,UI1ARA S K=0 I $L($G(J1)),$D(R1),$D(R2),$D(R4) S UI1AR=$P(J1," ")_" ",UI1ARA=$P(J1," ",2)_" " D ^cT489 D S5
52	G Y
	;
S5	S RS=DJ-R1 S RSE=$E((((DJ-R1)+($P(R2,D)/100))_"0"),1,7) 
	; S BEGSALDO="" S:("SE"[R4) BEGSALDO=$$GDBHBEG("CUM.AR.ARA",RS,UI1AR,UI1ARA)
S5A	S BEGSALDO="" S:("SE"[R4) BEGSALDO=$$SALDO^cTA180(Q,UI1AR,UI1ARA,0,$G(KM1(RS)),"CUM.AR.ARA",0)
S5B	S:$L(BEGSALDO) K=BEGSALDO
	; S BEGSALDO="" S:("TE"[R4) BEGSALDO=$$GDBHBEG("BUD.AR.ARA",RS,UI1AR,UI1ARA)
S5C	S BEGSALDO="" S:("TE"[R4) BEGSALDO=$$SALDO^cTA180(Q,UI1AR,UI1ARA,0,$G(KM1(RS)),"BUD.AR.ARA",0)
S5D	S:$L(BEGSALDO) K=(R4="T")*2-1*BEGSALDO+K
S5E	F RS0=$G(KM1(RS)):0.01:RSE D 
S5F	. S RS0=$E((RS0_0),1,7) I (RS0#1)>.12 S RS0=RS0+.88
S5G	. S SALDO="" S:("SE"[R4) SALDO=$$GDBHSAL("CUM.AR.ARA",RS0*100,UI1AR,UI1ARA)
S5H	. S:$L(SALDO) K=K+SALDO
S5I	. S SALDO="" S:("TE"[R4) SALDO=$$GDBHSAL("BUD.AR.ARA",RS0*100,UI1AR,UI1ARA)
S5J	. S:$L(SALDO) K=(R4="T")*2-1*SALDO+K
S5Z	Q
	;
	; tonen boekjaren op scherm ; code identiek aan label 6 tot 69 in programma cANT79
6	S $ZT="TRAP^cAN000"
	S RS0=DJ_"."_DM
61	S RS2=@("^"_Q_"BA(2)"),RS1=$G(^(26))
63	S RS4=$P(RS2,D,2) I RS0>RS4 S RS1=RS1+1,RS3=RS4\1*12+(RS4#1*100)_D_$E(RS4+1_0,1,7)_D_RS4_D,RS2=RS3_RS2
65	I RS1<5 S RS3=$P(RS2,D,RS1+1*3),RS4=$E(RS3-1_0,1,7),RS2=RS2_D_(RS4\1*12+(RS4#1*100))_D_RS3_D_RS4,RS1=RS1+1 G 65
67	F RS1=1:1:5 S RS4=$P(RS2,D,RS1*3-1)\1 W /CUP(U2(2),79-(RS1*13)+8),/SGR(4),RS4,/SGR(0)
69	K RS0,RS1,RS2,RS3,RS4 Q
	;
Y	S R=$$BJ^cAFE1(Q,DJ_"."_DM),QDR=$P($$MNTW^cAFE1(Q,R),D,3) 
YZ	K R1,R2,R3,R4 Q
	;
GDBHBEG(GLSUB,BJAAR,I1,I2)	      ; Ophalen beginsaldo van actieve records in ^DBH : combinatie grootboekrek.-anal. rekening
	N BEGSAL,RETSTR   
	S $ZT="TRAP^cAN000"
	S BEGSAL=""
	S RETSTR=$G(^DBH(Q,GLSUB,BJAAR_"00 "_I1_I2_"0 0",0)) ;I1 , I2 doorgeven met spatie achteraan 
	I $L($G(RETSTR)) G GDBHBEGZ
	I $P($G(RETSTR),D,30) G GDBHBEGZ
	S BEGSAL=$P(RETSTR,D,10)
GDBHBEGZ	Q BEGSAL
	;
GDBHSAL(GLSUB,HMAAND,I1,I2)	; Ophalen saldo van actieve records in ^DBH : combinatie grootboekrek.-anal. rekening
	N SAL,RETSTR  
	S $ZT="TRAP^cAN000"
	S SAL=""
	S RETSTR=$G(^DBH(Q,GLSUB,HMAAND_" "_I1_I2_"0 0",0))  ;I1 , I2 doorgeven met spatie achteraan 
	I '$L($G(RETSTR)) G GDBHSALZ
	I $P($G(RETSTR),D,30) G GDBHSALZ
	S SAL=$P(RETSTR,D,6)-$P(RETSTR,D,7)
GDBHSALZ	Q SAL
	;
ZZ	; 23.06.05 - 17 u 03 * V8.04