cI39 ;Conversie ivm J-2000 ;%I39 ; [ 03/27/00  12:33 PM ]
 ;
T1 ;Dit programma converteert:;
T2 ;a) L-lijnen bij producten: "Ljjmmdd(vvv)" naar "Ljjjjmmdd(vvv)";
T3 ;b) Globals boekhouding: K3, K4, K6 en L3 op 2' index;
T8 ;Q-waarde(s) <;
T9 ;Start <N>;
 ;
 ; init + uitleg
1 S Q=$G(Q) D ^cA604,MASTER^cQ5:'$D(boot)
11 w !!,$P($T(+1),U,2),!!
13 f i=1:1 s j=$p($t(@("T"_i)),U,2) q:j=""  w j,!
 ;
 ; vraagstelling
2 s qq=$g(^cLOG("Q"),Q) i $d(boot) s qq=$g(^cLOG(boot,"Q"),qq)
21 i $p(qq,D)="SYS" s qq=$p(qq,D,2,999)
23 i qq[D s qq=$tr(qq,D," ")
25 w !,$p($t(T8),U,2),qq,">" r k g YZ:k="-"!(k="^") i $l(k) s qq=k g 25
27 w !,$p($t(T9),U,2) r k g 25:"-^"[k&$l(k) s k=$tr(k,"JjYy1","11110") g 27:k'=1
 ;
3 ; aflopen Q-waardes
31 s Q=$p(qq," "),qq=$p(qq," ",2,999) i Q'?1.3U g 31:$l(qq),YZ
33 w !,Q,?5,$g(@("^"_Q_"BA(99,1)"),"?"),?40
 ;
 ; boekhouding
4 f g="K3","K4","K6","L3" d
 . w " ",g
 . s i="" f  s i=$o(@("^"_Q_g)@(i)) q:i=""  d
 .. s j="" f  s j=$o(@("^"_Q_g)@(i,j)) q:j=""  i j?6n d
 ... w "." s jj=$$DCO^cAFD1(j),jj=$$DC^cAFD1(jj)
 ... s @("^"_Q_g)@(i,jj)=@("^"_Q_g)@(i,j)
 ... s x="" f  s x=$o(@("^"_Q_g)@(i,j,x)) q:x=""  d
 .... s y="" f  s y=$o(@("^"_Q_g)@(i,j,x,y)) q:y=""  d
 ..... s @("^"_Q_g)@(i,jj,x,y)=@("^"_Q_g)@(i,j,x,y)
 ... k @("^"_Q_g)@(i,j)
 ;
 ; producten
5 w " PR" s pr=0 f  s pr=$o(@("^"_Q_"PR(pr)")) q:pr=""  d
 . s i=$o(^(pr,"L")) i $e(i)'="L" q
 . s sw=0 k ^HULP(boot,$J)
 . s i="L" f  s i=$o(@("^"_Q_"PR(pr,i)")) q:$e(i)'="L"  d
 .. s k=^(i),^HULP(boot,$J,i)=k
 .. i i?1"L"6N!(i?1"L"9N) d
 ... s j=$$DCO^cAFD1($e(i,2,7)),j="L"_$$DC^cAFD1(j)_$e(i,8,10)
 ... s sw=1,^(j)=^(i) k ^(i)
 . i sw w "." d
 .. s i="L" f  s i=$o(@("^"_Q_"PR(pr,i)")) q:$e(i)'="L"  k ^(i)
 .. s i="" f  s i=$o(^HULP(boot,$J,i)) q:i=""  d
 ... s k=^(i),@("^"_Q_"PR(pr,i)")=k
51 w " TL" s kc=0 f  s kc=$o(@("^"_Q_"TL(kc)")) q:kc=""  d
 . s us="" f  s us=$o(@("^"_Q_"TL(kc,us)")) q:us=""  d
 .. s ur="" f  s ur=$o(@("^"_Q_"TL(kc,us,ur)")) q:ur=""  d
 ... s pr="" f  s pr=$o(@("^"_Q_"TL(kc,us,ur,pr)")) q:pr=""  d
 .... s (i,sw)=0 f  s i=$o(@("^"_Q_"TL(kc,us,ur,pr,i)")) q:i=""  d
 ..... s k=^(i)
 ..... i k?1"L"6N!(k?1"L"9N) d
 ...... s j=$$DCO^cAFD1($e(k,2,7)),j="L"_$$DC^cAFD1(j)_$e(k,8,10)
 ...... s sw=1,^(i)=j
 .... i sw w "."
53 w " ULL" s pr=0 f  s pr=$o(@("^"_Q_"ULL(pr)")) q:pr=""  d
 . s (sw,x)=0 f  s x=$o(@("^"_Q_"ULL(pr,x)")) q:x=""  d
 .. s i="" f  s i=$o(@("^"_Q_"ULL(pr,x,i)")) q:i=""  d
 ... i i?1"L"6N!(i?1"L"9N) d
 .... s j=$$DCO^cAFD1($e(i,2,7)),j="L"_$$DC^cAFD1(j)_$e(i,8,10)
 .... s sw=1,^(j)=^(i) k ^(i)
 . i sw w "."
59 g 31
 ;
YZ w ! Q
 ;
ZZ ; 10.04.00 - 11 u 03 * V7.3