cTA18(SW) ;Ingeven beginsaldo ;cTA18 ; [ 09.04.04  8:40 AM ]
	; 
	; Input: SW: 0 of "" = Lokaal
	; 	    1       = IAS
	;
	G 1
	;
T0	; Beginsaldi grootboekrek./anal.rek. ;
T1	;Boekjaar;Grootboekrekening;
T2	;Onevenwichten;
T3	;Boekjaar;Grootboekrekening;Beginsaldo;Analytisch;Niet-anal.;
T4	;IAS-rekeningen; 
T5	;Boekjaar ; moet afgesloten zijn;
T6	;Boekjaar\"JJJJ[] = specifiek jaar   [] = ";
	;
T0F	; Solde init. compte du gr.-livre/compte anal. ;
T1F	;Excercice comptable;Compte du gr.-livre;
T2F	;Déséquilibres;
T3F	;Excercice compt.;Compte du gr.-livre;Solde initial;Analytique;Non anal.;
T4F	;Comptes IAS;
T5F	;L'exercice ; doit être clôturé;
T6F	;Année comptable\"AAAA[] = année spécifique   [] = ";
	;
T0E	; Initial balances general acc./analytical acc. ;
T1E	;Fiscal year;General account;
T2E	;Unbalances;
T3E	;Fiscal year;General account;Initial balance;Analytical;Non-anal.;
T4E	;IAS-accounts;
T5E	;Fiscal year ; must be closed;
T6E	;Fiscal year\"YYYY[] = particular year   [] = ";
	;
	; Schermopbouw
1	S $ZT="TRAP^cAN000"
	;
	S tQ=Q 
	I '$G(SW) D    ; Eventueel van Q-waarde switchen
	. N tQ,QU
	. S Q=$E(Q,2,$L(Q)) D ^cA604
	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
	W /CUP(2,3),"1. "_$P($T(@("T1"_QT)),U,2),/CUP(2,25),":"
	W /CUP(3,3),"2. "_$P($T(@("T1"_QT)),U,3),/CUP(3,25),":"
	;
	; Boekjaar
	D ^cT489 S BJR=BJ 
	I BJR<$$STARTJR^cTA180(Q) S K=$P($T(@("T5"_QT)),U,2)_($$STARTJR^cTA180(Q)-1)_$P($T(@("T5"_QT)),U,3) D F1 G YZ
	S MAXJR=BJR G 21
2	S R="BJR\22\3\"_$P($T(@("T6"_QT)),U,2)_"_BJ\4\\""-""[K!(K?4N&$L(K)&(K'<$$STARTJR^cTA180(Q))&(K'>MAXJR))\\\\\1" D R0 G YZ:K="-"
21	W /CUP(2,27),BJR
	;
	; Grootboekrekening
3	S BR=$$^cANSYN("AR",,,1,,,,,$P($T(@("T2"_QT)),U,2))
	I BR="-" G 2
	I BR="" G 5
	S B(1)=^(0) I $P(B(1),D,13) S R=200 D F2 G 3 ; Tekstrekening of buiten gebruik
	S BR=BR_" ",BEGIN=BR,EINDE=BR_"z"
	;
	; Beginsaldi
4	D BS^cAN210("BS.AR.ARA",0,0,0,"",1+$P(@("^"_Q_"BA(300)"),D,8)) 	
	G 3
	;
5	; Onevenwichten
	D ONEVEN(BJR)
	D BS^cAN210("BS.ONEVEN",0,0,0,"")
	K ^TEMP(boot,$J,"ONEVEN")	
	G 3
	;
YZ	D C^cA612 
	S Q=tQ D
	. N QU
	. D ^cA604 
	Q
	;
TOP1(BR,BJR)	; Top horizontaal scherm ingeven beginsaldi
	; Input:	BR:	Grootboekrekening
	; 	BJR:	Boekjaar
	N BS,TOT,I,BRUI1,NANAL,REK
	S $ZT="TRAP^cAN000"
	;
	S BS=$$BSAL^cAFE1(Q,BJR,"AR",BR)
	S REK=$P($$REK^cTA180("")," ")
	S I=BR,(TOT,NANAL)=0 F  S I=$O(^INDEX(Q,"CUM.AR.ARA",101,I)) Q:$P(I," ")'=$P(BR," ")  D
	. S BRUI1=^(I)
	. I $P(^DBH(Q,"CUM.AR.ARA",BRUI1,0),D,4)'=(BJR_".00") Q
	. I $P(BRUI1," ",3)=REK S NANAL=NANAL+$P(^(0),D,10) Q
	. S TOT=TOT+$P(^(0),D,10)
	; 
	; UTOP opzetten
	S UTOP(1)="2\1\"_$P($T(@("T3"_QT)),U,2)_"\4"      ; Boekjaar
	S UTOP(1.1)="2\20\: "_BJR_D_0
	S UTOP(2)="3\1\"_$P($T(@("T3"_QT)),U,3)_"\4"      ; Grootboekrekening
	S UTOP(2.1)="3\20\: "_$E(BR_$$SIG^cAFA1("AR",BR,102),1,27)_D_0
	S UTOP(3)="2\50\"_$P($T(@("T3"_QT)),U,4)_"\4"      ; Beginsaldo
	S UTOP(3.1)="2\60\: "_$$IP^cAFA1(BS,QD,17)_D_0
	S UTOP(4)="3\50\"_$P($T(@("T3"_QT)),U,5)_"\4"      ; Analytisch
	S UTOP(4.1)="3\60\: "_$$IP^cAFA1(TOT,QD,17)_D_0
	S UTOP(5)="4\50\"_$P($T(@("T3"_QT)),U,6)_"\4"      ; Niet-analytisch
	S UTOP(5.1)="4\60\: "_$$IP^cAFA1(NANAL,QD,17)_D_0
	S OK=0
TOP1Z	Q
	;
TOP3(UI1) ; Top logging
	; Input: UI1
	;
	N BS,TOT,I,BRUI1
	S $ZT="TRAP^cAN000"
	;
	S BR=$$SIG^cAFA1("BS.AR.ARA",$G(UI1),101)
	S BJR=$E($$SIG^cAFA1("BS.AR.ARA",$G(UI1),104),1,4)
	;
	; UTOP opzetten	
	S UTOP(1)="2\1\"_$P($T(@("T3"_QT)),U,2)_"\4"      ; Boekjaar
	S UTOP(1.1)="2\20\: "_BJR_D_0
	S UTOP(2)="3\1\"_$P($T(@("T3"_QT)),U,3)_"\4"      ; Grootboekrekening
	S UTOP(2.1)="3\20\: "_BR_$$SIG^cAFA1("AR",BR,102)_D_0
	S UTOP(3)="4\1\ "
	S UTOP(3.1)="4\20\ "
	S OK=0
TOP3Z	Q
	;
TOPTOT(BR,BJR)	; Enkel "Totaal" opnieuw opzetten in top ingeven beginsaldi
	; Input:	BR:	Grootboekrekening
	; 	BJR:	Boekjaar	
	N TOT,I,BRUI1,REK
	S $ZT="TRAP^cAN000"
	;
	S REK=$P($$REK^cTA180("")," ")
	S I=BR,(TOT,NANAL)=0 F  S I=$O(^INDEX(Q,"CUM.AR.ARA",101,I)) Q:$P(I," ")'=$P(BR," ")  D
	. S BRUI1=^(I)
	. I $P(^DBH(Q,"CUM.AR.ARA",BRUI1,0),D,4)'=(BJR_".00") Q
	. I $P(BRUI1," ",3)=REK S NANAL=NANAL+$P(^(0),D,10) Q
	. S TOT=TOT+$P(^(0),D,10)
	;
	; Opzetten UTOP
	S UTOP(4.1)="3\60\: "_$$IP^cAFA1(TOT,QD,17)_D_0	; Analytisch
	S UTOP(5.1)="4\60\: "_$$IP^cAFA1(NANAL,QD,17)_D_0	; Niet-analytisch	
TOPTOTZ Q
	;
TOP2(BJR)	; Top onevenwichten
	; Input:	BJR:	Boekjaar
	S $ZT="TRAP^cAN000"
	;
	; Opzetten UTOP
	S UTOP(1)="2\1\"_$P($T(@("T3"_QT)),U,2)_"\4"      ; Boekjaar
	S UTOP(1.1)="2\18\: "_BJR_D_0
	S OK=0
TOP2Z	Q
	;
BSUI1()	; Van UI1 van de index overgaan naar UI1 van de data
	S $ZT="TRAP^cAN000"
	N R
	S R="S UI1="""_$P(UI1," ",2,6)_""""
BSUI1Z Q R
	;
IASSYN(DEFAULT) ; IAS-rekeningen synoniemen
	; Input:	DEFAULT:	= default A-code 
	N ARA
	S $ZT="TRAP^cAN000"
	S ARA=$P($G(DEFAULT)," ")
IASSYNZ Q $$^cANSYN("ARA",,ARA,,,,,$P($T(@("T4"_QT)),U,2))
	;
UI1(INH)	; UI1 samenstellen van beginsaldo K-code / A-code / IAS-code
	; Input:	INH:	= B(1) bij het openen
	N K,MT
	S $ZT="TRAP^cAN000"
	;S MT=$P(INH,D,4)
	I $E($P(INH,D,3),$L($P(INH,D,3)),$L($P(INH,D,3)))'=" " S $P(INH,D,3)=$P(INH,D,3)_" "
	S K=$TR($P(INH,D,4),".","")_" "_$P(INH,D)_$P(INH,D,2)_$P(INH,D,3)_$TR($P(INH,D,5),".","")
UI1Z Q K
	;
VERSCHIL(BR,BJR,Q,UI1)	; Verschil uitrekenen tussen reeds verdeeld en te verdelen
	; Input:	BR:		Grootboekrekening
	; 			BJR:	Boekjaar
	; 			Q:		Firma
	; 			UI1:	UI1 van het record
	N BS,TOT,BSUI1,VERS,REK
	S $ZT="TRAP^cAN000"
	;
	S BS=$$BSAL^cAFE1(Q,BJR,"AR",BR)  
	S REK=$P($$REK^cTA180("")," ")
	S I=BR,TOT=0 F  S I=$O(^INDEX(Q,"CUM.AR.ARA",101,I)) Q:$P(I," ")'=$P(BR," ")  D
	. S BSUI1=^(I)
	. I $P(^DBH(Q,"CUM.AR.ARA",BSUI1,0),D,4)'=(BJR_".00") Q
	. I BSUI1=$G(UI1) Q                 ; record zelf niet meetellen
	. I $P(BSUI1," ",3)=REK Q           ; analytisch niet geventileer niet meetellen
	. S TOT=TOT+$P(^(0),D,10)
	S VERS=BS-TOT
VERSCHILZ Q VERS
	;
ONEVEN(BJR)	; MTEMP opbouwen met alle onevenwichten
	; Input:	BJR:	Boekjaar
	; 
	; Output:	^TEMP(boot,$J,"ONEVEN",BR,0)
	; 		 1. Grootboekrekening + omschrijving
	; 		 2. Beginsaldo grootboekrekening
	; 		 3. Verdeeld over A-code / IAS-code
	; 		 4. Verschil tussen 2 en 3
	N BR,TOT,I,BSUI1,VERS,REK,NANAL,REKANAL
	S $ZT="TRAP^cAN000"
	K ^TEMP(boot,$J,"ONEVEN")
	S REK=$$REK^cTA180("")
	S BR=0,D="\" F  S BR=$O(@("^"_Q_"AR(BR)")) Q:'$L(BR)  D 
	. I $P(^(BR,0),D,13)=1 Q  	; Tekstrekening
	. I $P(^(0),D,30) Q        ; Verwijderd of buiten gebruik
	. S REKANAL=$P(^(0),D,6)
	. S (BS,TOT,NANAL)=0
	. S BS=$$BSAL^cAFE1(Q,BJR,"AR",BR)  
	. ;S I=BR F  S I=$O(^INDEX(Q,"CUM.AR.ARA",101,I)) Q:$P(I," ")'=$P(BR," ")  D
	. ;. S BSUI1=^(I)
	. ;. I $P(^DBH(Q,"CUM.AR.ARA",BSUI1,0),D,4)'=(BJR_".00") Q
	. ;. I $P(BSUI1," ",3)=REK S NANAL=NANAL+$P(^(0),D,10) Q
	. ;. S TOT=TOT+$P(^(0),D,10)
	. S I=BJR_"00 "_BR F  S I=$O(^DBH(Q,"CUM.AR.ARA",I)) Q:$P(I," ",1,2)'=($P((BJR_"00 "_BR)," ",1,2))  D
	.. S INH=^(I,0)
	.. I $P(INH,D,30) Q
	.. I $P(INH,D,2)=REK S NANAL=NANAL+$P(INH,D,10) Q
	.. S TOT=TOT+$P(INH,D,10) 
	. S VERS=(BS-TOT) I 'VERS Q
	. I ('$L(REKANAL))!($E(REKANAL)="0") I +BS=(+TOT+NANAL) Q
	. S ^TEMP(boot,$J,"ONEVEN",BR,0)=BR_$$SIG^cAFA1("AR",BR,102)_D_BS_D_TOT_D_NANAL
ONEVENZ Q
	;
OPDUMMY(BR,BJR,Q)
	N BEDR
	S $ZT="TRAP^cAN000"
	;
	; Onthouden last reference
	D S1^cAFA1
	;
	S BEDR=$$VERSCHIL(BR,BJR,Q) 
	;
	;
	; Locken
OPDUMMYL	; L +@("^"_Q_"AR(AR)"):2 E  S R=14 D F2 G OPDUMMYL
	;
	S BP=0
	S RARA=$$REK^cTA180(""),RIAS=$$REK^cTA180("",1)
	S UI1=BJR_"00 "_BR_RARA_RIAS_0
	S INH=$$SIGN^cAFA1("BS.AR.ARA",UI1,0)
	I +BEDR=+$P(INH,D,10) G OPDUMMYY
	I $L(INH) G OPDUMMYV
	;
OPDUMMYO	; Openen
	I +BEDR=0 G OPDUMMYY
	S TAB(1)=BR_D_RARA_D_RIAS_D_BJR_".00"_D_BP_D_D_D_D_D_BEDR
	D P^cAN220("BS.AR.ARA","",UI1,"TAB","") G OPDUMMYY
	;
OPDUMMYV ; Verwijderen
	I +BEDR'=0 G OPDUMMYW
	D X^cAN220("BS.AR.ARA","",UI1) G OPDUMMYY
	;
OPDUMMYW	; Wijzigen
	S TAB(110)=BEDR
	D B^cAN220("BS.AR.ARA","",UI1,"TAB") 
	;
	;
OPDUMMYY	; Unlocken
	;L -@("^"_Q_"AR(AR)")
	;
	; Terugzetten last reference
	D S2^cAFA1
	;
OPDUMMYZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
F1	S R=250
F2	D TXT^cAFA1(R)
FZ	K R Q
	;
ZZ	; 15.12.05 - 12 u 16 * V8.05