cT181A5	;Controle analytische boekhouding ; ^cT181A4 ; Go naar ^cT181A6 [ 01/06/2004  11:00 AM ]  ; Compiled December 8, 2011 12:06:21
	;
	; De controle-globals opgebouwd via de dagboeken worden vergeleken
	; met de controle-globals opgebouwd via de 2-historieken van de rekeningen.
	;
T0	;Analytische controle boekhouding ;
T1	;Vergelijking resultaten analytische rekeningen ;
T2	; klopt; debet verschilt : ; credit verschilt : ;
T3	;Vergelijking resultaten grootboekrekeningen ;
	;
T0F	;Contrôle comptabilité analytique ;
T1F	;Comparaison des résultats comptes analytique
T2F	; ok; débit diffère : ; crédit diffère : ;
T3F	;Comparaison des résultats comptes de grand-livre ;
	;
T0E	;Analytische controle boekhouding ;
T1E	;Vergelijking resultaten analytische rekeningen ;
T2E	; klopt; debet verschilt : ; credit verschilt : ;
T3E	;Vergelijking resultaten grootboekrekeningen ;
	;
	; initialisatie
1	S Q2="",Q5="",Q9=""
	S Q0="^"_Q_"CNTRLA(X1,I1)",Q3="^"_Q_"CNTRLA(X1,I1,I2)",Q7="^"_Q_"CNTRLA(X1,I1,I2,I3)",Q11="^"_Q_"CNTRLA(X1,I1,I2,I3,I4)"
11	S Q1="^"_Q_"CNTRLA(X2,I1)",Q4="^"_Q_"CNTRLA(X2,I1,I2)",Q8="^"_Q_"CNTRLA(X2,I1,I2,I3)",Q12="^"_Q_"CNTRLA(X2,I1,I2,I3,I4)"
	;
	; analytische rekeningen
15	S Q10="^"_Q_"ARA(I2,0)",X1=10 W !,$P($T(@("T1"_QT)),U,2),! D 8,2
	; grootboekrekeningen
16	S Q10="^"_Q_"AR(I2,0)",X1=20 W !,$P($T(@("T3"_QT)),U,2),! D 8,2
	;
	G YZ
	;
2	; Ontbrekende nodes opzetten: dagboeken -> 2-historieken
	S (I1,I2,I3,I4)=""
22	S I1=$O(@Q0) G:'$L(I1) 3 S:'$D(@Q1) ^(I1)=0_D_0
24	S I2=$O(@Q3) G:'$L(I2) 22 S:'$D(@Q4) ^(I2)=0_D_0
26	S I3=$O(@Q7) G:'$L(I3) 24 S:'$D(@Q8) ^(I3)=0_D_0
28	S I4=$O(@Q11) G:'$L(I4) 26 S:'$D(@Q12) ^(I4)=0_D_0
	G 28
	;
3	; Ontbrekende nodes opzetten: 2-historieken -> dagboeken
	S (I1,I2,I3,I4)=""
32	S I1=$O(@Q1) G:'$L(I1) 4 S:'$D(@Q0) ^(I1)=0_D_0
34	S I2=$O(@Q4) G:'$L(I2) 32 S:'$D(@Q3) ^(I2)=0_D_0
36	S I3=$O(@Q8) G:'$L(I3) 34 S:'$D(@Q7) ^(I3)=0_D_0
38	S I4=$O(@Q12) G:'$L(I4) 36 S:'$D(@Q11) ^(I4)=0_D_0
	G 38
	;
4	; Vergelijking dagboeken <-> 2-historieken
	S (I1,I2,I3,I4)=""
42	S I1=$O(@Q0) W I1," " S SW1=1 G:'$L(I1) 7 
	;S X=@Q0,XX=Q0 D S1	; Per maand, debet en credit checken
	;S X=@Q1,XX=Q1 D S1
44	S I2=$O(@Q3) S SW2=1 I '$L(I2) D K1 G 42 
46	S I3=$O(@Q7) S SW3=1 I '$L(I3) D K2 G 44
48	S I4=$O(@Q11) S SW4=1 I '$L(I4) D K3 G 46 
	S D1=$P((@Q11),D),C1=$P((@Q11),D,2)
	S D2=$P((@Q12),D),C2=$P((@Q12),D,2)
	S DEB=D1-D2,CRE=C1-C2 D S3,K4
	G 48
	;-------------------------
K4	K:SW4 @Q12,@Q11 Q
K3	K:SW3 @Q8,@Q7 Q
K2	K:SW2 @Q4,@Q3 Q
K1	Q  
	;--------------------------
	;
7	K A,B,C,SW,SWS,SW1,SW2,SW3,SW4,SW5,SW6,SR,V,V1,Z,XX,ZZ 
	Q
	;
	; initialisatie
8	S I1="",X2=X1+1 
81	S I1=$O(@Q1) I $L(I1) S:'$D(@Q0) ^(I1)=D G 81
83	Q
	;
YZ	K X1,X2,X3,Q4,Q5,Q6,Q7,Q8,Q9,Q10
	D ^cA105 S $P(@("^"_Q_"CNTRLA"),D,4)=TD_D_$G(FOUT,0)_D
	I '$G(JOB) D W^cA612:$G(QW) G ^cT181A6:$D(FOUT)
	Q
	;
	; debet en credit
S1	S B="" I $P(X,D)=$P(X,D,2) S B=$P($T(@("T2"_QT)),U,2)
	S @XX=X_D_B
S1Z	Q
	;
	; Debet-credit verschilt
S3	S ERR=""
	I +DEB S ERR=$P($T(@("T2"_QT)),U,3)_DEB S FOUT=300,(SW1,SW2,SW3,SW4)=""
	I +CRE S:$L(ERR) ERR=ERR_" &" S ERR=ERR_$P($T(@("T2"_QT)),U,4)_CRE S FOUT=300,(SW1,SW2,SW3,SW4)=""
S3Z	S @Q12=@Q12_ERR Q
	;
ZZ	; 04.11.04 - 10 u 11 * V8.02