cT561 ;WIJZIGEN NUMMERS GROOTBOEKREKENINGEN ;%T56 ; [ 01/03/01  12:28 PM ]
 ;
T0 ;Wijzigen nummers grootboekrekeningen ;
 ;
T0F ;Modification numérotation des comptes ;
 ;
T0E ;Modification of general account numbers ;
 ;
1 S X="B"_II1,Y="B"_II2
11 S G="AR",GP="ARP" D S1,S2,S3,S4
13 S G="KL",GP="" D S1
15 S G="LE",GP="" D S1
17 S G="ARA",GP="" D S1,S2,S3,S4
 ;
YZ Q
 ;
 ; detailhistorieken gewone boekhouding
S1 S I=0 ZA ^HULPE(0) S HULPE=$G(^HULPE(0),1),^(0)=HULPE+1 ZD ^HULPE(0) I $D(^(HULPE)) G S1
S1A S I=$O(@("^"_Q_G_"(I)")),J=1E6
S1B I $L(I) S J=$O(@("^"_Q_G_"(I,J)")) I $E(J)=1,J?7N1"."1N.N D S10 G S1B
S1C I $L(I) D S11 G S1A
S1D ZA ^HULPE(0) K ^HULPE(HULPE) I $O(^(HULPE))="" S ^(0)=HULPE I HULPE>1,$O(^(0))="" S ^(0)=1
S1Z ZD ^HULPE(0) K HULPE Q
 ;
S10 S S1=^(J),S1P="" K ^(J) I $L(GP) S S1P=$G(@("^"_Q_GP_"(I,J)")) K ^(J)
S10A F S2=1:1 S S3=$P(S1,D,S2) Q:S3=""  D S100
S10Z K S1,S2,S3,S4,S1P Q
 ;
S100 I $P(S3,"#")=X S $P(S3,"#")=Y
S100A S S4=$G(^HULPE(HULPE,$E(J,1,7),0),1),^(0)=S4+1,^(S4)=S3_D_$P(S1P,D,S2)
S100Z Q
 ;
S11 S S2=""
S11A S S2=$O(^HULPE(HULPE,S2)),(S1,S1P)="",(S3,S4)=0 I S2="" K ^HULPE(HULPE) G S11Z
S11B S S3=$O(^HULPE(HULPE,S2,S3)),S5=$S(S3:^(S3),1:""),S5P=$P(S5,D,2),S5=$P(S5,D)
S11C I $L(S5),$L(S1)+$L(S5)<255 D S110 G S11B
S11D D S111 G S11C:$L(S5),S11A
S11Z K S1,S2,S3,S4,S5,S1P,S5P Q
 ;
S110 S S1=S1_S5_D I S5P S $P(S1P,D,$L(S1,D)-1)=S5P
S110Z Q
 ;
S111 S S4=S4+.01 I S4>.99 X "STOP"
S111A S @("^"_Q_G_"(I,S2_S4)")=S1 I $L(S1P) S @("^"_Q_GP_"(I,S2_S4)")=S1P
S111Z S (S1,S1P)="" Q
 ;
 ; globaalhistorieken gewone boekhouding
S2 S I=0
S2A S I=$O(@("^"_Q_G_"(I)")),J=1E6_" "
S2B I $L(I) S J=$O(@("^"_Q_G_"(I,J)")) I $E(J)=1,J?7N1U.UN D S20 G S2B
S2C I $L(I) G S2A
S2Z Q
 ;
S20 I $E(J,8,99)=X S ^($E(J,1,7)_Y)=^(J) K ^(J)
S20Z Q
 ;
 ; detailhistorieken analytische boekhouding
S3 S I=0 ZA ^HULPE(0) S HULPE=$G(^HULPE(0),1),^(0)=HULPE+1 ZD ^HULPE(0) I $D(^(HULPE)) G S3
S3A S I=$O(@("^"_Q_G_"(I)")),J=2E7
S3B I $L(I) S J=$O(@("^"_Q_G_"(I,J)")) I $L(J) D S30 G S3B
S3C I $L(I) D S11 G S3A
S3D ZA ^HULPE(0) K ^HULPE(HULPE) I $O(^(HULPE))="" S ^(0)=HULPE I HULPE>1,$O(^(0))="" S ^(0)=1
S3Z ZD ^HULPE(0) K HULPE Q
 ; 
S30 S S1="" I $E(J)=2,J?1N7E6N1"."1N.N S S1=^(J),S1P="" K ^(J) I $L(GP) S S1P=$G(@("^"_Q_GP_"(I,J)")) K ^(J)
S30A F S2=1:1 S S3=$P(S1,D,S2) Q:S3=""  D S300
S30Z K S1,S2,S3,S4,S1P Q
 ;
S300 I $P(S3,"#")=X S $P(S3,"#")=Y
S300A S S4=$G(^HULPE(HULPE,$E(J,1,14),0),1),^(0)=S4+1,^(S4)=S3_D_$P(S1P,D,S2)
S300Z Q
 ;
 ; globaalhistorieken analytische boekhouding
S4 S I=0
S4A S I=$O(@("^"_Q_G_"(I)")),J=2E7
S4B I $L(I) S J=$O(@("^"_Q_G_"(I,J)")) I $L(J) D S40 G S4B
S4C I $L(I) G S4A
S4Z Q
 ;
S40 I $E(J)=2,J?1N7E6N1U.UN,$E(J,15,99)=X S ^($E(J,1,14)_Y)=^(J) K ^(J)
S40Z Q
 ;
 ; link analytische - grootboek (detail + globaal)
S5 S I=0
S5A S I=$O(@("^"_Q_G_"(I)")),J=2E7
S5B I $L(I) S J=$O(@("^"_Q_G_"(I,J)")) I $L(J) D S50 G S5B
S5C I $L(I) G S5A
S5Z Q
 ;
S50 I $E(J)=2,$E(I1_$J("",7),1,7)=$E(J,2,8),J?1N7E6N1"."1N.N!(J?1N7E6N1U.UN) S ^($E(J)_$E(I2_$J("",7),1,7)_$E(J,9,99))=^(J) K ^(J)
S50Z Q
 ;
Z X ^cZ Q
ZZ ; 05.02.01 - 16 u 23 * V7.84