cT540 ;Vergelijking eind- en beginbalans ;%T54 ; [ 01/03/01  11:20 AM ]
 G 1
 ;
T0 ;Vergelijking eind- en beginbalans;
T1 ;Reëel;Theoretisch;
T2 ;Nummer\Omschrijving\eindsaldo;2\beginsaldo;2;
T3 ;Overdracht;Eindtotaal;
 ;
T0F ;Comparaison bilan final et initial;
T1F ;Réalité;Théorie;
T2F ;Numéro\Description\solde final;2\solde init.;2;
T3F ;Transfert;Total final;
 ;
T0E ;Comparison between final and initial balance;
T1E ;Real;Theoretical;
T2E ;Number\Description\final balance;2\Initial balance;2;
T3E ;Transfer;Final total;
 ;
 ; opbouw hulpbestand
1 S I1=0,(TVW,TVWE)=0 K ^HULP(boot,$J)
11 S I1=$O(@("^"_Q_"AR(I1)")),SW=SWA I I1="" G 3
13 S B(1)=$G(^(I1,0),I1_"\?") I $P(B(1),D,13)=1 G 11 ; geen tekstrek.
15 S X=$G(^(BJ1)),Y=$G(^(BJ1+.02))                   ; cumuls BJ1
17 S RES=X F I=2:1:24 S RES=RES+$P(X,D,I)-$P(Y,D,I)  ; reëel eindsaldo
19 I 'SW,RES S SW=1
 ;
 ; beginsaldi
2 S TBS=RES I $P(B(1),D,20) S TBS=0,TVW=TVW+RES I RES,$L(AR2) S TVWE=TVWE+$$BEDR^cAFE1(Q,RES,$P(MNTC1,D),$P(MNTC2,D),"F")
21 S TBSE=TBS I TBSE,$L(AR2) S TBSE=$$BEDR^cAFE1(Q,TBSE,$P(MNTC1,D),$P(MNTC2,D),"F")
23 S RBS=+$G(^(BJ2)) I 'SW,RBS S SW=1                ; reëel beginsaldo
25 I SW S ^HULP(boot,$J,I1)=$P(B(1),D,1,2)_D_RES_D_TBS_D_TBSE_D_RBS
27 G 11
 ;
 ; verrekening V/W
3 I 'TVW G 4
31 S B(1)=$P(@("^"_Q_"AR(AR1,0)"),D,1,2)_"\\\\"
33 I $D(^HULP(boot,$J,AR1)) S B(1)=^(AR1)
35 S $P(B(1),D,4)=$P(B(1),D,4)+TVW                   ; theoretisch bsal
37 I $L(AR2) S $P(B(1),D,5)=$P(B(1),D,5)+TVWE
39 S ^(AR1)=B(1)
 ;
 ; 400.000 tov klanten
4 I '$L(AR2) G 5
41 S (I1,TKL)=0,J=$$BJ^cAFE1(Q,DJ_"."_DM),MNTO=$$MNTO^cAFE1(Q,J)
42 S I1=$O(@("^"_Q_"KL(I1)")),I2=9999 I I1="" G 47   ; volgende klant
43 S X=$G(^(I1,BJ2)),Y=$G(^(BJ2+.02)),BS=0 F I=2:1:24 S BS=BS-$P(X,D,I)+$P(Y,D,I)
44 S I2=$O(^(I2)) I I2>9999,I2<1E6 D S1("V") G 44
45 S TKL=TKL+BS G 42
47 S I1=$P(VERBOT,D,2) D S2(I1,TKL)
49 S I1=$O(SAL("")) I $L(I1) D S2(I1,SAL(I1)) K SAL(I1) G 49   ; wissels
 ;
 ; 440.000 tov leveranciers
5 I '$L(AR2) G 6
51 S (I1,TLE)=0
52 S I1=$O(@("^"_Q_"LE(I1)")),I2=9999 I I1="" G 57   ; volgende lev.
53 S X=$G(^(I1,BJ2)),Y=$G(^(BJ2+.02)),BS=0 F I=2:1:24 S BS=BS+$P(X,D,I)-$P(Y,D,I)
54 S I2=$O(^(I2)) I I2>9999,I2<1E6 D S1("A") G 54
55 S TLE=TLE+BS G 52
57 S I1=$P(VERBOT,D,4) D S2(I1,-TLE)
59 S I1=$O(SAL("")) I $L(I1) D S2(I1,-SAL(I1)) K SAL(I1) G 59  ; wissels
 ;
 ; omrekeningsverschillen
6 I '$L(AR2) G 7
61 S (I1,TOM)=0
63 S I1=$O(^HULP(boot,$J,I1)) I $L(I1) S TOM=TOM+$P(^(I1),D,5) G 63
65 S B(1)=$P(@("^"_Q_"AR(AR2,0)"),D,1,2)_"\\\\"
66 I $D(^HULP(boot,$J,AR2)) S B(1)=^(AR2)
67 S $P(B(1),D,5)=$P(B(1),D,5)-TOM                   ; omrekeningsverschil
69 S ^(AR2)=B(1)
 ;
 ; initialisatie
7 S HD(1)=D,HD(2)=D_$P($T(@("T0"_QT)),U,2)_";C",HD(3)=D
71 S TAB="9\34\49\64\79" I $L(AR2) S TAB=TAB_"\94"
73 S I=$T(@("T1"_QT)),TIT(1)="\\"_$P(I,U,2)_";2\"_$P(I,U,3)_";2\"_$P(I,U,2)_";2\"
74 I $L(AR2) S TIT(1)=$P(TIT(1),D,1,4)_D_$P(I,U,3)_";2\"_$P(I,U,2)_";2\"
75 S I=$T(@("T2"_QT)),TIT(2)=$P(I,U,2,99)_D_$P(I,D,4) I $L(AR2) S TIT(2)=TIT(2)_D_$P(I,D,4)
77 S TIT(3)="\\"_BP_" ("_$P(MNTC1,D)_");2\"_BJ2_" ("_$P(MNTC1,D)_");2\"_BJ2_" ("_$P(MNTC2,D)_");2\"
78 I $L(AR2) S TIT(3)=TIT(3)_BJ2_" ("_$P(MNTC2,D)_");2\"
79 S AFS(1,2)=$P($T(@("T3"_QT)),U,2)
 ;
 ; printen rekeningen
8 S I1=""
81 S I1=$O(^HULP(boot,$J,I1)) I I1="" S AFS(1,2)=$P($T(@("T3"_QT)),U,3),END=1 D ^cA334 G YZ
83 S B(1)=^(I1),TXT(1)=$P(B(1),D)_"\\\\\\$E(K,1,3)_$S($L(K)>3:"".""_$E(K,4,9),1:"""")"
85 S TXT(2)=$P(B(1),D,2)
87 S TXT(3)=$P(B(1),D,3)_"\\\\1\"_$P(MNTC1,D,2)_"\\1"     ; eindsaldo
89 S TXT(4)=$P(B(1),D,4)_"\\\\1\"_$P(MNTC1,D,2)_"\\1"     ; theoretisch bs
 ;
9 S TXT(5)=$P(B(1),D,5)_"\\\\1\"_$P(MNTC2,D,2)_"\\1"     ; theoretisch bs
91 S TXT(6)=$P(B(1),D,6)_"\\\\1\"_$P(MNTC2,D,2)_"\\1"     ; reëel bs
93 I '$L(AR2) S TXT(5)=TXT(6),TXT(6)=""
95 D ^cA334 G 81
 ;
YZ K ^HULP(boot,$J) G YZ^cT54
 ;
 ; omrekening document
S1(P) S N=^(I2),WR=$P(N,D,14)
S1A I I2?5N S SAL(WR)=$G(SAL(WR))+$$BEDR^cAFE1(Q,$P(N,D,5),$P(MNTO,D),$P(MNTC2,D),P)
S1B I I2?6N S BS=$P(N,D)="F"*2-1*$$BEDR^cAFE1(Q,$P(N,D,10),$P(MNTO,D),$P(MNTC2,D),P)+BS
S1Z Q
 ;
 ; opzetten beginsaldo
S2(I,J) S B(1)=$P(@("^"_Q_"AR(I,0)"),D,1,2)_"\\\\"
S2A I $D(^HULP(boot,$J,I)) S B(1)=^(I)
S2B S $P(B(1),D,5)=J,^(I)=B(1)
S2Z Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84