cQ4	;Messages ;cQ4;
	Q
	;
T0	;Boodschappen ;
T1	;Contact opnemen met: ;uw software-leverancier;
T2	;U heeft geen toegang tot dit programma;
	;
T0F	;Messages ;
T1F	;Veuillez contacter: ;votre fournisseur du logiciel;
T2F	;Vous n'avez pas d'accès a ce programme;
	;
T0E	;Messages ;
T1E	;Please contact: ;Your software supplier;
T2E	;You do not have access to this program;
	;
T0D	;Nachrichten ;
T1D	;Bitte contactieren Sie: ;Ihren lieferant;
T2D	;Sie haben keine zugang zu diesem programme;
	;
KON	W $$KA()
KONZ	Q
	;
KA()	N K,L,M
	S QT=$G(QT),M=$P($T(@("T1"_QT)),";",2),K=$P($T(@("T1"_QT)),";",3)
	I $D(^cLOG(0,"ADRES",0)) S L=^(0) I $D(^cLOG(0,"ADRES",L,1)),$D(^(4)) S K=^(1)_" - "_^(4)
KAZ	Q M_K
	;
NOACCES	N R S QT=$G(QT),R=$P($T(@("T2"_QT)),";",2) D MS
NOACCESZ	Q
	;
MS	U $P S R=$G(R) I $D(R(1)) S FP=2303 W @F,@F1,@F4,R(1),$J("",$L(R)+10-$L(R(1))),@F5
	S FP=2403 W @F,@F4,R,$J("",$L($G(R(1)))-10-$L(R)),"  [] = ok ",@F5,@F2,@F0 R *K
	S FP=2303 W @F
MSZ	Q
	;
EXEC(L)	;Execute line from ^cLOG(boot,"EXEC")
	S L=$G(L)
	I $L(L),$D(^cLOG($ZCVT($ZU(110),"U"),"EXEC",L)) S X=^(L) I $L(X) X X
EXECZ	Q
	;
MAIL(FROM,TO,SUBJECT,DATA,ATTACH)  ;Send message by e-mail
	N I,M,S,STAT,Exception
	S S=##class(%Net.SMTP).%New()		;Make SMTP-object and connect to a server
	S S.smtpserver = "smtprelay.vanhoecke.be"
	S M=##class(%Net.MailMessage).%New()	;Make a message-object
	S M.From=FROM
	F I=1:1:$L(TO,";") D M.To.Insert($P(TO,";",I))
	S M.Subject=SUBJECT
	S M.Charset="iso-8859-1"
	D M.TextData.Write(DATA)			;add DATA
	I $D(ATTACH) S STAT=M.AttachFile($P(ATTACH,"\",1,$L(ATTACH,"\")-1),$P(ATTACH,"\",$L(ATTACH,"\")))	;add ATTACHMENT
	S STAT=S.Send(M) 				;Send message and close objects
MAILZ	Q
	;
VE(R)	;Check if valid e-mail address
	N A,B,I,K,L,N,OK,PD,PL
	S R=$G(R) I '$L(R) Q 0
	I R'["@" Q 0      ;at least one @
	;if only one @, it may not be within "
	I $F(R,"""") D  I K>L Q 0
	. S K=1 F I=1:1:$L(R) S B=$F(R,"""",K) I B S K=B
	. S L=1 F I=1:1:$L(R) S B=$F(R,"@",L) I B S L=B
	S PL=$P(R,"@",1,$L(R,"@")-1),PD=$P(R,"@",$L(R,"@"))
	I '$L(PL)!($L(PL)>64) Q 0    ;maximum length for local part
	S A="ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789!#$%&'*+-/=?^_`{|}~."
	S N="," F I=1:1:255 I A'[$C(I) S N=N_I_","
	;if local part doesn't start with a ", check for allowed characters
	I $E(PL)'="""" S OK=1 D  I 'OK Q 0
	. F I=1:1:$L(PL) S K=$A(PL,I) I N[(","_K_",") S OK=0 Q
	;if local part starts with ", check if it ends with a "
	I $E(PL)="""",$E(PL,$L(PL))'="""" Q 0
	;local part may not start or end with a .
	I ($E(PL)=".")!($E(PL,$L(PL))=".") Q 0
	I $F(PL,"..") Q 0            ;.. is not allowed
	I '$L(PD)!($L(PD)>255) Q 0   ;maximum length for domain part
	S A="ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789-."
	S N="," F I=1:1:255 I A'[$C(I) S N=N_I_","
	;if domain part doesn't start with a [, check if its's an ip-address
	I $E(PD)="[",PD'?1"["3(1.3N1".")1.3N1"]" Q 0
	I $E(PD)'="[" S OK=1 D  I 'OK Q 0
	. F I=1:1:$L(PD) S K=$A(PD,I) I N[(","_K_",") S OK=0 Q
	I $F(PD,"..") Q 0            ;.. is not allowed
	;check for 2 part . form
	I PD'?.E1".".E Q 0
VEZ	Q 1
	;
SHOW	;Show unsent messages in ^MAIL
	N J,K,R,RS,S,%ROWCOUNT
	S R(1)="MailID",R(2)="RcptTo",R(3)="RcptFrom",R(6)="TcpIPHost",R(7)="Subject",R(9)="DateCreated"
	S R(10)="TimeCreated",R(11)="Initials",R(12)="ToSend",R(13)="DateSended",R(14)="TimeSended"
	S R(15)="ErrorMsg",R(16)="NbrAttempts",R(17)="NbrSended",R(19)="Mailtype",R(20)="Program"
	S S="SELECT * FROM Prog_Sys.Mail WHERE B112='1'"
	S RS=##class(%Library.ResultSet).%New()
	S K=RS.Prepare(S)
	S K=RS.Execute()
	WHILE RS.Next() { 
		W !
		S J="" F  S J=$O(R(J)) Q:J=""  W !,$J(J,3),". ",$J(R(J),11),": ",RS.Data("B"_(J+100))
		}
	W !!,%ROWCOUNT," unsent e-mail",$S(%ROWCOUNT=1:"",1:"s"),".",!
SHOWZ	Q
	;
RES(R)	;Resend mail R
	S R=$G(R) Q:'$L(R)
	S $P(^MAIL(0,"MAIL",R,0),"\",12)=1
	S $P(^MAIL(0,"MAIL",R,0),"\",15)=""
	S $P(^MAIL(0,"MAIL",R,0),"\",16)=0
RESZ	Q
	;
YZ	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9