cT866	;Eenmalige boekingsreeksen ;%T86* ; [ 01/22/01  10:25 AM ]
	G YZ
	;
T0	;Boekhoudkundige verwerking ;
T7	;Boekingsmaand niet ingevuld of niet toegelaten.;
T8	;Analyt. maand niet ingevuld of niet toegelaten.;
T9	;Saldo verschillend van 0.;
T10	;Selectie onmogelijk.;
T11	;Referte;
T12	;Lange omschrijving;
T13	;Datum uittreksel niet ingevuld. ;
T14	;Journaal onbekend of buiten gebruik. ;
T15	;Rekeningen niet overal ingevuld. ;
	;
T0F	;Comptabiliser ;
T7F	;Mois comptable n'est pas rempli ou pas permi.;
T8F	;Mois analyt. n'est pas rempli ou pas permi.;
T9F	;Solde n'est pas 0.;
T10F	;Sélection impossible.;
T11F	;Référence;
T12F	;Description longue;
T13F	;Date d'extrait inconnu. ;
T14F	;Code journal inconnu où hors usage. ;
T15F	;Comptes inconnus. ;
	;
T0E	;Accounting processing ;
T7E	;Fiscal month is not entered or not allowed.;
T8E	;Analyt. month is not entered or not allowed.;
T9E	;Balance differs from 0.;
T10E	;Impossible selection; 
T11E	;Reference; 
T12E	;Long description; 
T13E	;Statement date is not entered.  ;  
T14E	;Unknown journal or out of use.  ; 
T15E	;Not all accounts are entered. ; 
	;
	; toggle boekingen (selecteren/deselecteren)
TOG	N UREF,USC,UQC,UI1 D DMS^cAN000("UQC","USC","FID.J")
	S $ZT="TRAP^cAN000"
TOGA	S UREF=^DMC(UQC,USC,"DATA","REF") K ^HULP(boot,$J+.02) 
TOGB	S UI1=0 F  S UI1=$O(@UREF) Q:UI1=""  I JRNO="."!($P(^(UI1,0),D,3)=JRNO) M ^HULP(boot,$J+.02,UI1)=@UREF
TOGC	D BS^cAN210("FID.J.S",0,0,0,"") K ^HULP(boot,$J+.02)
TOGZ	Q
	;
	; boeken van gekozen boekingsreeks
B	N INH,VOLG,BP,BPE,BPEC,JRN,REF,OMS,REF1,REFOK,LOMS1,LOMSOK
	S $ZT="TRAP^cAN000"
BA	S (BENTER,VOLG,REF1,LOMS1)="",(LOMSOK,REFOK)=0
BB	S VOLG=$O(^HULP(boot,$J+.02,VOLG)) G BZ:VOLG="" S INH=^(VOLG,0) G BB:'$P(INH,D,10)
BC	S BP=$P(INH,D,4),OKBP=$$OKBP(BP) I K="-" G BB
BD	S BPE=$P(INH,D,5),BPEC="YZ^"_$T(+0)
BE	S JRN=$P(INH,D,3),REF=$P(INH,D,6),OMS=$P(INH,D,2),LOMS=$P(INH,D,7),BODAT=$P(INH,D,11)
BF	S BJ=$$BJ^cAFE1(Q,BP),K=$$MNTC^cAFE1(Q,BJ),BF=$P(K,D),QD=$P(K,D,2),HBF=BF,HQD=QD,PAR=$$CNVC^cAFE1(Q,BJ,1,HBF,"F",99)
BG	S RB="D" S:JRN RB=RB_JRN S K=$$DC^cAFD1(BODAT),Q93="^"_Q_"BA(4,RB,"_K_")",@Q93=$G(@Q93,K_"0001") L +@Q93:2 E  G BB
BH	S:'$L(REF1) REF1=REF S:'$L(LOMS1) LOMS1=LOMS
BI	G BZ:LOMSOK&(K="-") I 'REFOK S R="REF1\22\3\"_$P($T(@("T11"_QT)),U,2)_"\\15\\",$P(R,D,13)=1 D R0 G BZ:K="-"!(K=",")
BJ	I 'LOMSOK S R="LOMS1\22\3\"_$P($T(@("T12"_QT)),U,2)_"\\50\\",$P(R,D,13)=1 D R0 G BI:K="-"!(K=",")
BK	S (REFOK,LOMSOK)=1 D ^cT864 L -@Q93 G BB
BZ	Q
	;
	;check boekingsmaand ok ?
OKBP(BP)	S OK=0 I '$G(BENTER) G OKZ:"-,"[K!(RK=31)
	N K,R S K=+$P(BP,".",2),R=K_D_$S($G(BENTER):1,1:0)_D_1 D M^cT163 I K="-" S OK=0
OKZ	Q OK
	;
	;check analytische maand ok ?
OKABP(BP)	S OK=1 G OKAZ:"-,"[K!(RK=31)
	I BP'>$P(@("^"_Q_"BA(2)"),D,3) S OK=0
OKAZ	Q OK
	;
	; check boek.maand /anal.maand ingevuld bij selectie
SELOK(R)	N OBP,BP,BPE,UI1,SALDO,BDAT,JRN,JRNS,OK,BA300 S UI1=R
SELOKA	S SALDO=0,UI1=R,OK=1,(OBP,BP)=$P(@UREF@(0),D,4),BPE=$P(^(0),D,5),BDAT=$P(^(0),D,11),JRN=$P(^(0),D,3)
SELOKB	I 'BP S OK=0 S K=$P($T(@("T7"_QT)),U,2)_$P($T(@("T10"_QT)),U,2) D F1 G SELOKZ
SELOKC	I 'BDAT S OK=0 S K=$P($T(@("T13"_QT)),U,2)_$P($T(@("T10"_QT)),U,2) D F1 G SELOKZ
SELOKD	I BP'>@("^"_Q_"BA(7)") S OK=0 S K=$P($T(@("T7"_QT)),U,2)_$P($T(@("T10"_QT)),U,2) D F1 G SELOKZ
SELOKE	S R=+$P(BP,".",2)_D_1_D_1 D M^cT163 I 'OK!(BP'=OBP) S OK=0,K=$P($T(@("T7"_QT)),U,2)_$P($T(@("T10"_QT)),U,2) D F1 G SELOKZ
	S BA300=+@("^"_Q_"BA(300)")
SELOKF	I $D(@("^"_Q_"BA")@("SWBP")),BPE'>$P(^(2),D,3) S OK=0,K=$P($T(@("T8"_QT)),U,2)_$P($T(@("T10"_QT)),U,2) D F1 G SELOKZ
SELOKG	I Q'="VK",$$DC^cAFD1("01."_$P(BPE,".",2)_"."_$E(BPE,3,4))'<$$DC^cAFD1(DT) S OK=0,K=$P($T(@("T8"_QT)),U,2)_$P($T(@("T10"_QT)),U,2) D F1 G SELOKZ
SELOKH	S VOLG=UI1_" " F  S VOLG=$O(^DATA(Q,"FID.J.DET",VOLG)) Q:VOLG=""!($P(VOLG," ")'=UI1)  S:'$P(^(VOLG,0),D) OK=0 Q:'OK  S AR=$P(^(0),D) S:BA300&($$SIG^cAFA1("AR",AR,106)&('$P(^DATA(Q,"FID.J.DET",VOLG,0),D,4))) OK=0 Q:'OK  S BEDRAG=$P(^(0),D,2) S:BEDRAG["-" BEDRAG=-BEDRAG S SALDO=SALDO+BEDRAG
	I 'OK S K=$P($T(@("T15"_QT)),U,2)_$P($T(@("T10"_QT)),U,2) D F1 G SELOKZ
SELOKI	I SALDO S K=$P($T(@("T9"_QT)),U,2)_$P($T(@("T10"_QT)),U,2),OK=0 D F1 G SELOKZ
SELOKJ	S JRNS="D"_$S(+JRN:$E(1000+JRN,2,4),1:"") I '$D(@("^"_Q_"BA(""%T"",JRNS)"))!$P($G(^(JRNS)),D,3) S K=$P($T(@("T14"_QT)),U,2)_$P($T(@("T10"_QT)),U,2),OK=0 D F1 G SELOKZ
SELOKZ	Q OK
	;
YZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
F1	S R=250
F2	D TXT^cAFA1(R)
FZ	K R Q
	;
ZZ	; 04.11.04 - 10 u 11 * V8.02