cQJRNLT	;Show data from journalspace ;cQJRNLT;
	Q
	;
START	; select journalspace - copied from JRNDUMP
	W !!,"Show data from journalspace",!!
	D BLD(.A)
DISP	F I=1:1:A W !,$J(I,3),". ",A(I)
	W !!,"Enter sequence number of desired journalspace: " R K G YZ:K="^",START:K="-"
	S K=+K I '$D(A(K)) W !!,"Invalid input",!! G DISP
	;
	U 0 W !!,"Reading journalspace ",A(K),!
	D READ(A(K))
	Q
	;
READ(J)	; read journalfile
	S (%JFILE,JFILE)=J
	S ns=$ZU(5) ZN "%SYS"
	S X=$$OPENJRN^JRNUTIL(%JFILE) I X'=1 G ERR
	S X=$$USEJRN^JRNUTIL(%JFILE) I X'=1 G ERR
	S ADDR=0,k=""
	W !,"For a specific ProcessID ([enter] for none): " R K S PROC=+K
	W !,"For a specific Global ([enter] for none)   : " R K S GLOC=K
	I $L(GLOC),$E(GLOC)'="^" S GLOC="^"_GLOC
	W !
	F  S X=$$GETREC^JRNUTIL(ADDR,.JRNODE) Q:X'=1  D  Q:ADDR=0  Q:(k="-")!(k="^")
	. D DATA
	. D
	.. I (PROC&(PID'=PROC))!($L(GLOC)&(GLON'=GLOC)) Q
	.. U 0 W !,ADDR,?10,ADDRN,?20,ACT,!,GLO,!
	.. W !,"ProcessID: ",PID
	.. W !,"Global   : ",GLON
	.. W !,"Globaldb : ",GLOS
	.. W !,"Globalref: ",GLOR
	.. W !,"Old Value: ",$S('$D(VO):"<No value>",1:$$FORM(VO))
	.. W !,"New Value: ",$S('$D(V):"<No value>",1:$$FORM(V))
	.. W !,"Timestamp: ",DAY," ",TIME
	.. W ! r k
	. S ADDR=ADDRN K JRNODE
	S X=$$CLOSEJRN^JRNUTIL(%JFILE)
	ZN ns
	; 
YZ	Q
	;
BLD(A)	N K,JF,ns S ns=$ZU(5) zn "%SYS" K A
	S A=0,JF=$ZU(78,3) S:JF="" JF=$P($G(^%SYS("JOURNAL","LAST")),"^",2) I JF="" Q
	S A=A+1,A(A)=JF
	F  S K=$$PREVJRN^JRNUTIL2(JF,.JF) Q:K'>0  I '$ZU(140,4,JF) S A=A+1,A(A)=JF
	ZN ns
	Q
	;
DATA	;Get data
	K ACT,ADDRN,DATE,DAY,GLO,GLON,GLOR,GLOS,PID,TIME,V,VO
	S PID=$P($P(JRNODE(1,1),":"),"/",1) I $D(^SYS("PIDList",PID)) S PID=@$Q(^SYS("PIDList",PID))
	S ADDRN=$P($P(JRNODE(1,1),":"),"/",3)	;Get next address
	S ACT=$ZCONVERT($P(JRNODE(1,1),":",2),"U")	; Action, convert to upcase (v5)
	S GLO=$P(JRNODE(1,1),":",4,$L(JRNODE(1,1),":"))       ;full global reference
	S GLOS=$P($P(GLO,"^^",2),"""") S:'$L(GLOS) GLOS=0     ;database
	S GLOR=$S($L(GLO):"^"_$P(GLO,"]",2),1:"")   ;globalref
	S GLON=$P(GLOR,"(")    ;global
	S DATE=JRNODE(1,1,3),DAY=$ZD($P(DATE,",",1),3,,4),TIME=$$T($P(DATE,",",2))
	I $D(JRNODE(1,1,1)) S VO=JRNODE(1,1,1)
	I $D(JRNODE(1,1,2)) S V=JRNODE(1,1,2)
DATAZ	Q
	;
FORM(R)	;Display data
	S R=$G(R) N I
	I R?.E1C.E F I=1:1:$L(R) I $E(R,I)?1C S R=$E(R,0,I-1)_$c(27)_"[1m"_"$c("_$A(R,I)_")"_$c(27)_"[0m"_$E(R,I+1,$L(R))
FORMZ	Q R
	;
T(R)	S R=$G(R,$P($H,",",2))	
TZ	Q $E("0"_(R\3600),$L(R\3600),4)_":"_$E("0"_(R#3600\60),$L(R#3600\60),4)_":"_$E("0"_(R#3600#60\1),$L(R#3600#60\1),4)
	;
ERR	U 0 W !,$G(X),! G YZ
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9