cT411	;Pointeren voorschotten: printen lijst; cT41
	;
	G 1
	;
T0	;Pointeren voorschotten;
T1	;Rekening: ;
T2	;Openstaande punten;
T3	;Boekjaar ;
T4	; Klant\Datum\Debet;2\Credit;2\Saldo;2\ Referte\A;
T5	;Nog te pointeren;Beginsaldo;
T6	;SUBTOTAAL 1;
T7	;j;
T8	;SUBTOTAAL 2;
T9	;MANUELE VERRICHT.;
T10	;SUBTOTAAL 3;
T11	;TOTAAL SALDO;
	;
T0F	;Pointage automatique;
T1F	;Compte: ;
T2F	;Points ouverte;
T3F	;Exercice ;
T4F	; Client\Date\Debit;2\Credit;2\Solde;2\ Ref.\A;
T5F	;Encore à pointer;Solde init.;
T6F	;SOUS TOTAL 1;
T7F	;O;
T8F	;SOUS TOTAL 2;
T9F	;OPER.MANUELLES;
T10F	;SOUS TOTAL 3;
T11F	;TOTAL SOLDE;
	;
1	N REK,BSAL,I1,KC,I2,LIJN,FMNT,BEDR,FILIJN,IND1,IND2,IND3,SALDO,TSALDO
11	S $ZT="TRAP^cAN000"
	; Opzoeken rekening uit parameters
13	S REK=$P(@("^"_Q_"BA(""%F"",21)"),D)
	;  Opzetten hoofding
15	S HD(1)="\"_$P($T(@("T1"_QT)),U,2)_REK_" ;C;F83;\"
17	S HD(2)="\"_$P($T(@("T2"_QT)),U,2)_" ;C;F83;\"
19	S HD(3)="\"_$P($T(@("T3"_QT)),U,2)_KJ_" ;C;F83;\"
	;
	;  Opzetten kolommen + titels
2	S TAB="19\25\37\49\61\77\79"
21	S TIT(1)=$P($T(@("T4"_QT)),U,2,99)
23	S FMNT=$P($$MNTC^cAFE1(Q,KJ),D)
	;
	;  Aflopen van ^TEMP + printen van de lijst
	;  Printen deel 1 van de lijst
	;  Printen beginsaldo
3	S TXT(1)=$P($T(@("T5"_QT)),U,2),TXT(2)="",BSAL=$P($G(^TEMP(boot,$J,1,1,0)),D,2)
31	S BSAL=$$OMREK^cAFE1(Q,BSAL,FMNT,$P(MUNT,D),"V",$P(MUNT,D,2))
33	I BSAL<0 S TXT(3)="",TXT(4)=$E(BSAL,2,99)_"\1\\\1\"_$P(MUNT,D,2)
35	I BSAL'<0 S TXT(3)=BSAL_"\1\\\1\"_$P(MUNT,D,2),TXT(4)=""
37	S TXT(5)=BSAL_"\1\\\1\"_$P(MUNT,D,2),TXT(6)=$P($T(@("T5"_QT)),U,3)    
39	S END=0 D ^cA334
	;
	;  Printen deel 1 van de lijst (gesorteerd op naam van de klant)
4	S I1="",TSALDO=0
41	F  S I1=$O(^TEMP(boot,$J,2,I1)) Q:I1=""  D
	. S KC=^(I1)
	. I '$D(^TEMP(boot,$J,1,1,KC)) Q
	. S TXT(1)=$$SG^cAFA1("KL",KC,101)_" "_$P(^(0),D,2)_"\\\\\\\\\1"
	. S I2=""
	. F  S I2=$O(^TEMP(boot,$J,1,1,KC,I2)) Q:I2=""  D
	.. S LIJN=^(I2)
	.. S IND1=$E($P(LIJN,D),2,5)_"."_$E($P(LIJN,D),6,7)
	.. S IND2=$E($P($P(LIJN,D,3),"#"),2,99)
	.. S IND3=$P($P(LIJN,D,3),"#",2)
	.. S FILIJN=@("^"_Q_"FI(IND1,IND2,IND3)")
	.. S TXT(2)=$P(FILIJN,D,2)
	.. S BEDR=$P(LIJN,D,4)
	.. S BEDR=$$OMREK^cAFE1(Q,BEDR,FMNT,$P(MUNT,D),"V",$P(MUNT,D,2))
	.. I BEDR<0 S TXT(3)="",TXT(4)=$E(BEDR,2,99)_"\1\\\1\"_$P(MUNT,D,2)
	.. I BEDR'<0 S TXT(3)=BEDR_"\1\\\1\"_$P(MUNT,D,2),TXT(4)=""
	.. S TXT(5)=BEDR_"\1\\\1\"_$P(MUNT,D,2)
	.. S TXT(6)=$P(FILIJN,D,9)
	.. S END=0 D ^cA334
	;  Printen subtotaal 1
43	S END=3 D ^cA334
45	S TXT(1)=$P($T(@("T6"_QT)),U,2),BEDR=$P($G(^TEMP(boot,$J,1,1,0)),D)
46	S BEDR=$$OMREK^cAFE1(Q,BEDR,FMNT,$P(MUNT,D),"V",$P(MUNT,D,2)),TSALDO=TSALDO+BEDR
47	S TXT(2)="",TXT(3)="",TXT(4)="",TXT(6)="",TXT(5)=BEDR_"\1\\\1\"_$P(MUNT,D,2)
48	S END=0 D ^cA334
49	S END=3 D ^cA334
	;
	;  Printen deel 2 van de lijst (gesorteerd op naam van de klant)
5	S I1=""
51	F  S I1=$O(^TEMP(boot,$J,2,I1)) Q:I1=""  D
	. S KC=^(I1)
	. I '$D(^TEMP(boot,$J,1,2,KC)) Q
	. S TXT(1)=$$SG^cAFA1("KL",KC,101)_" "_$P(^(0),D,2)_"\\\\\\\\\1"
	. S I2=""
	. F  S I2=$O(^TEMP(boot,$J,1,2,KC,I2)) Q:I2=""  D
	.. S LIJN=^(I2)
	.. S IND1=$E($P(LIJN,D),2,5)_"."_$E($P(LIJN,D),6,7)
	.. S IND2=$E($P($P(LIJN,D,3),"#"),2,99)
	.. S IND3=$P($P(LIJN,D,3),"#",2)
	.. S FILIJN=@("^"_Q_"FI(IND1,IND2,IND3)")
	.. S TXT(2)=$P(FILIJN,D,2)
	.. S BEDR=$P(FILIJN,D,5)
	.. S BEDR=$$OMREK^cAFE1(Q,BEDR,FMNT,$P(MUNT,D),"V",$P(MUNT,D,2))
	.. I $P(FILIJN,D,6)="D" S TXT(3)=BEDR_"\1\\\1\"_$P(MUNT,D,2),TXT(4)=""
	.. I $P(FILIJN,D,6)="C" S TXT(4)=BEDR_"\1\\\1\"_$P(MUNT,D,2),TXT(3)=""
	.. S SALDO=$P(LIJN,D,4)
	.. S SALDO=$$OMREK^cAFE1(Q,SALDO,FMNT,$P(MUNT,D),"V",$P(MUNT,D,2))
	.. S TXT(5)=SALDO_"\1\\\1\"_$P(MUNT,D,2)
	.. S TXT(6)=$P(FILIJN,D,9)
	.. S TXT(7)=$S($P(LIJN,D,5)=1:$P($T(@("T7"_QT)),U,2),1:"")
	.. S END=0 D ^cA334
	; Printen subtotaal 2
53	S END=3 D ^cA334
55	S TXT(1)=$P($T(@("T8"_QT)),U,2),BEDR=$P($G(^TEMP(boot,$J,1,2,0)),D)
56	S BEDR=$$OMREK^cAFE1(Q,BEDR,FMNT,$P(MUNT,D),"V",$P(MUNT,D,2)),TSALDO=TSALDO+BEDR
57	S TXT(2)="",TXT(3)="",TXT(4)="",TXT(6)="",TXT(7)="",TXT(5)=BEDR_"\1\\\1\"_$P(MUNT,D,2)
58	S END=0 D ^cA334
59	S END=3 D ^cA334
	;
	;  Printen deel 3 van de lijst
6	S TXT(1)=$P($T(@("T9"_QT)),U,2)_"\\\\\\\\\1"
61	S I1=""
63	F  S I1=$O(^TEMP(boot,$J,1,3,"Z",I1)) Q:I1=""  D
	. S LIJN=^(I1)
	. S IND1=$E($P(LIJN,D),2,5)_"."_$E($P(LIJN,D),6,7)
	. S IND2=$E($P($P(LIJN,D,3),"#"),2,99)
	. S IND3=$P($P(LIJN,D,3),"#",2)
	. S FILIJN=@("^"_Q_"FI(IND1,IND2,IND3)")
	. S TXT(2)=$P(FILIJN,D,2)
	. S BEDR=$P(LIJN,D,4)
	. S BEDR=$$OMREK^cAFE1(Q,BEDR,FMNT,$P(MUNT,D),"V",$P(MUNT,D,2))
	. I BEDR<0 S TXT(3)="",TXT(4)=$E(BEDR,2,99)_"\1\\\1\"_$P(MUNT,D,2)
	. I BEDR'<0 S TXT(3)=BEDR_"\1\\\1\"_$P(MUNT,D,2),TXT(4)=""
	. S TXT(5)=BEDR_"\1\\\1\"_$P(MUNT,D,2)
	. S TXT(6)=$P(FILIJN,D,9)
	. S END=0 D ^cA334
	;  Printen subtotaal 3
64	S END=3 D ^cA334
65	S TXT(1)=$P($T(@("T10"_QT)),U,2),BEDR=$P($G(^TEMP(boot,$J,1,3,0)),D)
66	S BEDR=$$OMREK^cAFE1(Q,BEDR,FMNT,$P(MUNT,D),"V",$P(MUNT,D,2)),TSALDO=TSALDO+BEDR
67	S TXT(2)="",TXT(3)="",TXT(4)="",TXT(6)="",TXT(7)="",TXT(5)=BEDR_"\1\\\1\"_$P(MUNT,D,2)
68	S END=0 D ^cA334
69	S END=3 D ^cA334
	;
	;  Printen TOTAAL subtotaal
7	S TXT(1)=$P($T(@("T11"_QT)),U,2)
71	S TXT(2)="",TXT(3)="",TXT(4)="",TXT(6)="",TXT(7)="",TXT(5)=TSALDO_"\1\\\1\"_$P(MUNT,D,2)
73	S END=0 D ^cA334
75	S END=1 D ^cA334
	;
YZ	Q
	;
ZZ	; 18.04.02 - 15 u 36 * V7.92