cT66E2	;Leveranciersbetalingen V6 ;%T66 ;Do uit %T66E1 ; [ 09/05/01  11:33 AM ]
	G 1
	;
T0	;Opbouw ^_Q_L3 ;
	;
T0F	;Construction ^_Q_L3 ;
	;
T0E	;Opbouw ^_Q_L3 ;
	;
	; opzetten variabelen ivm compatibiliteit vroegere versie
1	S Q1="DUMMY(NR)",Q2="^"_Q_"L1(LNR)",Q3="^"_Q_"LE(I1,0)"
11	S Q41="^"_Q_"AR(BR,0)"
13	S Q4="^"_Q_"L3(PRO,DATUM)",Q50="^"_Q_"L3(PRO,DATUM,LNR)",Q51="^"_Q_"L3(PRO,DATUM,LNR,I1)",Q52="^"_Q_"L3(PRO,DATUM,LNR,J1)"
	;
	; initialisatie
2	S DATUM=$$DC^cAFA1(DAT)_"."_BVB K @Q4
21	S K=$$OMREK^cAFE1(Q,1,HBF,"EUR","F",99) I $P(BA39,D,11)'="" S K=$$OMREK^cAFE1(Q,1,"EUR",$P(BA39,D,9),"F",99)
23	S TREC=0_D_BNK_D_PRO_D_0_D_1001_D_0_D_HBF_D_HQD_D_SWBB_D_K,@Q4=TREC
	;
	; opbouw bestand
3	S LNR="",SW=0 F  Q:SW  S LNR=$O(^HULP(boot,$J,LNR)) Q:LNR=""  D
	. S I1=$$UI1^cAFA1("LE",101,LNR)
	. S VM="" F  Q:SW  S VM=$O(^HULP(boot,$J,LNR,VM)) Q:VM=""  D
	.. S I="" F  Q:SW  S I=$O(^HULP(boot,$J,LNR,VM,I)) Q:I=""  D
	... S J=^(I)        ; kopie van BVB.DET
	... S FNR=$P(J,D,2),OF=$G(@("^"_Q_"LE(I1,FNR)")) I OF="" D E5^cT66E Q
	... I $P(OF,D)="C" S $P(J,D,3)=-$P(J,D,3),$P(J,D,4)=-$P(J,D,4)
	... S H=$P(J,D,5),H=^DATA(Q,"BVB.LE.B",BVB,H)
	... S N=LNR_D I $L($P(H,D,4)) S N=N_$P(H,D,4)_" "           ; adres
	... S N=N_$P(H,D,3)_D_$P(H,D,5,10)_D
	... S N=N_$P(OF,D)_D_I_D_$P(J,D,3)_D_$P(OF,D,6,7)_D_FNR_D   ; factuur
	... S N=N_$$SIG^cAFA1("LE",I1,110)_D_VM_D_$P(J,D,4)_D_$P(OF,D,15)_D
	... S N=N_$$OMREK^cAFA1($P(J,D,4),HBF,BF,"A",1)
	... S K=$P(OF,D,5)-$P(N,D,11),KX=$P(OF,D,6) I KX,K<KX S $P(N,D,12)=K
	... S J1=$P(TREC,D,5),$P(TREC,D,5)=J1+1
	... S $P(N,D,20)=$P(H,D,11)  ; 05.11.07 : KU : BIC
	... S VMED=$$VMED(FNR) I $L(VMED) S $P(N,D,13)=VMED ; 31.03.08 - GM
	... S J1=VM_" "_J1,@Q52=N,@Q4=TREC
31	I 'SW S $P(@Q4,D)=$$SIG^cAFA1("BVB",BVB,105)
	I 'SW S $P(@Q4,D,11)=$$SIG^cAFA1("BVB",BVB,107)   ; aanduiding Europees
	I SW K @Q4
	;
YZ	K ^HULP(boot,$J) Q
	;
VMED(FNR) ; Vrije mededeling uit aankoop-document halen
	; Input:  FNR: Factuurnummer
	; Output: R: Vrije mededeling
	; 
	; Uitleg: indien vrije mededeling is ingevuld primeert deze boven
	; ------  factuurnr leverancier. Deze vrije mededeling zit echter
	;         niet in de openstaande factuur, maar wel in het aankoop-
	;         dagboek.
	; 
	N R,AA,BP
	S $ZT="TRAP^cAN000"
	;
	; Controle parameters
VMED1	S R="" I '$L($G(FNR)) G VMEDZ
	;
	; Boekingsmaand bepalen
VMED2	S AA="^"_Q_"AA(BP)",BP=""
VMED21	S BP=$O(@AA,-1) G:'$L(BP) VMEDZ  I '$D(@AA@(FNR)) G VMED21
	;
	; Vrije mededeling
VMED23	S R=$P(@AA@(FNR),D,40)
	;
VMEDZ	Q R
	;
ZZ	; 18.04.08 - 16 u 39 * V9.01