cT185A ;Controle boekhouding ;%T181 ;do uit %T185 ; [ 02/23/00  9:03 AM ]
 ;
T0 ;Controle boekhouding ;
T1 ;Historieken & cumuls van de analytische rekeningen;
T2 ;bestaat niet in dagboek;geen ventilatie in dagboek;van andere rekening;
 ;
T0F ;Contrôle comptabilité ;
T1F ;Historiques & cumuls des comptes analytiques;
T2F ;n'existe pas dans le journal;pas d'imputation dans le journal;d'un autre compte;
 ;
T0E ;Controle boekhouding ;
T1E ;Historieken & cumuls van de analytische rekeningen;
T2E ;bestaat niet in dagboek;geen ventilatie in dagboek;van andere rekening;
 ;
 ; initialisatie
1 S Q0="^"_Q_"CNTRL(101,I1,I2,I3)",Q1="^"_Q_"ARA(I2)",Q2="^"_Q_"ARA(I2,Y)"
11 S Q3="^"_Q_"FI(I1,I3,N)",Q4="^"_Q_"VE(I1,N)",Q5="^"_Q_"AA(I1,N)"
12 S Q30="^"_Q_"FIE(I1,I3,N)"
13 S Q6="^"_Q_"CNTRL(102,I1,I2)",Q7="^"_Q_"CNTRL(103,I1,I2,V)"
15 S BP=BPA+.01 S:BPC BP=BPC W !,$P($T(@("T1"_QT)),U,2),!
17 S I2=0
 ;
 ; alle rekeningen
2 S I2=$O(@Q1) G YZ:I2="" S Y=1_BP*100-.001,V="" W $E(I2)
21 S Y=$O(@Q2) G 3:Y="" S I1=$E(Y,2,5)_"."_$E(Y,6,7),A=^(Y) I I1<BP!(I1'=BP&BPC) G 21
22 I $E(Y)=2,Y?1N7E6N1"."1N.N!(Y?1N7E6N1U.UN) G 21   ; geen analyt. hist.
23 I $E(Y,8)="B" S I3=$E(Y,9,99),A(0)=$P(A,D,3),A(1)=$P(A,D,4) D S1 G 21
25 I $E(Y,8)="V"!($E(Y,8)="A") S I3=$E(Y,8),A(0)=$P(A,D,3),A(1)=$P(A,D,4) D S1 G 21
27 I Y["." D S2   ; detailhistorieken
29 G 21
 ;
 ; cumuls voor de gevraagde boekingsmaanden
3 S BJ=$P(BPA(0),D,2),Y=BJ\1,BPB=+BPA(0)
31 S A1=$G(^(Y)),B1=$G(^(Y+.02)),A2=$G(^(Y+1)),B2=$G(^(Y+1.02)),A3=$G(^(Y+2)),B3=$G(^(Y+2.02))
33 S Y=$P(BPA(0),D,3),I1=BPA I BPC S I1=BPC G 37
35 S I1=I1+.01 G 2:I1>BPH S:$L(I1)=6 I1=I1_0 S:$P(I1,".",2)>12 I1=I1+.88
37 S:I1>BJ BPB=BJ\1*12+(BJ#1*100),BJ=BJ+1,A1=A2,B1=B2,A2=A3,B2=B3,(A3,B3)="" S BX=I1\1*12+(I1#1*100)-BPB+1
38 I +$P(B1,D,BX)!+$P(A1,D,BX) S @Q6=$P(A1,D,BX)_D_$P(B1,D,BX)
39 G 2:BPC,35
 ;
YZ K A,A1,A2,A3,B1,B2,B3,N,CD Q
 ;
 ; resultaat controle historiek
S1 I A(0)!A(1) S:'$D(@Q0) @Q0=D S ^(I3)=^(I3)+A(0)_D_($P(^(I3),D,2)+A(1))
S1Z Q
 ;
 ; aflopen velden detailhistoriek
S2 S (A(0),A(1))=0,Z=$P(A,D),A=$P(A,D,2,99) G S2Z:'$L(A)&'$L(Z) S I3=$E(Z),N=$E(Z,2,99) G S2:V=Z S V=Z
S2A I I3="V" G S2E:'$D(@Q4) S B=@Q4,CD=$P(B,D)="F",SW=1 D S3,S1 G S2
S2B I I3="A" G S2E:'$D(@Q5) S B=@Q5,CD=$P(B,D)="C",SW=1 D S3,S1 G S2
S2C I I3="B" S I3=$P(N,"#"),N=$P(N,"#",2) G S2E:'$D(@Q3) S B=@Q3 G S2F:$P(B,D,7)'="A",S2F:$P(B,D,16)'=I2
 I I3="E" S I3=$P(N,"#"),N=$P(N,"#",2) G S2E:'$D(@Q30) S B=@Q30 G S2F:$P(B,D,7)'="A",S2F:$P(B,D,16)'=I2
S2D S CD=$P(B,D,6)="C",A(CD)=$P(B,D,5) D S1 G S2
S2E S @Q7=$P($T(@("T2"_QT)),U,2),FOUT=3 G S2
S2F S @Q7=$P($T(@("T2"_QT)),U,4),FOUT=3 G S2
S2Z Q
 ;
 ; aflopen ventilaties per factuur
S3 S N=N+.01 G S3Z:'$D(^(N)) S B=^(N)
S3A F I=1:1 S K=$P(B,D),B=$P(B,D,2,999) Q:K=B  I $P(K,"#",9)=I2 S A(CD)=A(CD)+$P(K,"#",4),SW=0
S3B G S3
S3Z S:SW @Q7=$P($T(@("T2"_QT)),U,3),FOUT=3 Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84