cI43	;Conversie BTW-nummers; cI43
	;
T0	;Conversie BTW-nummers;
	;
YZ	Q
	;
BTW	; Aanpassen velden ivm BTW-nummers
	N qq,I,q
	S $ZT="TRAP^cAN000"
	W !!,"Conversie BTW-nummers"
	; Aflopen alle Q-waarden
	S qq=^cLOG(boot,"Q",$ZU(5))
	F I=1:1:$L(qq,D) S q=$P(qq,D,I) I q'="DAM",$L(q) D
	. ; Aanpassen BTW-nummers klanten
	. D BTWNR(q,"KL")
	. ; Aanpassen BTW-nummers leveranciers
	. D BTWNR(q,"LE")
	. ; Aanpassen BTW-nummers uit ^_Q_BTW(0,0
	. F J=7,8 D
	.. S BTWNR=$P($G(@("^"_q_"BTW(0,0)")),D,J)
	.. I '$L(BTWNR) Q
	.. I $E(BTWNR,1,2)?2U,($E(BTWNR,1,2)'=$P(@("^"_q_"BA(39)"),D,4)) Q
	.. N Q
	.. S Q=q
	.. I '$$CBTW(BTWNR) S ^TEMPC($T(+0),Q,"BTW")=BTWNR Q
	.. I BTWNR=K Q
	.. S $P(@("^"_q_"BTW(0,0)"),D,J)=K
	W !!,"Einde conversie BTW-nummers"
BTWZ	Q
	;
BTWNR(Q,DMS)	;  Aanpassen veld BTW-nummer bij doorgegeven DMS en Q-waarde
	N CODE,UREF,UI1,BTWNR
	S $ZT="TRAP^cAN000"
	I '$D(^DMS(Q,DMS)) G BTWNRZ
	S UREF=$P($$REF^cAFA10(.Q,DMS),D)
	I '$L(UREF) G BTWNRZ
	S CODE=$P($G(@("^"_Q_"BA(39)")),D,4)
	I CODE="" G BTWNRZ
	W !!,Q_" - "_DMS,!!
	K ^TEMPC($T(+0),Q,DMS)
	S UI1=0
	F  S UI1=$O(@UREF) Q:UI1=""  D
	. S BTWNR=$P(^(UI1,0),D,16)
	. I '$L(BTWNR) Q
	. I $E(BTWNR,1,2)?2U,($E(BTWNR,1,2)'=CODE) Q
	. I '$$CBTW(BTWNR) S ^TEMPC($T(+0),Q,DMS,UI1)=BTWNR Q
	. I BTWNR=K Q
	. D W^cAN220(DMS,"",UI1,116,K)
	. I K="-" X "STOP"
BTWNRZ	Q
	;
CBTW(NR,DMS)	; BTW-nummer
	; DMS : wordt meegegeven als moet getest worden op dubbel BTW-nr
	N R,RK,RL,RLI
	I '$L(NR)!(NR="-") S R=1 G CBTWZ
	S (K,RK)=$$UC^cAFA1(NR),R=1,RL=$P(@("^"_Q_"BA(39)"),D,4),RLI=$E(K,1,2)
	I $E(K,1,2)="LL" S R=0 G CBTWZ  ; S K=$P($T(@("T2"_QT)),U,2) D TXT^cAFA1(250) S R=0 G BTWZ
	S:RLI?2U K=$E(K,3,99) S:RLI'?2U RLI=RL 
	I $D(^BA(5,RLI)) D
	. I RLI="BE" S:K?9N K=0_K
	. S R=0 I @^BA(5,RLI,1) S R=1
	. I K=0 S K=$E(1E20,2,$P(^(0),D,2)+1)
	I 'R S K=RK
	I R S K=RLI_K
	I R,$L($G(DMS)),'$$BTWD^cAFI1(DMS,K) S R=0
CBTWZ	Q R
	;
DMA(DMS)	; Aanpassen commentaar BTW-nummer
	N I1,I2,I3,BIN,COM,BI
	S $ZT="TRAP^cAN000"
	S BIN="\116\"
	S I1=""
	F  S I1=$O(^DMA(I1)) Q:I1=""  D
	. I '$D(^DMA(I1,DMS)) Q
	. S I2=0
	. F  S I2=$O(^DMA(I1,DMS,I2)) Q:I2=""  D
	.. S I3=0
	.. F  S I3=$O(^DMA(I1,DMS,I2,I3)) Q:I3=""  D
	... S BI=$G(^DMA(I1,DMS,I2,I3,16))
	... I BIN'=(D_BI_D) Q
	... W !,I1_" - "_DMS_" - "_I2_" - "_I3
	... S COM="LLxxxxxxxxxxx[] = nummer   LL0[] = onbekend nummer  (LL= BE, DE, FR, ...)                    [] = geen\PPxxxxxxxxxxx[] = numéro   PP0[] = n° inconnu  (PP= BE, DE, FR, ...)                         [] = sans\LLxxxxxxxxxxx[] = Nummer   LL0[] = unbekannte Nummer  (LL= BE, DE, FR, ...)                  [] = kein\ICxxxxxxxxxxx[] = number   IC0[] = unknown number  (IC= BE, DE, FR, ...)                     [] = none"
	... S ^DMA(I1,DMS,I2,I3,10)=COM
DMAZ	Q
	;
ZZ	; 27.04.06 -  8 u 53 * V8.07