cT870(GL)	; Wijzigen omschrijving voorschotten ; cT870
	;
T0	;Wijzigen omschrijving voorschotten;
T1	;Voorschotten
	;
T0F	;Modification description acomptes;
T1F	;Acomptes;
	;
T0E	;Modification description advances;
T1E	;Advances;
	;
1	K ^TEMP(boot,$J),^TEMP(boot,"VOOR")
	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
13	S K=$$^cANSYN(GL) G YZ:K="-" S (UI1,UI1KL)=K,KC=$P(UI1," ",2)
	S ^TEMP(boot,"VOOR",UI1)="",LOCKREF="^TEMP(boot,""VOOR"",UI1)"
	S OK=$$PLUS^cANLOCK(LOCKREF,"",$P($T(@("T1"_QT)),U,2),1,0) G 13:'OK
	;
2	S I2=990000 F  S I2=$O(@("^"_Q_GL_"(UI1,I2)")) Q:$E(I2,1,2)'=99  S INH=^(I2) D
	. I GL="KL" S $P(INH,D,4)=-$P(INH,D,4),$P(INH,D,10)=-$P(INH,D,10)
	. S ^TEMP(boot,$J,I2,0)=I2_D_D_D_$P(INH,D,2)_D_$P(INH,D,9)_D_$P(INH,D,4)_D_$P(INH,D,10)
	. S FI=$P(INH,D,21),IND1=$P(FI,"#"),IND2=$P(FI,"#",2),IND3=$P(FI,"#",3)
	. Q:'$L(FI)
	. S $P(^TEMP(boot,$J,I2,0),D,2)=$P(@("^"_Q_"FI(IND1,IND2,IND3)"),D,9)
	. S $P(^TEMP(boot,$J,I2,0),D,3)=$P(@("^"_Q_"FI(IND1,IND2,IND3)"),D,15)
	. S $P(^TEMP(boot,$J,I2,0),D,8)=FI
	. S $P(^TEMP(boot,$J,I2,0),D,9)=$P(@("^"_Q_"FI(IND1,IND2,IND3)"),D,3)
	. S $P(^TEMP(boot,$J,I2,0),D,10)=$P(@("^"_Q_"FI(IND1,IND2,IND3)"),D,4)
	;
3	D BS^cAN210("VOOR",0,0,0,"","")
	;
	K ^TEMP(boot,$J),^TEMP(boot,"VOOR") L -^TEMP(boot,"VOOR",UI1KL) G 13
	;
YZ	Q
	;
WIJZIG(FI)	; wegschrijven referte en omschrijving in fiancieel dagboek en bij voorschot
	N BP,REK,I3,INH
	S $ZT="TRAP^cAN000"
	S INH=@UREF@(0)
	S BP=$P(FI,"#"),REK=$P(FI,"#",2),I3=$P(FI,"#",3)
	S $P(@("^"_Q_GL_"(UI1KL,UI1)"),D,7)=$P(INH,D,2)
	S $P(@("^"_Q_"FI(BP,REK,I3)"),D,9)=$P(INH,D,2),$P(^(I3),D,15)=$P(INH,D,3)
WIJZIGZ	Q
	;
ZZ	; 24.02.06 -  9 u 54 * V8.06