cTI50	;Exporteren intrastat ;%TI50 ; [ 01/07/02  10:04 AM ]
	G 1
	;
T0	;Exporteren Intrastat ;
T1	;Aankoop;Verkoop;
T2	;Maand\"jjjj.mm[] = bepaalde maand";
T3	;Bevestiging\"[] = ok   ,[] = hernemen";
T4	;Transactie;Regio;
T5	; ontbreekt bij document ;
T6	;aankomst;vertrek;
	;
T0F	;Exportation Intrastat ;
T1F	;Achats;Ventes;
T2F	;Mois\"aaaa.mm[] = mois spécifique";
T3F	;Confirmation\"[] = ok   ,[] = reprendre";
T4F	;Transaction;Région;
T5F	; manque au document ;
T6F	;aankomst;vertrek;
	;
T0E	;Exporteren Intrastat ;
T1E	;Aankoop;Verkoop;
T2E	;Maand\"jjjj.mm[] = bepaalde maand";
T3E	;Bevestiging\"[] = ok   ,[] = hernemen";
T4E	;Transactie;Regio;
T5E	; ontbreekt bij document ;
T6E	;aankomst;vertrek;
	;
	; Exporteren 1 lijn
	; U5=hoofding ; B(1)=detaillijn
S1	I $$NL^cTI100 G S2
	I $$FR^cTI100 G S3
	K RT S C=$P(PAR,D,US-5) I 'C S C=1                ; coëfficiënt
S1A	S RT(1)=$$SIG^cAFA1("INTR.GOE",$P(B(1),D),103)    ; officiële goed.code
S1B	S RT(2)=$P(B(1),D,12)                             ; transactie
	I 'RT(2) S RT(2)=$P(U5,D,4)
	I 'RT(2) S RT(2)=$P(PAR,D,US-3)
	I 'RT(2) S K=$P($T(@("T4"_QT)),U,2)_$P($T(@("T5"_QT)),U,2)_UR D F1
	I 'RT(2) S RT(2)=""
S1C	S RT(3)=US0                                       ; stat.stelsel
S1D	S RT(4)=$P(@("^"_Q_"INTR(""%F"",2,$P(U5,D)_"" "")"),D,2)    ; ISO-land
S1E	S K=$P(B(1),D,4) D S9 S RT(5)=K                   ; gewicht
S1F	S K=$P(B(1),D,5) D S9 S RT(6)=K                   ; aanv.eenheden
S1G	S RT(7)=$$BTW^cAFO1($$SG^cAFA1($S(US=19:"LE",1:"KL"),NR,116)) ; BTWnr
S1H	S RT(8)=$P(U5,D,2)                                ; vervoerswijze
S1I	S K=$P(B(1),D,7) D S9 S RT(9)=K                   ; factuurwaarde BF
S1J	S K=$P(B(1),D,6) D S9 S RT(10)=K                  ; factuurwaarde VM
S1K	S RT(11)=$P($G(@("^"_Q_"BA(11,VM)"),VM),D)        ; off.muntcode
S1L	I BP>2002 D
	. S RT(12)=$P(B(1),D,13)                          ; regio
	. I 'RT(12) S RT(12)=$P(U5,D,10)
	. I 'RT(12) S RT(12)=$P(PAR,D,US-2)
	. I 'RT(12) S K=$P($T(@("T4"_QT)),U,3)_$P($T(@("T5"_QT)),U,2)_UR D F1
	. I 'RT(12) S RT(12)=""
	. S RT(13)=$P(U5,D,11)                            ; inco
	. I RT(13)="" S RT(13)=$P(PAR,D,US-1)
	. I $P(PAR,D,US-1)="N" K RT(13)
S1Y	S RT=$O(RT(""),-1)
S1Z	D ^cA700 Q
	;
	;  Exporteren 1 lijn Nederlandse firma
	;  Opgelet in Nederland moet 'Transactie creditnota's' op 1 gezet worden
	;  U5=hoofding ; B(1)=detaillijn
S2	K RT,RL
	; Indien creditnota's: omdraaien van teken
	I (FC="-1") F I=4,5,6,7 I $L($P(B(1),D,I)) S $P(B(1),D,I)=$P(B(1),D,I)*-1
S2A	S RT(1)=KC,RL(1)=6  			     ; boekingsperiode
S2B	S RT(2)=$E($P(PAR,D,6),1,12),RL(2)=12	     ; BTW-nummer
	I RT(2)="" S RT(2)=$E($P(@("^"_Q_"BTW(0,0)"),D,6),1,12)
S2C	S RT(3)=$S(US=19:6,1:7),RL(3)=1                   ; goederenstroom
S2D	S RT(4)=$J($E($P(U5,D,12),1,2),2),RL(4)=2         ; statistisch stelsel
S2E	S RT(5)=$E($P(@("^"_Q_"INTR(""%F"",2,$P(U5,D)_"" "")"),D,2),1,2),RL(5)=2  ; ISO-land
S2F	S RT(6)=$E($P(B(1),D,12),1),RL(6)=1               ; transactie
	I 'RT(6) S RT(6)=$E($P(U5,D,4),1)
	I 'RT(6) S RT(6)=$E($P(PAR,D,US-3),1)
	I 'RT(6) S K=$P($T(@("T4"_QT)),U,2)_$P($T(@("T5"_QT)),U,2)_UR D F1
	I 'RT(6) S RT(6)=""
S2G	S RT(7)=$J($E($$SIG^cAFA1("INTR.GOE",$P(B(1),D),103),1,8),8),RL(7)=8  ; officiële goed.code
S2H	S RT(8)=$E($P(U5,D,2),1),RL(8)=1                  ; vervoerswijze
S2I	S K=$P(B(1),D,4)				     ; gewicht
	I K>0&(K<1) S K=1
	I K<0&(K>-1) S K=-1
	I $L(K) S K=$J(K,"",0)
	S RT(9)=$J($E(K,1,10),10),RL(9)=10
S2J	S RT(10)=$J($E($P(B(1),D,5),1,10),10),RL(10)=10   ; Aanvullende eenheden
S2K	S K=$P(B(1),D,6)				     ; Factuurwaarde EUR
	I K>0&(K<1) S K=1
	I K<0&(K>-1) S K=-1
	I $L(K) S K=$J(K,"",0)
	S RT(11)=$J($E(K,1,10),10),RL(11)=10
S2L	S RT(12)=$E($$SG^cAFA1($S(US=19:"LE",1:"KL"),NR,116),1,16),RL(12)=16 ; BTW-nr. KL of LE
	; Factuurnummer
	S RT(13)=UR,RL(13)=6
S2Y	S RT=$O(RT(""),-1)
S2Z	D ^cA700 Q
	;
	; Exporteren 1 lijn Franse firma
	; U5=hoofding ; B(1)=detaillijn
S3	K RT,TR S C=$P(PAR,D,US-5) I 'C S C=1                ; coëfficiënt
S3A	S RT(1)=$$SIG^cAFA1("INTR.GOE",$P(B(1),D),103)    ; officiële goed.code
S3B	S TR=$P(B(1),D,12)                             ; transactie
	I 'TR S TR=$P(U5,D,4)
	I 'TR S TR=$P(PAR,D,US-3)
	I 'TR S K=$P($T(@("T4"_QT)),U,2)_$P($T(@("T5"_QT)),U,2)_UR D F1
	I 'TR S TR=""
	S RT(2)=$E(TR,1),RT(3)=$E(TR,2)
S3C	S RT(4)=$P(U5,D,12)                                       ; stat.stelsel
S3D	S RT(5)=$P(@("^"_Q_"INTR(""%F"",2,$P(U5,D)_"" "")"),D,2)    ; ISO-land
	I $L($P(U5,D,14)) S RT(6)=$P(@("^"_Q_"INTR(""%F"",2,$P(U5,D,14)_"" "")"),D,2)  ; land van oorsprong
S3E	S K=$P(B(1),D,4) D S9 S RT(7)=K                   ; gewicht
S3F	S K=$P(B(1),D,5) D S9 S RT(8)=K                   ; aanv.eenheden
S3G	S RT(9)=$$SG^cAFA1($S(US=19:"LE",1:"KL"),NR,116)  ; BTWnr
S3H	S RT(10)=$P(U5,D,2)                                ; vervoerswijze
S3I	S K=$P(B(1),D,7) D S9 S RT(11)=K                   ; factuurwaarde BF
S3J	S K=$P(B(1),D,6) D S9 S RT(12)=K                  ; factuurwaarde VM
	S K=$P(B(1),D,9) D S9 S RT(13)=K		     ; statistische waarde EUR
S3K	S RT(14)=$P($G(@("^"_Q_"BA(11,VM)"),VM),D)        ; off.muntcode
S3L	S RT(15)=$P(U5,D,13)                              ; situation lieu
	S RT(16)=$P(B(1),D,14)			     ; leveringsvoorwaarden
	S RT(17)=UR				     ; factuurnummer
S3Y	S RT=$O(RT(""),-1)
S3Z	D ^cA700 Q
	;
S9	I K<0 S K=-K
S9Z	Q
	;
	; Initialisatie + vraagstelling
1	S US=$P(R,U,2) I US'=19,US'=29 G YZ
11	S K=$P($T(@("T0"_QT)),U,2)_$P($T(@("T1"_QT)),U,$S(US=19:2,1:3))_" "_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
13	S A=$E(DM-1/100+DJ_0,1,7) I DM<2 S A=DJ-.88
15	S R="A\22\3\"_$P($T(@("T2"_QT)),U,2)_"\7\PCTR\\\\\\1" D R0 G YZ:K="-"!(K=",")
17	S (A,BP)=$S(K:K,1:A),FP=403 W @F,@F1,$P($P($T(@("T2"_QT)),U,2),D)," : ",BP
	;
	; Bestand
2	S PAR=$G(@("^"_Q_"INTR(""%P"",""P"")"))
21	S MSDOS=""
23	S K=$P(PAR,D,32) S:K="" K="C:/INSTAT" D  S MSDOS=MSDOS_K
	. S K=$TR(K,"/","\")
	. I $E(K,$L(K))'=D S K=K_D
25	I '$$NL^cTI100 S MSDOS=$TR(MSDOS,D,U)_$E(BP,1,4)_$E(BP,6,7)_$E($P($T(@("T1"_QT)),U,$S(US=19:2,1:3)))_".txt"
26	I $$NL^cTI100 S MSDOS=$TR(MSDOS,D,U)_$P($T(@("T6"_QT)),U,$S(US=19:2,1:3))_".txt"
	S S4="IS:"_$P($T(@("T1"_QT)),U,$S(US=19:2,1:3))_" "_BP	
27	S FORM=$P(PAR,D,33) S:FORM="" FORM=" " D 11^cA701 G 15:K="-"
29	I FORM=" " S VL="",VS=",",RS=$C(13,10)
	;
	; Bevestiging
3	S FP=1803 W @F,@F1,$P($P($T(@("T2"_QT)),U,2),D)," : ",BP
31	S R="K\22\3\"_$P($T(@("T3"_QT)),U,2)_"\1\\""-,""[K" D R0 G 15:$L(K)
33	S US0=US,KC=BP*100,UR="",RO=2203,FP=RO W @F,@F1 K RL,RN,RT
35	S R=$$MNTC^cAFE1(Q,$$BJ^cAFE1(Q,BP)),BF=$P(R,D),QD=$P(R,D,2)
	;
	; Opbouw bestand
4	S UR=$O(@("^"_Q_"INTR(KC,US,UR)")),UZ=100 I UR="" S US=$S(US=19:29,1:19) G:'$$NL^cTI100 5 G 6
41	S U5=^(UR,1),FC=$P($G(@("^"_Q_$S(US=19:"AA",1:"VE")_"(BP,UR)"),$P(U5,D,7)),D)
42	I $P(U5,D,9) G 4
43	S:'$L(FC) FC="F" S FC=FC="F"*2-1
45	S NR=+$P($G(^(UR)),D,4),VM=$P($G(^(UR)),D,24) I VM="" S VM=BF
47	S UZ=$O(@("^"_Q_"INTR(KC,US,UR,UZ)")) G 4:UZ="" S B(1)=^(UZ)
48	S OK=1,K=$P(B(1),D,7) I FC=1&(K<0)!(FC=-1&(K>0)) S OK=0 ; geen neg.ln.
49	D S1:OK!($$NL^cTI100) G 47
	;
	; terugzending (ander stelsel)
5	S UR=$O(@("^"_Q_"INTR(KC,US,UR)")),UZ=100 I UR="" G 6
51	S U5=^(UR,1),FC=$P($G(@("^"_Q_$S(US=19:"AA",1:"VE")_"(BP,UR)"),$P(U5,D,7)),D)
52	I $P(U5,D,9) G 5
53	S:'$L(FC) FC="F" S FC=FC="F"*2-1
55	S NR=+$P($G(^(UR)),D,4),VM=$P($G(^(UR)),D,24) I VM="" S VM=BF
57	S UZ=$O(@("^"_Q_"INTR(KC,US,UR,UZ)")) G 5:UZ="" S B(1)=^(UZ)
58	S OK=1,K=$P(B(1),D,7) I FC=1&(K>0)!(FC=-1&(K<0)) S OK=0 ; enkel neg.ln.
59	D S1:OK G 57
	;
	; uitlezen
6	D ^cA702
	;
YZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
PCTR	;K?4N1"."2N&(K#1)&(K#1<.13)!("-,"[K)
	;
F1	S R=250
F2	D TXT^cAFA1(R)
FZ	K R Q
	;
ZZ	; 22.11.04 - 16 u 14 * V8.02