cI39E4 ;Instellen P4 (euro) ;%I39E ; [ 12/16/98  5:03 PM ]
 ;
T0 ;Instellen P4 (euro) ;
T1 ;Conversie naar euro.;
T2 ;Bent u zeker dat u een veiligheidskopie heeft genomen\".[] = ja";
T3 ;NA deze conversie is er geen weg terug!;
T4 ;Deze conversie beslaat ; firma;'s;
T5 ;Het programma test eerst of er geen belemmeringen zijn.;
T6 ;Bevestiging\".[] = doorgaan";
T7 ;Fout in conversiebestand ;
T8 ;De conversie kan niet worden uitgevoerd ;
T9 ;De conversie werd niet volledig uitgevoerd ;
T10 ;De conversie werd correct uitgevoerd ;
T11 ;Alle financiële verrichtingen (bankuittreksels) moeten geboekt zijn.;
T12 ;Oude betalingsopdrachten (financieel: O[]) worden verwijderd.;
T13 ;Geschatte duurtijd : ;Start : ;Einde : ;
 ;
T0F ;Instellen P4 (euro) ;
T1F ;Conversion pour euro.;
T2F ;Vous confirmez que vous avez pris une copie de sauvegarde\".[] = oui";
T3F ;Vous ne pouvez pas retourner APRES cette conversion!;
T4F ;Cette conversion concerne ; firme;s;
T5F ;Le programme contrôle d'abord s'il y a des anomalies.;
T6F ;Confirmation\".[] = continuer";
T7F ;Erreur dans le fichier de conversion ;
T8F ;La conversion ne peut pas être exécutée ;
T9F ;La conversion n'était pas exécutée complètement ;
T10F ;La conversion est exécutée correcte ;
T11F ;Tous les opérations financières (extraits) doivent être comptabilisées.;
T12F ;Vieux paiements globals (financier: O[]) seront radiés.;
T13F ;Durée estimée : ;Début : ;Fin : ;
 ;
 ; init + uitleg
1 D T^cA612($P($T(@("T1"_QT)),U,2),2,0,7,1,1)
11 S R="K\22\3\"_$P($T(@("T2"_QT)),U,2)_"\1\\K="".""!(K=""-"")" D R0 G YZ:K="-"
13 W /CUP(4,2),@F92,$P($T(@("T3"_QT)),U,2),@F93,@F1
15 L ^HULP("EURO",Q):2 E  D TXT^cAFA1(14) G YZ
 ;
 ; firma's ophalen
2 K A,B S HULPI1="EURO",HULPI2=Q,HULPI3="A",HULPI4="",A=0
21 S HULPI4=$O(^HULP(HULPI1,HULPI2,HULPI3,HULPI4)) I HULPI4="" G 3
23 S K=^(HULPI4),Q=$P(K,D),P=$P(K,D,2)
25 I Q=""!(P="") S K=$P($T(@("T7"_QT)),U,2)_$ZR D TXT^cAFA1(250) G Y
27 I '$D(B(Q)) S A=A+1,A(A)=Q,B(Q)=A
29 G 21
 ;
 ; firma's tonen
3 I HULPI3="A" S HULPI3="B" G 21
31 S I=$T(@("T4"_QT)) W /CUP(6,3),$P(I,U,2),A,$P(I,U,3) I A>1 W $P(I,U,4)
33 S I=7,J=3,M=40 I A>20 S M=25 I A>30 S M=20
35 F B=1:1:A W /CUP(I,J),$J(B,2),". ",$E(@("^"_A(B)_"BA(99,1)"),1,M-7) S I=I+1 I I>16 S I=7,J=J+M
37 K A,B
 ;
 ; testen uitvoeren
4 W /CUP(20,2),@F92,$P($T(@("T5"_QT)),U,2),@F93
41 S R="K\22\3\"_$P($T(@("T6"_QT)),U,2)_"\1\\K=""-""!(K=""."")" D R0 G Y:K="-"
43 S HULPI3="A",HULPI4=""
45 S HULPI4=$O(^HULP(HULPI1,HULPI2,HULPI3,HULPI4)) I HULPI4="" G 5
47 S K=^(HULPI4),Q=$P(K,D),P=$P(K,D,2),QD=+$G(@("^"_Q_"BA(34)")),QN=^(99,1),FOUTCODE=1 W /CUP(22,3),HULPI4,@F1
48 D ^cA106,^cA105 S ^HULP(HULPI1,HULPI2,HULPI3,HULPI4,"BEGIN")=DT_D_TD_D_$H_D_QU K ^("EINDE"),^("FOUT") D @P
49 D ^cA106,^cA105 S ^HULP(HULPI1,HULPI2,HULPI3,HULPI4,"EINDE")=DT_D_TD_D_$H_D_QU_D_FOUTCODE G 45
 ;
 ; controle op fouten
5 S HULPI4=""
51 S HULPI4=$O(^HULP(HULPI1,HULPI2,HULPI3,HULPI4)) I HULPI4="" G 6
53 S K=$G(^(HULPI4,"EINDE")) I $P(K,D,5)=2 G 51
55 W /CUP(22,2),@F4,$P($T(@("T8"_QT)),U,2),@F5,!?2 D KON^cQ4 D TXT^cAFA1(4) G Y
 ;
 ; conversie uitvoeren
6 W /CUP(17,1),@F92,@F94,$P($T(@("T3"_QT)),U,2),@F93,@F95,@F1,!?2,$P($T(@("T11"_QT)),U,2),!?2,$P($T(@("T12"_QT)),U,2)
60 W !?2,$P($T(@("T13"_QT)),U,2),$G(^HULP(HULPI1,HULPI2,"T"),"?")
61 S R="K\22\3\"_$P($T(@("T6"_QT)),U,2)_"\1\\K=""-""!(K=""."")" D R0 G Y:K="-"
63 S HULPI3="B",HULPI4="" D ^cA106,^cA105 W /CUP(21,3),$P($T(@("T13"_QT)),U,3),DT," / ",TD D X^cA612
65 S HULPI4=$O(^HULP(HULPI1,HULPI2,HULPI3,HULPI4)) I HULPI4="" G 7
67 S K=^(HULPI4),Q=$P(K,D),P=$P(K,D,2),QD=+$G(@("^"_Q_"BA(34)")),QN=^(99,1),FOUTCODE=1 W /CUP(22,3),HULPI4,@F1
68 D ^cA106,^cA105 S ^HULP(HULPI1,HULPI2,HULPI3,HULPI4,"BEGIN")=DT_D_TD_D_$H_D_QU K ^("EINDE"),^("FOUT") D @P
69 D ^cA106,^cA105 S ^HULP(HULPI1,HULPI2,HULPI3,HULPI4,"EINDE")=DT_D_TD_D_$H_D_QU_D_FOUTCODE I FOUTCODE=2 G 65
 ;
 ; controle op fouten
7 S HULPI4="" D W^cA612 W /CUP(21,43),$P($T(@("T13"_QT)),U,4),DT," / ",TD,@F1
71 S HULPI4=$O(^HULP(HULPI1,HULPI2,HULPI3,HULPI4)) I HULPI4="" G 8
73 S K=$G(^(HULPI4,"EINDE")) I $P(K,D,5)=2 G 71
75 W /CUP(22,2),@F4,$P($T(@("T9"_QT)),U,2),@F5,!?2 D KON^cQ4 D TXT^cAFA1(4) G Y
 ;
 ; programma van de menu verwijderen
8 W /CUP(22,2),@F4,$P($T(@("T10"_QT)),U,2),@F5 D TXT^cAFA1(4)
81 K @%ZM
 ;
 ; terugzetten Q-waarde + einde
Y S Q=HULPI2
YZ K HULPI1,HULPI2,HULPI3,HULPI4 Q
 ;
 ; foutboodschap
FOUT(K) N R S R=$O(^HULP(HULPI1,HULPI2,HULPI3,HULPI4,"FOUT",""),-1)+1,^(R)=K Q
 ;
R0 S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
 ;
ZZ ; 29.12.98 - 15 u 04 * V7.12