cQCPFN	;Create new namespace(s);cQCPFN;
	W !,"Usage:"
	W !?3,"Do MC^"_$T(+0)_" to modify cache settings",!
	W !?3,"Do CN^"_$T(+0)_"(Name,Number) to create namespaces Name1 till NameNumber"
	W !,?3,"Ex. Do Start^"_$T(+0)_"(""TEST"",3) will create namespaces TEST1, TEST2 and TEST3",!
	Q
	;
date	;date
	N %H,%J,%R S %H=1+$H,%J=%H\1461,%R=%H#1461,DJ=%J*4+1841+(%R\365),DD=%R#365,DM=1 I %R=1460 S DD=365,DJ=DJ-1
	F %J=31,(%R>1154)+28,31,30,31,30,31,31,30,31,30 Q:%J'<DD  S DM=DM+1,DD=DD-%J
	S:'DD DJ=DJ-1,DM=12,DD=31 S:DD<10 DD=0_DD S:DM<10 DM=0_DM S DT=DD_"."_DM_"."_$E(DJ,3,4)
datez	Q
time	;time
	N %J,%R S QT=$G(QT),%R=$P($H,",",2)\60,%J=%R\60
	S TD=$J(%J,2)_$P(" u ; h ; h ",";",$S(QT="F":2,QT="E":3,1:1))_(%R#60\10)_(%R#10)
timez	Q
doubleq(X)	;Double quotes in string
	N Y S Y=0 F  S Y=$F(X,"""",Y) Q:'Y  S X=$E(X,0,Y-1)_""""_$E(X,Y,$L(X)),Y=Y+1
doubleqz	K Y Q X
	;
MC	;Modify Caché
	W !!,$P($T(+1),";",2),!
	I '(($P($P($ZV,")",2),"(",1)[" 2008")!($P($P($ZV,")",2),"(",1)[" 2010")) W !,"Works only on Caché 2008 & 2010.",! Q
	;Do not proceed on TBxxx systems
	S K=$E($ZCVT($ZU(110),"U"),1,2) I (K="TB") Q
	;
	S NS=$ZU(5) ZN "%SYS"
	;
	W !,"Configuration"
	W !?10,"Journaldirectories ..."
	F J="C:\DataM\Journal\Aij\","D:\DataM\Journal\Aij\","D:\DataM\Journal\Wij\","E:\DataM\Journal\Aij\","D:\DataM\InterSystems\Cache\CSP\datam" I $$TST(J) S ER=$$CRED(J)
	S JDIR=$S('$$TST("E:\"):"E",1:"C")_":\DataM\Journal\Aij\"
	S DIR=##class(%SYS.Journal.System).GetPrimaryDirectory()
	I $ZCVT(JDIR,"U")'=$ZCVT(DIR,"U") D
	. S JDIRA=$S($E(JDIR)="E":"C",1:$E($ZU(86)))_":\DataM\Journal\Aij\"
	. D ##class(%SYS.Journal.System).SetPrimaryDirectory(JDIR,1)
	. D ##class(%SYS.Journal.System).SetAlternateDirectory(JDIRA,1)
	. D ##class(%SYS.Journal.System).SwitchFile(JDIR,JDIRA,1024)
	W !,"Add device faxmodem."
	S N="faxmodem"
	I ($P($P($ZV,")",2),"(",1)[" 2008") D
	. S OK=##class(Config.Configuration).GetDevice(N,.device,.type,.stype,.prompt,.open,.alt,.desc,.alias)
	. I 'OK S OK=##class(Config.Configuration).AddDevice(N,"COM1:","TRM","","","","","fax modem",4)
	E  D
	. S OK=##class(Config.Devices).Get(N,.P)
	. I 'OK D
	.. K P
	.. S P("Alias")=4
	.. S P("Description")="fax modem"
	.. S P("PhysicalDevice")="COM1:"
	.. S P("SubType")="C-VT220"
	.. S P("Type")="TRM"
	.. S OK=##Class(Config.Devices).Create(N,.P)
	W !?10,"SQL Settings ..."
	Set OK=##class(%SYSTEM.SQL).SetCachedQuerySaveSource(0)
	;
	W !,"Security Management"
	;Users
	W !?10,"Create user SU ..."
	S N="SU"
	S OK=##class(Security.Users).Exists(N,.u,.s,.f)
	I 'OK D
	. K P
	. S P("ChangePassword")=0
	. S P("Comment")=""
	. S P("Enabled")=1
	. S P("ExpirationDate")=""
	. S P("Flags")=1
	. S P("FullName")="Data-M Super user"
	. S P("InvalidLoginAttempts")=0
	. S P("InvalidLoginDateTime")=""
	. S P("InvalidLoginDevice")=""
	. S P("InvalidLoginService")=""
	. S P("InvalidLoginStatus")=1
	. S P("LegacyPassword")=""
	. S P("LoginDateTime")=""
	. S P("LoginDevice")=""
	. S P("LoginService")=""
	. S P("NameSpace")=""
	. S P("Password")="MF5761EP"
	. S P("Roles")="%All"
	. S P("Routine")=""
	. S P("Salt")=""
	. S P("SuperUser")=1
	. S OK=##class(Security.Users).Create(N,.P)
	W !?10,"Enable Service telnet ..."
	S S="%Service_Telnet",OK=##class(Security.Services).Get(S,.P)
	I OK S P("Enabled")=1,OK=##class(Security.Services).Modify(S,.P)
	W !?10,"Change Service Login ..."
	S S="%Service_Login",OK=##class(Security.Services).Get(S,.P)
	I OK S P("AutheEnabled")=1024,OK=##class(Security.Services).Modify(S,.P)
	;
	W !,"Tasks"
	W !?10,"Integrity Check ..."
	S TID=4,T=##Class(%SYS.Task).%OpenId(TID)
	I +T S T.RescheduleOnStart=1 D T.%Save(),T.%Close()
	S OK=##Class(%SYS.Task).Resume(TID)
	W !?10,"Purge Tasks ..."
	S TID=3,T=##Class(%SYS.Task).%OpenId(TID)
	I +T S T.RescheduleOnStart=1 D T.%Save(),T.%Close()
	S Days=##class(%SYS.Task).HistoryPurgeGet() I Days'=14 Do ##class(%SYS.Task).HistoryPurgeSet(14)
	;
	I '$$EXIST^%R("%ZX364","%SYS") X "ZR  ZL %X364 zs %ZX364"
	;
	ZN NS
	;
	I ($P($P($ZV,")",2),"(",1)[" 2010") D
	. W !?10,"Modifying cache.cpf"
	. S ROUT="cQCPF5" K ^TEMP($J,"new")
	. F J=0:1 S K=$T(2+J^@ROUT) S K=$P(K,";",2,$L(K,";")) Q:K="END"  D
	.. D FR^cQCPF($P(K,";",2),$P(K,";",1),$P(K,";",3))
	;
	W !,"Done.",!
MCZ	Q
	;
CN(V,NX,O)	;Create new namespace(s);
	W !?20,$P($T(+1),";",2),!
	I '(($P($P($ZV,")",2),"(",1)[" 2008")!($P($P($ZV,")",2),"(",1)[" 2010")) W !,"Works only on Caché 2008 and 2010.",! Q
	;Do not proceed on TBxxx systems
	S V=$G(V),NX=$G(NX),O=$G(O),K=$E($ZCVT($ZU(110),"U"),1,2) I (K="TB") Q
	I (V="")!'NX D  Q
	. W !,"Usage:",!?3,"Do CN^"_$T(+0)_"(Name,Number) "
	. W "will create namespaces Name[1] till Name[Number]"
	. W !?3,"Ex. Do CN^"_$T(+0)_"(""TEST"",3) will create namespaces TEST1, TEST2 and TEST3."
	. W !!?3,"Do CN^"_$T(+0)_"(Name,Number,1) "
	. W "will create namespace Name[Number] only"
	. W !?3,"Ex. Do CN^"_$T(+0)_"(""TEST"",3,1) will create namespaces TEST3 only."
	;
	S DBPATH=$E($ZU(86))_":\DataM\database\"_V_"\"
	K DB S DB(V_"-R0")=DBPATH_"R\0\"
	F I=0:1:NX I (I=0)!('O)!(O&(I=NX)) S DB(V_"-G"_I)=DBPATH_"G\"_I_"\"
	;
	W !,"This program will create the following databases if they don't exist already:",!
	S I="" F J=0:1 S I=$O(DB(I)) Q:I=""  W ?J#2*40+3,DB(I) I J#2 W !
	W !,"The following Namespace(s) will be created if they don't exist already:",!?3
	F I=1:1:NX I ('O)!(O&(I=NX)) W V,I,"  "
	W !,"The globalmappings will be added if not already defined."
	I ($P($P($ZV,")",2),"(",1)[" 2008") D
	. W !,"*** Warning ***"
	. W !,"Creating a namespace takes a lot of time, cpu and journalspace. This will "
	. W !,"result in an unresponsive system until this job ends if there are a lot of"
	. W !,"namespaces already defined."
	. W !,"Some figures:"
	. W !,"On a single cpu system with 123 databases and 70 namespaces it took 40 seconds"
	. W !,"to activate one (1) globalmapping. Given that there are about 120 entries, it"
	. W !,"takes 75 minutes to complete one namespace."
	. W !,"Moreover, the activation of the globalmappings creates about 2 GB journaldata"
	. W !,"for each namespace!"
	. W !!,"Use this routine on a stand-alone system NOT on an internal system!",!
	W !,"Proceed (Y/N): N",*8 R K I $ZCVT(K,"U")'="Y" Q
	;
	S NS=$ZU(5) ZN "%SYS"
	W !,"Adding Databases ..."
	S I="" F  S I=$O(DB(I)) Q:I=""  S J=DB(I) D
	. I $$TST(J) S ER=$$CRED(J)
	. I $$TST(J_"cache.dat") D CDB(I,J)
	. I ($P($P($ZV,")",2),"(",1)[" 2008") D  Q
	.. I '##class(Config.Configuration).GetDatabase(I,.dir,.srvr,.mnt,.clmnt,.mntrq) D ADB(I,J)
	. E  D
	.. I '##Class(Config.Databases).Get(I,.P) D CDB(I,J)
	W !,"Adding Namespace(s) ..." 
	F I=1:1:NX I ('O)!(O&(I=NX)) D
	. I ($P($P($ZV,")",2),"(",1)[" 2008") D  Q
	.. I '##class(Config.Configuration).GetNamespace(V_I,.dbglo,.dbrou,.dbsys,.dbsysrou,.dblib,.dbtemp) D ANS(V,I)
	. E  D
	.. I '##Class(Config.Namespaces).Get(V_I,.P) D ANS(V,I)
	ZN NS
	;
	F I=1:1:NX I ('O)!(O&(I=NX)) D
	. W !,"Adding Global Mappings for Namespace ",V,I
	. K GMX D GMX(V,I)
	. S NS=$ZU(5) ZN "%SYS"
	. I ($P($P($ZV,")",2),"(",1)[" 2008") D
	.. S J=""
	.. F  S J=$O(GMX(J)) Q:J=""  D
	... I $E(GMX(J),1,6)="GloMap" D
	.... S G=$P($P(GMX(J),"=",2),",",1),S=""
	.... S DB=$P($P(GMX(J),"=",2),",",2),LDB=$P($P(GMX(J),"=",2),",",3)
	.... S COLL=$P($P(GMX(J),"=",2),",",5),SLMLOC=""
	... I $E(GMX(J),1,6)="GloSLM" D
	.... S S=$P($P(GMX(J),"=",2),"~",1),SLMLOC=$P($P(GMX(J),"=",2),"~",2)
	... S DB=$G(DB),LDB=$G(LDB),COLL=$G(COLL),SLMLOC=$G(SLMLOC)
	... S OK=##class(Config.Configuration).GetGlobalMapping(V_I,G,S,.db,.ldb,.coll,.slmloc)
	... I OK,(DB'=$G(db))!(LDB'=$G(ldb))!(COLL'=$G(coll))!(SLMLOC'=$G(slmloc)) D
	.... S OKN=##class(Config.Configuration).ModifyGlobalMapping(V_I,G,S,DB,LDB,COLL,SLMLOC)
	... I 'OK S OKN=##class(Config.Configuration).AddGlobalMapping(V_I,G,S,DB,LDB,COLL,SLMLOC)
	. I ($P($P($ZV,")",2),"(",1)[" 2010") D
	.. S J=""
	.. F  S J=$O(GMX(J)) Q:J=""  D
	... S P("Database")=$P(GMX(J),"=",2),G=$P($P(GMX(J),"="),"_",2)
	... S OK=##Class(Config.MapGlobals).Create(V_I,G,.P)
	... I 'OK S OKN=##Class(Config.MapGlobals).Modify(V_I,G,.P)
	. ZN NS
	;
	W !,"Done.",!
CNZ	Q
	;
TST(R)	; Check if file or dir R exists
	N ER S R=$G(R),ER=0 I '$L(R) Q 1
	S ER=$ZU(140,4,R) I ER'=0 S ER=2
TSTZ	Q ER
	;
CRED(R)	; Create directory R
	N ER,I S R=$G(R),ER=0 I '$L(R) Q 1
	I $E(R,$L(R))="\" S R=$E(R,1,$L(R)-1)
	F I=$E(R,1,2)="\\"*3+2:1:$L(R,"\") S ER=$$CREDA($P(R,"\",1,I)) Q:ER
	Q ER
CREDA(R)	I '$$TST(R) Q 0   ; directory does already exist
	S ER=$ZU(140,9,R) S:ER=-183 ER=0
CREDZ	Q ER
	;
ADB(X,Y)	;Add database
	S X=$G(X),Y=$G(Y) Q:'$L(X)  Q:'$L(Y)
	N srvr,mnt,clmnt,mntrq
	S srvr="",mnt=0,clmnt=0,mntrq=0
	S OK=##class(Config.Configuration).AddDatabase(X,Y,srvr,mnt,clmnt,mntrq)
ADBZ	Q
	;
CDB(X,Y)	;Create database
	S X=$G(X),Y=$G(Y) Q:'$L(X)  Q:'$L(Y)
	I ($P($P($ZV,")",2),"(",1)[" 2008") D 
	. N srvr,mnt,clmnt,mntrq,enc,res,jrnl
	. S srvr="",mnt=0,clmnt=0,mntrq=0,enc=0,res="%DB_%DEFAULT",jrnl=1
	. S OK=##class(Config.Configuration).CreateDatabase(X,Y,1,8192,mnt,clmnt,mntrq,enc,res,jrnl)
	E  D
	. N P,db
	. S P("ClusterMountMode")=0
	. S P("Directory")=Y
	. S P("GlobalJournalState")=1
	. S P("MountAtStartup")=0
	. S P("MountRequired")=0
	. S P("Server")=""
	. S P("Size")=1
	. S P("StreamLocation")=""
	. S db=##Class(SYS.Database).%New()
	. S db.Directory=P("Directory")
	. S OK=db.%Save()
	. I OK S OK=##Class(Config.Databases).Create(X,.P)
CDBZ	Q
	;
ANS(X,Y)	;Add Namespace
	S X=$G(X),Y=$G(Y) Q:'$L(X)  Q:'$L(Y)
	I ($P($P($ZV,")",2),"(",1)[" 2008") D 
	. N dbsys,dbsysrou,dblib,dbtemp
	. S dbsys="CACHESYS",dbsysrou="CACHESYS",dblib="CACHELIB",dbtemp="CACHETEMP"
	. S OK=##class(Config.Configuration).AddNamespace(X_Y,X_"-G"_Y,X_"-R0",dbsys,dbsysrou,dblib,dbtemp)
	E  D
	. N P
	. S P("Globals")=X_"-G"_Y
	. S P("Library")="CACHELIB"
	. S P("Routines")=X_"-R0"
	. S P("SysGlobals")="CACHESYS"
	. S P("SysRoutines")="CACHESYS"
	. S P("TempGlobals")="CACHETEMP"
	. S OK=##Class(Config.Namespaces).Create(X_Y,.P)
ANSZ	Q
	;
GMX(B,C)	;Set globalmapping for database B, number C
	S B=$G(B),C=$G(C) Q:'$L(B)!'$L(C)
	K GMX D GMX^cQCPFR(B,C)
GMXZ	Q
	;
AGM(N,G,DB)	;Add globalmapping in namespace N for global G in database DB
	; D AGM^cQCPFN("TST1","DOC","TST-G0")
	; maps ^DOC to the G0 database in namespace TST1
	N NS,OK,P
	S N=$G(N),G=$G(G),G=$S($E(G)="^":$E(G,2,$L(G)),1:G),DB=$G(DB),P("Database")=DB,OK=0,NS=$ZU(5) zn "%SYS"
	I $L(N)&$L(G)&$L(DB),'(($P($P($ZV,")",2),"(",1)[" 3.")!($P($P($ZV,")",2),"(",1)[" 3.0")!($P($P($ZV,")",2),"(",1)[" 3.2")!($P($P($ZV,")",2),"(",1)[" 4.")!($P($P($ZV,")",2),"(",1)[" 4.0")!($P($P($ZV,")",2),"(",1)[" 4.0.4")!($P($P($ZV,")",2),"(",1)[" 5.")!($P($P($ZV,")",2),"(",1)[" 5.0")!($P($P($ZV,")",2),"(",1)[" 2008")) S OK=##Class(Config.MapGlobals).Create(N,G,.P)
	ZN NS
AGMZ	Q OK
	;
ER	U 0 W !,$ZE,!
	W !,"Error=",$SYSTEM.Status.GetErrorText(OK)
ERZ	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9