cT412	;Pointeren voorschotten: automatisch pointeren; cT41
	;
	G 1
	;
T0	;Pointeren voorschotten;
	;
T0F	;Pointage des acomptes;
	;
1	N REK,KC,I2,LIJN,OK,VNR,KCF,COM,SWPNT,IND1,STUK,SALDO,BSAL,NSALDO,VNRPNT
11	S $ZT="TRAP^cAN000"
13	S REK=$P(@("^"_Q_"BA(""%F"",21)"),D)_" "
	;  Locken van ^_Q_ARP(REK
15	S OK=$$PLUS^cANLOCK("^"_Q_"ARP(REK)",2,"",1) I 'OK G YZ
16	S @%Q1=0
	;  Aflopen van deel 2 van de lijst
17	S KC=0
19	F  S KC=$O(^TEMP(boot,$J,1,2,KC)) Q:KC=""  D
	. ; opzoeken factuutklant, commentaar + volgnummer van pointeren
	. S KCF=$P($G(^TEMP(boot,$J,1,2,KC)),D)
	. S COM=$$SG^cAFA1("KL",KC,101)_$S($L(KCF):" ("_KCF_") ",1:" ")_$P(^(0),D,2)
	. S VNR=$G(@("^"_Q_"ARP(REK,0)"),1)
	. S SWPNT=0
	. S SALDO=0
	. S I2=""
	. F  S I2=$O(^TEMP(boot,$J,1,2,KC,I2)) Q:I2=""  D
	.. S LIJN=^(I2)
	.. ;  controle of lijn kan worden gepointeerd
	.. I $P(LIJN,D,5)'=1 Q
	.. S SWPNT=1
	.. S SALDO=SALDO+$P(LIJN,D,6)
	.. S IND1=$P(LIJN,D)
	.. S STUK=$P(LIJN,D,2)
	.. ;  pointeren van de lijn
	.. S $P(@("^"_Q_"ARP(REK,IND1)"),D,STUK)=VNR
	. ;  indien lijn werd gepointeerd volgnummer van pointeren ophogen + commentaar lijn wegschrijven
	. I SWPNT=1 D
	.. S @("^"_Q_"ARP(REK,0,VNR)")=$H_D_QU_D_COM_D_SALDO
	.. S @("^"_Q_"ARP(REK,0)")=VNR+1
	.. ;  Pointeren tov het beginsaldo
	.. I SALDO'=0 D
	... S BSAL=$$BSAL^cT410(KJ)
	... I SALDO<0 S NSALDO=BSAL+(-SALDO)
	... I SALDO>0 S NSALDO=BSAL-SALDO
	... S $P(@("^"_Q_"ARP(REK,0,VNR)"),D,4)=NSALDO
	... S VNRPNT=$G(@("^"_Q_"ARP(REK,KJ)"))
	... S $P(@("^"_Q_"ARP(REK,0,VNR)"),D,5)=VNRPNT
	... S @("^"_Q_"ARP(REK,KJ)")=VNR
	;
Y	L -@("^"_Q_"ARP(REK)")
	S @%Q1=1
YZ	Q
	;
ZZ	; 18.04.02 - 15 u 36 * V7.92