cTN009	;Controle BH ;cTN009 ; [ 12/10/01  5:49 PM ]
	;
T0	;Job controle boekhouding ;
T1	;Begin: ;Einde: ;Duur: ;Opgelet: er zijn fouten.;
T2	;opgelet fouten gevonden;geen fouten gevonden;
	;
T0F	;Job contrôle comptabilité ;
T1F	;
T2F	;opgelet fouten gevonden;geen fouten gevonden;
	;
T0E	;Job controle boekhouding ;
T1E	;
T2E	;opgelet fouten gevonden;geen fouten gevonden;
	;
YZ	Q
	;
CNTRL(VBM,TBM,RES) ; Controle boekhouding
	; Input: VBM: Van maand (verplicht)
	;        TBM: Tot maand (optioneel)
	;             Indien niet doorgegeven: jongste boekingsmaand
	;        RES: "" of 0: mail
	;             1: scherm
	S $ZT="TRAP^cAN000"
	N @$$INIT^cTN009("VBM,TBM,RES")
	;
	; Controle parameters
CNTRL1	F i="VBM","TBM","RES" S @i=$G(@i) 
	I '$L(VBM) S VBM=$$SIG^cAFA1("Q",Q,210) S:'$L(VBM) VBM=$$DEFBM^cTN9301(Q)
	I '$L(VBM) G CNTRLZ
	I '$$SIG^cAFA1("Q",Q,201) G CNTRLZ ; Enkel oude bestandsstructuur
	D ERR(0)
	;
	; Start
CNTRL2	S STH=$H
	;
	; Controles uitvoeren
CNTRL3	D DOC^cTN0090(VBM,TBM) ; Documenten
	D REG^cTN0091(VBM,TBM) ; Registraties
	D DIV^cTN0092(VBM,TBM) ; Divers
	D VGL^cTN0093(VBM,TBM) ; Vergelijk oud <-> nieuw
	;
	; Overzicht
CNTRL4	S ETH=$H
	W !,!,$P($T(@("T1")),U,2),?10,$$HD^cAFD1(STH)," - ",$$HT^cAFD1(STH,1)
	W !,$P($T(@("T1")),U,3),?10,$$HD^cAFD1(ETH)," - ",$$HT^cAFD1(ETH,1)
	S VERS=$P(ETH,",",2)-$P(STH,",",2)
	S MIN=(VERS\60),MIN=$E("0"_MIN,$L(MIN),$L(MIN)+1)
	S SEC=(VERS#60),SEC=$E("0"_SEC,$L(SEC),$L(SEC)+1)
	W !,$P($T(@("T1")),U,4),?10,MIN,":",SEC,!
	S ERR=0 I '$$ERR("00") W !,$P($T(@("T1")),U,5),! S ERR=1
	;
	; KD - 03.05.07 - alert sturen
CNTRL5	I RES G CNTRL6
	S TXT(1)=$P($T(@("T1")),U,2)_" "_$$HD^cAFD1(STH)_" - "_$$HT^cAFD1(STH,1)
	S TXT(2)=$P($T(@("T1")),U,3)_" "_$$HD^cAFD1(ETH)_" - "_$$HT^cAFD1(ETH,1)
	S TXT(3)=$P($T(@("T1")),U,4)_" "_MIN_":"_SEC	
	S VAR("B1")=$P($T(@("T2")),U,3)
	; Fout gevonden; TXT wijzigen
	I ERR S VAR("B1")=$P($T(@("T2")),U,2)
	; Alert versturen
	D ^cANEM1("D1024",$T(+0),$P($T(@("T0"_QT)),U,2),.TXT,.VAR,"")
	G CNTRLZ
	;
	; Scherm
CNTRL6	I 'ERR G CNTRLZ
	D ERR("99")
	;
CNTRLZ	Q
	;
DEF()	; Ophalen BH-definities
	N REF,DMS,PDMS,R
	S $ZT="TRAP^cAN000"
	;
	S R="" F DMS="DB","REG","JRN","AR.A","ARA.A" D
	. S PDMS=$P(DMS,".")
	. S R=$S($L(R):R_",",1:"")_"UREF"_PDMS_","_"IREF"_PDMS
	. I $L($G(@("UREF"_PDMS))),$L($G(@("IREF"_PDMS))) Q
	. S REF=$$REF^cAFA10(.Q,DMS),@("UREF"_PDMS)=$P(REF,D),@("IREF"_PDMS)=$P(REF,D,3)
	;
DEFZ	Q R
	;
ERR(TYPE,PUI1,PUI2,PUI3,ERR)	
	S $ZT="TRAP^cAN000"
	N @$$INIT^cTN009("TYPE,PUI1,PUI2,PUI3,ERR")
	;
	; Controle parameters
ERR1	F i="TYPE","PUI1","PUI2","PUI3","ERR" S @i=$G(@i) 
	;
	; Definitie
ERR2	S ERRGL="^DBH(""EA"",""CNTRL"","""_$$Q^cAFA10()_""")",R=1
	;
	I TYPE="0" G ERR3    ; Logging (start)
	I TYPE="00" G ERR35  ; Logging (einde)
	I TYPE="1A" G ERR4   ; Dagboeken
	I TYPE="1B" G ERR45  ; Registraties
	I TYPE="3" G ERR5    ; Rekeningen 
	I TYPE="4" G ERR9    ; Beginsaldi
	I TYPE="5" G ERR10   ; Beginsaldi
	I TYPE="10" G ERR6   ; Vgl documenten oud<->nieuw
	I TYPE="11" G ERR7   ; Vgl cumuls oud<->nieuw
	I TYPE="12" G ERR8   ; Vgl openstaande posten oud<->nieuw
	I TYPE="99" G ERRX  ; Output
	G ERRZ
	; 
	; *****************************************************************
	; 
	; Layout controle global
	; ^DBH("EA","CNTRL",Q
	; 
	; 0:  Logginggegevens
	;     1. Firma-omschrijving
	;     2. Initialen uitvoerder laatste controle
	;     3. Startdatum laatste controle
	;     4. Starttijd laatste controle
	;     5. Einddatum laatste controle
	;     6. Eindtijd laatste controle
	;     7. Controle status (0= NOK, 1= OK)
	;
	; 1:  Fouten ivm dagboeken en registraties
	;     DB,x: foutboodschap
	;     DB,REG,x: foutboodschap
	; 
	; 2:  Omzet
	;     TYPE (KL.A of LE.A)
	;     TYPE,UI1 (UI1 Type)
	;     TYPE,UI1,JR (Kalenderjaar): saldo omzet
	;    
	; 3:  Cumuls
	;     TYPE (AR.A,ARA.A,KL.A,...
	;     TYPE,UI1 (UI1 Type)
	;     TYPE,UI1,MT (Maand)
	;     TYPE,UI1,MT,0: saldo cumuls in munt BH
	;                ,1: saldo cumuls in munt rekening (enkel bij AR.A)
	;               
	; 4:  Beginsaldi
	;     TYPE (AR.A,KL.A,LE.A)
	;     TYPE, JR (Boekjaar): foutboodschap
	;    
	; 5:  Samengestelde cumuls
	;     UI1 (AR.A)
	;     UI1,MT (Maand\Jaar): 
	; 
	;  ****************************************************************   
	;  * Enkel indien beide bestandsstructuren worden gelijkgehouden. *
	;  * Beide bestanden worden met elkaar vergeleken.                *
	;  ****************************************************************
	;  
	; 10: Documenten 
	;     TYPE ("O->N","N->O")
	;     TYPE,x: Foutboodschap
	; 
	; 11: Cumuls en beginsaldi
	;     TYPE (AR.A,KL.A,LE.A)
	;     TYPE,UI1 (UI1 Type)
	;     TYPE,UI1,JR (Boekjaar): foutboodschap ivm beginsaldo
	;             ,MT (Maand)   : foutboodschap ivm maandcumuls
	; 
	; 12: Openstaande documenten
	;     TYPE ("O->N","N->O")
	;     TYPE,x: Foutboodschap
	;     
	; 13: Gecombineerde cumul
	;     TYPE (CUM of BEG)
	;     TYPE,MT (Maand of jaar)
    	;     TYPE,MT,AR (Grootboekrekening)
    	;     TYPE,MT,AR,ARA (Analytische rekening)
    	;     TYPE,MT,AR,ARA,IAS (IAS-rekening)        : Beginsaldo     
    	;     TYPE,MT,AR,ARA,IAS,BPE (Leveringsmaand)  : Cumul
	;
	; *****************************************************************
	;
	; 0: Logging	
ERR3	K @ERRGL
	; Start
	S @ERRGL@(0)=$$SIG^cAFA1("Q",Q,102)_D_$G(QU)_D_$$HD^cAFD1($H)_D_$$HT^cAFD1($H,1)
	G ERR39
	; Einde
ERR35	S $P(@ERRGL@(0),D,5)=$$HD^cAFD1($H)
 	S $P(@ERRGL@(0),D,6)=$$HT^cAFD1($H,1)
 	S R=1 I $L($O(@ERRGL@(0))) S R=0
 	S $P(@ERRGL@(0),D,7)=R
ERR39	G ERRY
	; 
	; I: Dagboeken/Registraties
ERR4	S I3="",I3=$O(@ERRGL@(1,PUI1,I3),-1)+1
	S @ERRGL@(1,PUI1,I3)=ERR
	G ERRY
ERR45	I '$L(PUI1) S UI1=PUI2,PUI1=$P(@UREFREG@(0),D,3)
	S I4="",I4=$O(@ERRGL@(1,PUI1,PUI2,I4),-1)+1
	S @ERRGL@(1,PUI1,PUI2,I4)=ERR
ERR49	G ERRY
	;
	; III: Rekeningen (cumuls, openstaand, ...)
ERR5	S I3=999,I3=$O(@ERRGL@(3,PUI1,PUI2,I3),-1)+1
	S @ERRGL@(3,PUI1,PUI2,I3)=ERR
ERR59	G ERRY
	;
	; X: Vgl documenten oud<->nieuw
ERR6	S I3="",I3=$O(@ERRGL@(10,PUI1,I3),-1)+1
	S @ERRGL@(10,PUI1,I3)=ERR
ERR69	G ERRY
	;
	; XI: Vgl cumuls oud<->nieuw
ERR7	S @ERRGL@(11,PUI1,PUI2,PUI3)=ERR
ERR79	G ERRY
	;
	; XII: Vgl openstaande posten oud<->nieuw
ERR8	S I3="",I3=$O(@ERRGL@(12,PUI1,I3),-1)+1
	S @ERRGL@(12,PUI1,I3)=ERR
ERR89	G ERRY
	;
	; IV: Beginsaldi
ERR9	S @ERRGL@(4,PUI1,PUI2)=ERR
ERR99	G ERRY
	;
	; V: Gecombineerde cumuls
ERR10	S I3=999,I3=$O(@ERRGL@(5,PUI1,PUI2,I3),-1)+1
	S @ERRGL@(5,PUI1,PUI2,I3)=ERR
ERR109	G ERRY
	;
	; Output
ERRX	ZW @ERRGL G ERRY
	;
ERRY	
ERRZ	Q R
	;
INIT(R)	; Initialisatie + samenstellen string met var. voor een EXCLUSIEVE New 
	; R        = welke variabelen moeten bijgezet worden in de uitgangstring
	;             vb : R ="A,B" : Uitgang  = "(%Q1,D,DD,...,A,B)"
	; 
	N DEF
	I '$G(%dmINIT) D INIT^cAFVBA01
	S DEF=$$DEF()
	; samenstellen string met standaard variabelen + variabelen meegegeven in R
	S R="(%dmINIT,%Q1,D,DD,DJ,DM,DT,Q,QD,QL,QM,QN,QP,QS,QT,QTU,QU,QZ,TD,U,boot,bootrvg,client,cs,master,slave,workst"_$S($L($G(DEF)):","_DEF,1:"")_$S($L($G(R)):","_R,1:"")_")"
INITZ	Q R
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09