cTN001	;Algemene functies DBH ; cTN001
	;
YZ	Q
	;
CHBH(DMS,UI1)	; Nog niets geboekt op deze rekening?
	; Input: DMS
	;        UI1
	;        
	; Output: 0: Reeds op geboekt
	;         1: Nog niet op geboekt        
	N @$$INITVAR^cAFVBA01("DMS,UI1")
	S OK=1
	S MX=$S(DMS="AR.A":"M11",DMS="ARA.A":"M12",DMS="KL.A":"M16",DMS="LE.A":"M17",1:"")
	I '$L(MX) G CHBHZ
	;
	D Q1^cAFA10(DMS)
	;
	; nieuwe registratie
CHBHA	I +$$PAR^cTN001(Q,201)'=2 G CHBHB
	S IREF=$P($$REF^cAFA10(Q,"REG",MX),D,3),Q49="" I '$L(IREF) G CHBHY
CHBHA2	S Q49=$O(@IREF@(Q49)) I '$L(Q49) G CHBHY 
	I $D(@IREF@(Q49,UI1)) S OK=0 G CHBHY
	G CHBHA2
	;
	; oude registratie
CHBHB	S OUI1=$$SIG^cAFA1(DMS,UI1,150)
	I '$L(OUI1) G CHBHY  ; geen oude bestanden meer
	S DMS=$P(DMS,".A")
	; Huidige BH: geboekt?
	S i=$$SIG^cAFA1(DMS,OUI1,101) I $L($O(^(9))) S OK=0 G CHBHY
	; Indien er BH('en) worden gelijkgehouden: hierin geboekt?
	S Q49=Q(49),Q="" I '$L(Q(49)) G CHBHY
CHBHB2	S Q=$O(^DMS(Q49,DMS,"KOPIE",Q)) I '$L(Q) G CHBHY
	S i=$$SIG^cAFA1(DMS,OUI1,101) I $L($O(^(9))) S OK=0 G CHBHY
	G CHBHB2	
	;
CHBHY	D Q2^cAFA10
	;
CHBHZ	Q OK
	;
ARA(Q,AR,PAR) ; Analytische BH? Indien AR doorgegeven: actie 
	; Input: Q:  Vennootschap
	;        AR: Grootboekrekening
	;        PAR: Parameters gescheiden door "\"
	;             1. Switch output
	;                "",0: Types actie reduceren tot 0 (niet vragen\vast) of 1 (vragen): voor input
	;                1: Specifieke actie teruggeven: voor controle
	;             
	; Output: gescheiden door "\"
	;         1. Type actie
	;            0= Analytische rekening niet vragen (of geen analytische BH)
	;            1= Analytische rekening vragen, niet verplicht (of analytische BH)
	;            << indien switch output op 1 >>
	;            2= Analytische rekening vragen, verplicht
	;            3= Vaste analytische rekening
	;            4= Vaste analytische curve
	;         2. Vaste analytische rekening (of "")
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("AR,PAR")
	; 
	; Check parameters
ARA1	S R=+$$PAR(Q,501) I 'R!'$L($G(AR)) G ARAZ
	;
	; Default actie voor analytische rekening ophalen
ARA2	S R=+$$SIG^cAFA1("AR.A",AR,106)
	;
ARA3	I R'=3 G ARAY
	S $P(R,D,2)=$$SIG^cAFA1("AR.A",AR,157)
	;
	; Eventueel output aanpassen
ARAY	I '$P($G(PAR),D) D
	. I ($P(R,D)>1) S $P(R,D)=1
	. I $L($P(R,D,2)) S $P(R,D)=0
	;
ARAZ	Q R
	;
PER(Q) 	; Analytische periode vragen?
	; Input Q: Vennootschap
	; 
	; Output: 0: Niet vragen
	;         1: Vragen
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("")
	;
	; Analytische BH?
PER1	S R=$$ARA($G(Q)) I 'R G PERZ
	;
	; Analytische periode vragen?
PER2	S R=+$$PAR($G(Q),517)
	;
PERZ	Q R
	;
	; Ondersteunt firma IAS?
IAS(Q)	Q $$PAR($G(Q),508)
	;
	; omrekenen via driehoeksmethode
OMREK(Q,BE,MI,MO,AD,MIPARE,MOPARE)	
	; input: 1. Q : Q-waarde
	;        2. BE: bedrag uit cumulnode/dagboek
	;        3. MI: muntcode input
	;        4. MO: muntcode output
	;        5. AD: aantal dec.   (""=decimalen muntcode output)
	;        6. MIPARE : '1 EUR =' voor MI : indien doorgegeven wordt met dit gerekend
	;        7. MOPARE : '1 EUR =' voor MO : indien doorgegeven wordt met dit gerekend
	; output: omgerekend bedrag, afgerond op AD
	S $ZT="TRAP^cAN000"
	N BA11,BA39,R,RZR D S1^cAFE1
	S MNTF=$$SIG^cAFA1("Q",$$Q^cAFA10(),202),R=BE
	I '$L($G(MI)) S MI=MNTF
	I '$L($G(MO)) S MO=MNTF
	I MI=MO G OMREKY
	S R=BE/$$PARE(MI,$G(MIPARE))  ; MI naar EUR
	S R=R*$$PARE(MO,$G(MOPARE))   ; EUR naar MO
OMREKY	I '$L($G(AD)) S AD=$$SIG^cAFA1("CODE.9009",MO,105) I '$L(AD) S AD=2
	I AD<99 S R=$J(R,0,AD)
OMREKZ	D S2^cAFE1 Q R
	;
PARE(MNT,PARE)	; ophalen pariteit voor munt MNT
	; MNT  : UI1 munt
	; PARE : indien ingevuld wordt steeds deze genomen
	N RZR D S1^cAFE1
	I $L($G(PARE)) G PAREZ
	S PARE=$$SIG^cAFA1("CODE.9009",MNT,104)
	I '$L(PARE) S PARE=1
PAREZ	D S2^cAFE1 Q PARE
	;
PAR(UI1,BIN)	; parameters firma
	N UQC,USC,R
	S $ZT="TRAP^cAN000"
	S R=""
	D DMS^cAN000("UQC","USC","Q",1) I '$L(UQC)!'$L(USC) G PARZ  ; geen licentie
	S R=$$SIG^cAFA1("Q",UI1,BIN)
PARZ	Q R
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09