cQFLIST	;List Files ;cQFLIST;
	;
START	N E,FILE,I,K,L,S,T W !?10,$P($T(+1),";",2),! S $ZT="ERR^"_$T(+0)
	;
FILE	W !,"Filename: " R K
	G FILE:K?.E1C.E I K="-"!(K="^") G YZ
	S FILE=K W !!
TRANS	S T=0 W !,"Translate control characters ?  <Y>: " R K I "Yy"[K S T=1
SCROLL	S S=0 W !,"Srcoll ?  <Y>: " R K I "Yy"[K S S=1
	W !!
	;
OPEN	I $$TST^cQFILE(FILE) W "File ",FILE," does not exist!",! G FILE
	S K=" Start of "_FILE_" ",L="",$P(L,"-",70)="-",$E(L,35-($L(K)/2),34+($L(K)/2))=K
	U 0 S $Y=0 W L,! S L="",E=$$ORF^cQFILE(FILE,1)
	F  S E=$$RFF^cQFILE(FILE,.K,1) Q:E  D  I "-^"[L&$L(L) S E="Operator requested break" Q
	. U 0 I 'T I K?1C W /SGR(1),"<",$A(K),">",/SGR(0)
	. E  W K
	. I S I $Y>22 W "<NEXT>" R L S $Y=0 F I=1:1:$X W *8," ",*8
OPENE	I E'=99 u 0 W !,"End of file not reached!  Errorcode = ",E,!
	S E=$$CF^cQFILE(FILE)
	S K=" End of "_FILE_" ",L="",$P(L,"-",70)="-",$E(L,35-($L(K)/2),34+($L(K)/2))=K U 0 W !,L,!
	;
YZ	Q
	;
ERR	I $ZE["<INTERRUPT>" S $ZT="ERR^"_$T(+0),E="Interrupted by Operator" G OPENE
	U 0 W !,$ZE,!
	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9