cT159	;Inboeken wissels ;%T158 ; [ 01/02/01  11:02 AM ]
	S $ZT="TRAP^cAN000"
	G 0
	;
T0	;Inboeken wissels ;
T1	;Factuurnummer;[] = overzicht documenten   .[] = overzicht wisseldoc.;   B[] = bank;
T2	;Bevestiging\"V[] = definitief verwijderen";
T3	;Bedrag\"[] = openstaand   xxxx[] = bedrag factuur   xxxx-[] = bedrag cr.nota";Tot.;
T7	;Factuurdatum van factuur ; komt na wisseldatum
T8	;Een wissel mag geen voorschotten bevatten;
T9	;Klant;Leverancier;
T10	;Muntcode verschilt van ;
T11	;Ongeldige factuur;
T12	;V[] = verwijderen;
T13	;niet aanvaarde kredietbrief;aanvaarde kredietbrief;promesse
	;
T0F	;Inscription des traites ;
T1F	;N° de facture;[] = aperçu des documents   .[] = aperçu des doc. à traite;   B[] = banque;
T2F	;Confirmation\"V[] = annuler définitivement";
T3F	;Montant\"[] = solde   xxxx[] = montant facture    xxxx-[] = montant note de cr.";Tot.;
T7F	;Date du document; supérieure à la date de la traite
T8F	;Une traite ne peut pas contenir des acomptes;
T9F	;Client;Fournisseur;
T10F	;Code mon. différent du ;
T11F	;Le numéro de facture n'existe pas;
T12F	;V[] = annulation ;
T13F	;LCR non acceptée;LCR acceptée;billet à ordre;
	;
T0E	;Registration bills of exchange ;
T1E	;Invoice number;[] = survey documents       .[] = survey bill of exch. docs;   B[] = bank;
T2E	;Confirmation\"V[] = remove permanently";
T3E	;Amount\"[] = open   xxxx[] = invoice amount   xxxx-[] = amount cr.note";Tot.;
T7E	;Invoice date of document ; is after bills of exchange date
T8E	;A bill of exchange may not contain advances;
T9E	;Customer;Supplier;
T10E	;Currency differs from ;
T11E	;Invalid invoice;
T12E	;V[] = remove     ;
T13E	;niet aanvaarde kredietbrief;aanvaarde kredietbrief;promesse;:
	;
	; sorteren openstaande facturen
S1	K ^HULP(boot,$J) S FNR=1E5-1 F  S FNR=$O(@Q1) Q:FNR'?6N  S I=$$DC^cAFD1($S(SORT=2:DT,1:$P(^(FNR),D,2+SORT)))_FNR,^HULP(boot,$J,I)=FNR
S1Z	Q
	;
	; opentaande facturen
S2	K C8 S B1=0 F FP=1102:100:1802 W @F,$J("",56)
S2A	S C1=$O(^HULP(boot,$J,C1)) I C1="" S C1=99999 G S2Z
S2B	S FNR=^(C1),B1=B1+1,C8(FNR)=B1,K=@Q1 D OF G S2A:B1<8
S2Z	Q
	;
OF	W /CUP(C8(FNR)+10,2),$P(K,D),$J(FNR,7),$J($P(K,D,2),9),$J($P(K,D,3),9),$J($P(K,D,9),4)
OFA	I $P(K,D)="C" S $P(K,D,4)=-$P(K,D,4),$P(K,D,5)=-$P(K,D,5)
OFB	S DEC=$$DEC^cAFA1($P(K,D,9)) W $$IP^cAFA1($P(K,D,4),DEC,13),$$IP^cAFA1($P(K,D,5),DEC,13)
OFZ	Q
	;
	; wisselfacturen
S3	K C9 S B2=0 F FP=1159:100:1859 W @F,$J("",21)
S3A	S C2=$O(@("^"_Q_"WI(WNR,C2)")) I C2="" S C2=99999 G S3Z
S3B	S FNR=C2,B2=B2+1,C9(FNR)=B2,BDR=$P(^(C2),D,5) D WF G S3A:B2<8
S3Z	Q
	;
	; klant + facturen
S4	W /CUP(8,20),@F2 
S4A	W /CUP(8,2),@F6,$P($T(@("T9"_QT)),U,KZ="LE"+2),@F9,/CUP(8,19),": ",$E($$KL^cAFO1(KZ,KC,2),1,60)
S4B	S tFNR=FNR D S1 S C1=99999,C2=C1 D S2,S3 W /CUP(20,68),$$IP^cAFA1(TOT,QA,12) S FNR=tFNR
S4C	W /CUP(21,1),@F1 I $G(FNR),$D(C8(FNR)) W /CUP(C8(FNR)+10,32)," "
S4D	W /CUP(21,3),$P($P($T(@("T1"_QT)),U,2),D)," : ",FNR
S4Z	Q
	;
WF	I $P(^(C2),D)="C" S BDR=-BDR
WFA	W /CUP(C9(FNR)+10,59),$J(FNR,6),$$IP^cAFA1(BDR,QA,15)
WFZ	Q
	;
	;GM 06.04.04 - klant / leverancier keuze
0	I '$L($G(WKZ)) S WKZ="" G 09					;indien bestaande wissel, keuze overslaan
01	W /CUP(8,20),@F2
	I '$L($G(WKZ)) D UNLOCK(I1)					;unlocken van vorige klant / leverancier
03	S K=$$^cANSYN(KZ,"",WKZ,1,,,,,$P($T(@("T1"_QT)),U,2)) G YZ:K="-"	;nieuwe klant / leverancier kiezen
	I '$L(K) S BYFNR=$$BYFACT((KZ="KL")) G:BYFNR="-" 03			;GM 16.12.04 Mogelijkheid klant\lev te kiezen via factuurnr
05	S B(1)=^(0),KC=$P(B(1),D)						;variabelen opvullen
07	S I1=@("^"_Q_$E(KZ)_"1(KC)"),WKZ=""
09	W /CUP(8,2),@F6,$P($T(@("T9"_QT)),U,KZ="LE"+2),@F9,/CUP(8,19),": ",$E($$KL^cAFO1(KZ,KC,2),1,60)
	;
	; facturen sorteren & detail tonen
1	D S1 S C1=99999,C2=C1 D S2,S3 W /CUP(20,68),$$IP^cAFA1(TOT,QA,12)
11	W /CUP(21,1),@F1 I $G(FNR),$D(C8(FNR)) W /CUP(C8(FNR)+10,32)," "
	D INP  ; ophalen inputmogelijkheden (zie K(...) = commentaar_D_excute
	I $L($G(BYFNR)) S (K,FNR)=BYFNR,BYFNR="" G 12A
12	S R="FNR\22\3\"_$P($T(@("T1"_QT)),U,2)_"\COM\6\\""-.VB""[K&($L(K)<2)!(K?6N)!$S('$L(K):0,1:$D(K(K)))\\\1" D R0 
	G 01:K="-",4:K="V"
	I K="B",'BANKPAR G 12
	I K="B",KZ'="KL" G 12
	I K="B" D BANK
12A	I $L(K),$D(K(K)) X $P(K(K),D) G 11:K="-",1
13	I K'?6N D S3:FNR=".",S2:FNR="" G 11
15	W /CUP(21,3),$P($P($T(@("T1"_QT)),U,2),D)," : ",FNR
17	S WZ=0 I $D(@("^"_Q_"WI(WNR,FNR)")) S A=^(FNR),WZ=1 G:'$$KL(0,1) 11 D S4 G 29
19	;S VM=$P(^(0),D,8) I $O(^(0))="" S VM="" --> VM is vast "EUR"
	;
	; opzoeken openstaande factuur
2	I $E(FNR,1,2)=99  S K=$P($T(@("T8"_QT)),U,2) D F1 G 11
	I '$D(@Q1) S R=86 D F2 G 11   ; factuur onbekend
	I $$DH^cAFD1($P(@Q1,D,2))>$$DH^cAFD1(FDT) S K=$P($T(@("T7"_QT)),U,2)_FNR_$P($T(@("T7"_QT)),U,3) D F1 G 11   ; datum in toekomst
21	I '$D(C8(FNR)) S A=FNR D S2 S FNR=A G 21
23	W /CUP(C8(FNR)+10,32),"*"
25	S A=@Q1,K=$P(A,D,9) S:K="" K=BF
27	I $L(VM),K'=VM S K=$P($T(@("T10"_QT)),U,2)_VM D F1 G 11
28	I VM="" S VM="EUR",QA=$$DEC^cAFA1(VM) W /CUP(20,58),@F4,$P($T(@("T3"_QT)),U,3),VM," ",@F5,@F2
29	G:'$$LOCK 11 	; proberen te locken
	;
	; bedrag ingeven
3	S R="BDR\22\3\"_$P($T(@("T3"_QT)),U,2)_"\10\\""-""[K!$$W^cAFI2(K,QA,$P(A,D)=""C"")" D R0 G 11:K="-"
30	I $P(A,D)="C",$L(BDR) G 3:BDR'["-" S BDR=+BDR
31	S OF=$G(@Q1) I 'WZ,BDR>$P(OF,D,5) S R=217 D F2 G 3
33	I WZ,BDR>($P(OF,D,5)+$P(A,D,5)) S R=217 D F2 G 3
35	I 'WZ D ^cT1590 G 1      ; factuur toevoegen aan wissel
37	S WZ=BDR,BDR=0 D ^cT1591 ; factuur terug openstellen
39	S BDR=WZ,WZ=0 G 35
	;
	; verwijderen
4	S R="K\22\3\"_$P($T(@("T2"_QT)),U,2)_"\1\\""-V""[K&$L(K)\\\1" D R0 G 11:K'="V"
41	I $P($G(@("^"_Q_"BA(73,""IW"",""V"",0)")),D),$L($P(^(0),D,2)) S OK=1 X $P(^(0),D,2) I 'OK G 11
42	S FNR=99999,OK=1 F  S FNR=$O(@("^"_Q_"WI(WNR,FNR)")) Q:'$L(FNR)  D  I 'OK  D UNLOCK(,1) Q
	. I '$$KL(1,0) S OK=0  ; alle klanten / leveranciers proberen te locken
	I 'OK G 11
43	S FNR=99999
45	S FNR=$O(@("^"_Q_"WI(WNR,FNR)")) I FNR'="" S A=^(FNR),BDR=0 D KL(0,1) D ^cT1591 G 45
	D UNLOCK(,1)
47	S @%Q1=0,$P(@("^"_Q_"WI(WNR,0)"),D)=1,FNR=WNR K @Q1 S @%Q1=1
48	D S4 W /CUP(21,3),@F2 ;D S1 S (C1,C2)=1E5-1 D S2,S3 W /CUP(20,68),$$IP^cAFA1(TOT,QA,12)
49	G YZ
	;
BYFACT(TYPE) ; Klant of leverancier (en factuur) ophalen aan openstaand factuurnummer
	; Input: TYPE: 0: Openstaande aankoopfactuur
	; 	      1: Openstaande verkoopfactuur	
	; Output: Factuurnummer of "-"
	; 	 K=UI1 van klant of leverancier en last reference op node 0 van de klant\leverancier	      
	N BYFNR,GL,NODE,REF
	S $ZT="TRAP^cAN000"
	; 
	; Opzetten variabelen
	S GL1="AF" I TYPE S GL1="VF"
	S GL2="LE" I TYPE S GL2="KL"
	;
	; Vraag om factuurnummer
BYFACT1	S R="BYFNR\22\3\"_$P($T(@("T1"_QT)),U,2)_"\\6\\""-""[K&($L(K)<2)!(K?6N)\\\1\\1" D R0 G:(K="-") BYFACTZ G:'$L(K) BYFACT1
	S NODE=$G(@("^"_Q_GL1_"("_BYFNR_")")) I '$L(NODE) S K=$P($T(@("T11"_QT)),U,2) D F1 G BYFACT1
	;
	; Input en last reference juist zetten
	S K=$$UI1^cAFA1(GL2,101,$P(NODE,D)) 
	S REF=$$SG^cAFA1(GL2,$P(NODE,D),101) 
	;
BYFACTZ	Q $G(BYFNR)
	;
	; GM 06.04.04 eventueel van klant / leverancier wisselen
KL(LOCK,CHANGE) 	; Input: LOCK: 	0: niet locken
		;	    	1: locken		
		; CHANGE: 0: niet veranderen van klant / leverancier
		;	 1: eventueel veranderen van klant / leverancier
	N tI1,tKC,tB,OK
	S $ZT="TRAP^cAN000"
	S tI1=I1,tKC=KC,tB(1)=B(1),OK=1
	S KC=$P(@("^"_Q_"WI(WNR,FNR)"),D,25) I '$L(KC) S KC=$P(@("^"_Q_"WI(WNR,0)"),D,3)
	I tKC=KC G KLZ
	S I1=@("^"_Q_$E(KZ)_"1(KC)")
	I '$G(LOCK) G KLY
	S OK=$$LOCK I 'OK S I1=tI1,KC=tKC G KLZ
	I '$G(CHANGE) S LOCKT(I1)=1 G KLY
KLY	S B(1)=@("^"_Q_KZ_"(I1,0)")
	I '$G(CHANGE) S I1=tI1,KC=tKC,B(1)=tB(1)
KLZ	Q OK
	;
YZ	K B1,B2,C8,C9,WKLLOCK Q
	;
INP	; ophalen input
	; uitgang : COM  = commentaar
	;           K(x) = inputmogelijkheid
	;                  inhoud : execute (S K=$$...) uit te voeren bij keuze
	N I3,OK,A
	S $ZT="TRAP^cAN000"
	S COM=$P($T(@("T1"_QT)),U,3),COME=""
	S I3="" K K S K=""
	F  S I3=$O(@("^"_Q_"BA(73,""IW"",""M"",I3)")) Q:I3=""  D
	. S A=^(I3)
	. S OK=0
	. I '$L($P(A,D,3)) Q         ; indien geen execute ingevuld
	. I '$L($P(A,D,4)) Q         ; geen conditie ingevuld
	. X $P(A,D,4) I 'OK Q        ; bepalen OK : 0 = niet tonen, 1 = tonen
	. S K($P(A,D))=$P(A,D,3)     ; execute
	. S COME=$S($L(COME):"   ",1:"")_$P(A,D,QTU*10-8)
	; I '$L(COME) G INPY
	; S COM=COM_"   "_COME
	; I $L(COM)>77 S COM=$P(COM,"   "_COME),COM=" "_COM_$J("",79-$L(COM))_COME
INPY	; S COM=""""_COM_""""
INPZ	Q
	;
	; commentaar ipv via INP
COM	W !?2,$P($T(@("T1"_QT)),U,3)
	I KZ="KL",BANKPAR W $P($T(@("T1"_QT)),U,4)
	W !?2,$P($T(@("T12"_QT)),U,2)
	I $L(COME) W "           ",COME
COMZ	Q
	;
LOCK() 	
	; Locken van huidige klant / leverancier
	; Indien de wisselklant / leverancier nog niet is gelockt, ook locken
	N OK,FNR,IND
	S $ZT="TRAP^cAN000"
	S FNR=0
	S OK=$$PLUS^cANLOCK(Q1,,$P($T(@("T9"_QT)),U,2+(KZ'="KL"))_" "_$P(I1," ",2),1) I 'OK G LOCKZ
	I '$G(WKLLOCK) S IND=@("^"_Q_$E(KZ)_"1(WKC)") S OK=$$PLUS^cANLOCK("^"_Q_KZ_"(IND,0)",,$P($T(@("T9"_QT)),U,2+(KZ'="KL"))_" "_$P(IND," ",2),1)  I 'OK D UNLOCK(I1) G LOCKZ
	S WKLLOCK=1
LOCKZ	Q OK
	;
UNLOCK(I1,SW)	
	; Input: I1: klant / leverancier die moet ge-unlockt worden
	; 	     SW: indien 1: volledige LOCKT unlocken
	N KL,FNR
	S $ZT="TRAP^cAN000"
	S FNR=0
	I '$G(SW)!'$D(LOCKT) G UNLOCKY
	S KL="" F  S KL=$O(LOCKT(KL)) Q:'$L(KL)  D  
	. N I1
	. S I1=KL
	. L -@Q1 
	G UNLOCKZ
UNLOCKY	I $L($G(I1)) L -@Q1 
UNLOCKZ	Q
	;
	; module B[] : wijzigen banknummer, banknaam en accept - code
BANK	N ACC,NR,NAAM,WINUL,UI1
	S $ZT="TRAP^cAN000"
	S UI1=WNR
	K ^TEMP(boot,$j)
	S WINUL=@("^"_Q_"WI(WNR,0)")
	S ^TEMP(boot,$j,WNR,0)=$P(WINUL,D,10,13)
	D W^cAN200("WI.BANK","","","",$$IDEM^cAFA1)
	S $P(@("^"_Q_"WI(WNR,0)"),D,10,13)=$P(^TEMP(boot,$J,WNR,0),D,1,4)
	K ^TEMP(boot,$j)
BANKZ	Q
	;
ACCOUT(ACC) ; output accept - codes
	S STRING=""
	S STRING=$P($T(@("T13"_QT)),U,2+ACC)
ACCOUTZ	Q STRING
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
F1	S R=250
F2	D TXT^cAFA1(R)
FZ	K R Q
	;
ZZ	; 04.04.05 - 14 u 29 * V8.03