cI92	;Hernummeren van de klanten (enkel boekhouding); %I92 [ 08/20/2002  12:00 PM ]
	;
	G 1
	;
T0	;Hernummeren van de klanten (enkel boekhouding!);
T1	;Q-waarde;
T2	;Hernummeren vanaf\"xxxxxx = huidig klantnummer +/- xxxxxx";
T3	;Nieuw klantnummer = klantnummer ;
T4	;Bevestiging\".[] = ok";
T5	;Einde hernummering klanten.;
T6	;Keuze\"[] = bijtellen   1[] = aftrekken";
	;
1	D P^cA612(2,1,20,80,1,0,1,1,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
11	N QQ,NNR,BEV,UI1,NUI1,KLNR,NKLNR,NAAM,I1,I2,I3,I4,INH,X,Y,UQA,USA
13	S $ZT="TRAP^cAN000"
	;  Vraagstelling voor welke Q-waarde
15	S R="QQ\22\3\"_$P($T(@("T1"_QT)),U,2)_"\C1\3\\$L(K)&(""-""[K!($$QWRD^cI92(K)))\\\1\\1" D R0
16	I QQ="-" G YZ
17	W /CUP(2,2),@F6,$P($T(@("T1"_QT)),U,2),@F9," : ",QQ
	; Vraagstelling naar de hernummering
19	S R="NNR\22\3\"_$P($T(@("T2"_QT)),U,2)_"\7\\$L(K)&(""-""[K!(K?.N))\\\\\1" D R0
	;
2	I NNR="-" G 15
21	S R="TEKEN\22\3\"_$P($T(@("T6"_QT)),U,2)_"\1\\K=""1""!(K=""-"")!(K="""")\\\\\1" D R0
23	I TEKEN="-" G 19
25	W /CUP(4,3),$P($T(@("T3"_QT)),U,2),$S(TEKEN="":"+ ",1:"- "),NNR
27	S R="BEV\22\3\"_$P($T(@("T4"_QT)),U,2)_"\1\\$L(K)&(K="".""!(K=""-""))" D R0
28	I BEV="-" G 21
29	I TEKEN=1 S NNR="-"_NNR
	;
	;  Hernummeren van de klanten
3	K ^TEMPC($T(+0),QQ) 
	;  Aflopen van het klantenbestand
31	S UI1=0
33	F  S UI1=$O(@("^"_QQ_"KL(UI1)")) Q:UI1=""  D
	. S KLNR=$P(^(UI1,0),D)
	. W /CUP(17,2),@F2,KLNR
	. S NAAM=$P(^(0),D,2)
	. S NKLNR=KLNR+NNR
	. I $D(^TEMPC($T(+0),QQ,"KL",KLNR)) Q
	. S $P(@("^"_QQ_"KL(UI1,0)"),D)=NKLNR
	. S NUI1=$$DI^cAN000(NAAM,NKLNR)
	. ;  Aanpassen factuurklant
	. I $L($P(@("^"_QQ_"KL(UI1,1)"),D,20)) S $P(@("^"_QQ_"KL(UI1,1)"),D,20)=$P(@("^"_QQ_"KL(UI1,1)"),D,20)+NNR
	. M @("^"_QQ_"KL(NUI1)")=@("^"_QQ_"KL(UI1)")
	. S ^TEMPC($T(+0),QQ,"KL",NKLNR)=KLNR_D_NKLNR
	. K @("^"_QQ_"KL(UI1)")
	. S @("^"_QQ_"K1(NKLNR)")=NUI1
	. K @("^"_QQ_"K1(KLNR)")
	. ; Hernummeren logging
	. M ^DLOG(QQ,"KL",NKLNR)=^DLOG(QQ,"KL",KLNR)
	. K ^DLOG(QQ,"KL",KLNR)
	. ; Hernummeren TXT
	. M ^DTXT(QQ,"KL",NKLNR)=^DTXT(QQ,"KL",KLNR)
	. K ^DTXT(QQ,"KL",KLNR)
	; Hernummeren ^DIN
34	S ^DIN(QQ,"KL")=$G(^DIN(QQ,"KL"))+NNR
	;  Controle indexen klanten
35	N Q S Q=QQ
36	D DMS^cAN000("UQC","USC","KL")
37	D S1^cAN002(UQC,USC,17,0)
	; 
	;  Hernummeren contactpersonen
4	S I1=""  
41	F  S I1=$O(^DATA(QQ,"CP",I1)) Q:I1=""  D
	. W /CUP(17,2),@F2,I1
	. I '$L($P(^(I1,1),D,20)) Q
	. S $P(^(1),D,20)=$P(^(1),D,20)+NNR
	;  Controle indexen contactpersonen
43	D DMS^cAN000("UQC","USC","CP")
45	D S1^cAN002(UQC,USC,17,0)
	;
	;  Hernummeren domiciliëringen
5	S I1=""
51	F  S I1=$O(@("^"_QQ_"K3(I1)")) Q:I1=""  D
	. S I2=""
	. F  S I2=$O(@("^"_QQ_"K3(I1,I2)")) Q:I2=""  D
	.. S I3=""
	.. F  S I3=$O(@("^"_QQ_"K3(I1,I2,I3)")) Q:I3=""  D
	... W /CUP(17,2),@F2,I3
	... I $D(^TEMPC($T(+0),QQ,"K3",I3)) Q
	... S I4=""
	... F  S I4=$O(@("^"_QQ_"K3(I1,I2,I3,I4)")) Q:I4=""  D
	.... S INH=^(I4)
	.... S $P(INH,D)=$P(INH,D)+NNR
	.... S @("^"_QQ_"K3(I1,I2,I3,I4)")=INH
	... S NKLNR=I3+NNR
	... M @("^"_QQ_"K3(I1,I2,NKLNR)")=@("^"_QQ_"K3(I1,I2,I3)")
	... S ^TEMPC($T(+0),QQ,"K3",NKLNR)=I3_D_NKLNR
	... K @("^"_QQ_"K3(I1,I2,I3)")
	;
	;  Hernummeren Kumul zakencijfer opstarten klanten
53	S I1=0
55	F  S I1=$O(@("^"_QQ_"K9(I1)")) Q:I1=""  D
	. W /CUP(17,2),@F2,I1
	. I $D(^TEMPC($T(+0),QQ,"K9",I1)) Q
	. S NKLNR=I1+NNR
	. M @("^"_QQ_"K9(NKLNR)")=@("^"_QQ_"K9(I1)")
	. S ^TEMPC($T(+0),QQ,"K9",NKLNR)=I1_D_NKLNR
	. K @("^"_QQ_"K9(I1)")
	;
	;  Hernummeren verkoopdagboek
6	S I1=""
61	F  S I1=$O(@("^"_QQ_"VE(I1)")) Q:I1=""  D
	. S I2=""
	. F  S I2=$O(@("^"_QQ_"VE(I1,I2)")) Q:I2=""  D
	.. W /CUP(17,2),@F2,I2
	.. I I2["." Q
	.. S INH=^(I2)
	.. I $L($P(INH,D,4)) S $P(INH,D,4)=$P(INH,D,4)+NNR
	.. S @("^"_QQ_"VE(I1,I2)")=INH
	;
	;  Hernummeren openstaande verkoopfacturen
63	S I1=""
65	F  S I1=$O(@("^"_QQ_"VF(I1)")) Q:I1=""  D
	. W /CUP(17,2),@F2,I1
	. S $P(^(I1),D)=$P(^(I1),D)+NNR
	;
	;  Hernummeren financieel
7	S I1=""
71	F  S I1=$O(@("^"_QQ_"FI(I1)")) Q:I1=""  D
	. S I2=""
	. F  S I2=$O(@("^"_QQ_"FI(I1,I2)")) Q:I2=""  D
	.. S I3=""
	.. F  S I3=$O(@("^"_QQ_"FI(I1,I2,I3)")) Q:I3=""  D
	... W /CUP(17,2),@F2,I3
	... S INH=^(I3)
	... I $P(INH,D,7)="K" D
	.... S X=$P($P(INH,D,8),"#")
	.... S Y=X+NNR_"#"_$P($P(INH,D,8),"#",2)
	.... S $P(INH,D,8)=Y
	... I $L($P(INH,D,32)) S $P(INH,D,32)=$P(INH,D,32)+NNR
	... S @("^"_QQ_"FI(I1,I2,I3)")=INH
	;
	;  Hernummeren beginbalans verkoop
73	S I1=""
75	F  S I1=$O(@("^"_QQ_"VEB(I1)")) Q:I1=""  D
	. S I2=""
	. F  S I2=$O(@("^"_QQ_"VEB(I1,I2)")) Q:I2=""  D
	.. W /CUP(17,2),@F2,I2
	.. I $D(^TEMPC($T(+0),QQ,"VEB",I2)) Q
	.. S NKLNR=I2+NNR
	.. M @("^"_QQ_"VEB(I1,NKLNR)")=@("^"_QQ_"VEB(I1,I2)")
	.. S ^TEMPC($T(+0),QQ,"VEB",NKLNR)=I2_D_NKLNR
	.. K @("^"_QQ_"VEB(I1,I2)")
	;
	;  Hernummeren wissels
77	S I1=""
79	F  S I1=$O(@("^"_QQ_"WI(I1)")) Q:I1=""  D
	. I '$D(@("^"_QQ_"WI(I1,0)")) Q
	. S INH=^(0)
	. I $P(INH,D,6)'="KL" Q
	. S $P(INH,D,3)=$P(INH,D,3)+NNR
	. S @("^"_QQ_"WI(I1,0)")=INH
	;
	;  Hernummeren leveranciers
8	S UQA=$P($G(^DMS(QQ,"LE","DMA","W")),D),USA=$P($G(^("W")),D,2)
81	I UQA=""!USA="" G 9
82	S I1=0
	F  S I1=$O(@("^"_QQ_"LE(I1)")) Q:I1=""  D
	. W /CUP(17,2),@F2,I1
	. I '$L($P(^(I1,2),D,30)) Q
	. S NKLNR=$P(^(2),D,30)+NNR
	. D W^cAN220(USA,UQA,I1,330,NKLNR)
	;
9	S K=$P($T(@("T5"_QT)),U,2) D TXT^cAFA1(250)
	;
YZ	D C^cA612 Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q
	;
C1	W !?2,$TR(^cLOG(boot,"Q","TST,"_boot),"\"," ") Q
	;
QWRD(K)	;  Inputcontrole op geldige Q-waarde
	N R,qq
	S $ZT="TRAP^cAN000"
	I '$L(K) S R=0 G QWRDZ
	S R=1
	S qq=^cLOG(boot,"Q","TST,"_boot)
	S qq=U_$TR(qq,"\",U)_U
	I qq'[(U_K_U) S R=0
QWRDZ	Q R
	;
ZZ	; 29.10.02 - 11 u 38 * V7.93