cTN1109	; Aankoop : Dagboek : Conversie nieuw naar oud ;cTN1109;   [ 18/11/09  15:44:36 ]
	;
T1	;Transactie (;) niet volledig afgewerkt.;
T2	;Geen gegevens voor doorgegeven sleutel ;.;
T3	;Sleutel ; is niet van aankoopdagboek.;
T4	;Factuur ; is reeds geboekt in ;.;
	;
T1F	;Transaction (;) incomplète.;
T2F	;Pas de données pour la clé informée ;.;
T3F	;Clé ; n’appartient pas au journal d’achat.;
T4F	;Facture ; déjà enregistrée en ;.;
	;
T1E	;The transaction (;) is not completed.;
T2E	;No data for the transmitted key ;.;
T3E	;The key ; is not from the purchases book.;
T4E	;The invoice ; is already booked ;.;
	;
YZ	Q
	;
AA(Q,DBUI1,GECOLEVA)	; Aankoopdagboek ("^"_Q_"AA") opzetten
	; Q = Q-waarde
	; DBUI1 = UI1 uit ^DBH("EA","DB"
	;
	S $ZT="TRAP^cAN000"
	N (DBUI1,GECOLEVA,%Q1,D,DD,DJ,DM,DT,F,F0,F1,F11,F12,F2,F3,F4,F5,F55,F56,F57,F58,F6,F60,F61,F62,F7,F70,F71,F8,F9,F90,F91,F92,F93,F94,F95,FDL,FG,FIN,FS,Q,QD,QL,QM,QN,QP,QS,QT,QTU,QU,QZ,TD,U,boot,bootrvg,client,crossover,cs,i,io,master,slave,workst)
AAA	S B(1)=$$SIGN^cAFA1("DB",DBUI1,0) F I=3,4 S B(I-1)=$G(^(I))
	I '$L(B(1)) S OK="0\"_$P($T(@("T2"_QT)),U,2)_U1IDB_$P($T(@("T2"_QT)),U,3) G AAZ
	I $P(B(1),D)'="A" S OK="0\"_$P($T(@("T3"_QT)),U,2)_U1IDB_$P($T(@("T3"_QT)),U,3) G AAZ  ; geen aankoop
	S Q=$P(B(1),D,49),Q(49)=Q
	I $$SIG^cAFA1("Q",Q,201)=2 S OK=1 G AAZ
	S REFREG=$$REF^cAFA10(.Q,"REG","M1")
	S IREFREG=$P(REFREG,D,3),UREFREG=$P(REFREG,D) I '$L(IREFREG)!'$L(UREFREG) X "STOP"
AAB	; algemeen
	S QD=@("^"_Q_"BA(34)")
	S BF=$P(^(39),D)                                ; muntcode
	S SWAN=+$P($G(@("^"_Q_"BA(300)"),0),D)
	S BP=$P(B(1),D,5)                               ; Boekingsmaand
	S BPE=$P(B(1),D,6),BPEC="BPEC^"_$T(+0)          ; Boekingsperiode
	S JRN=$$SIG^cAFA1("JRN",$P(B(1),D,2),103)       ; journaalnummer
	I JRN=0 S JRN=""
	S SWX=U_'$P(B(2),D,33)                          ; vermelden op betalingsvoorstel
	S BJ=$P(B(1),D,4)                               ; boekjaar
	S FNR=$P(B(1),D,3)                              ; factuurnummer
	S i="" F  s i=$o(@("^"_Q_"AA(i)"),-1) Q:i=""  I $D(^(i,FNR)) Q
	I $L(i) S OK="0\"_$P($T(@("T4"_QT)),U,2)_FNR_$P($T(@("T4"_QT)),U,3)_i_$P($T(@("T4"_QT)),U,4) G AAZ
	S FC=$P(B(1),D,23)                              ; factuurcode (F/C)
	S FDT=$P(B(1),D,7)                              ; factuurdatum
	S VVD=$P(B(1),D,8)                              ; vervaldatum
	S KC=$$SIG^cAFA1("LE.A",$P(B(1),D,10),101)      ; nr leverancier
	S KN=$P(^(0),D,2)                               ; naam leverancier
	S I1=$P(^(0),D,50)                              ; index leverancier
	S VM=$P(B(1),D,14)                              ; muntcode
	S MPAR=1/$P(B(1),D,27)                          ; pariteit
	S COM=$P(B(1),D,24)                             ; factuurnummer leverancier
	S OM1=$P(B(1),D,12) ;$P(B(1),D,13)              ; omschrijving (= nieuwe referte, indien leeg = nieuwe omschrijving)
	I '$L(OM1) S OM1=$P(B(1),D,13)
	S SRT=JRN                                       ; journaalnummer
	S OGM=$S('$P(B(2),D,34):"",1:$P(B(2),D,32))     ; gestructureerde mededeling
	S MEDED=$S($P(B(2),D,34):"",1:$P(B(2),D,32))    ; mededeling (niet gestructureerd)
	S DVO=$P(B(2),D,31)                             ; datum ontvangst
	S SWINV=$P(B(2),D,36)                           ; IC-investering: 0=Goed, 1=Dienst, ""=n.v.t.
AAC	; bedragen in VM
	S TTB=$$B(FC,$P(B(1),D,19))                     ; totaal bedrag
	S KKB=$$B(FC,$S($L($P(B(1),D,20)):-$P(B(1),D,20),1:""))                     ; bedrag korting contant
	S NETG=$$B(FC,$P(B(3),D))                       ; netto bedrag goederen
	S NETD=$$B(FC,$P(B(3),D,2))                     ; netto bedrag diensten
	S NETI=$$B(FC,$P(B(3),D,3))                     ; netto investeringen
	S NETA=$$B(FC,$P(B(3),D,4))                     ; netto andere
	S MST=$$B(FC,$P(B(3),D,5))                      ; maatstaf van heffing
	S MSTG=$$B(FC,$P(B(3),D,6))                     ; maatstaf goederen
	S MSTD=$$B(FC,$P(B(3),D,7))                     ; maatstaf diensten
	S MSTI=$$B(FC,$P(B(3),D,8))                     ; maatstaf investeringen
	S MSTA=$$B(FC,$P(B(3),D,9))                     ; maatstaf andere
	S AFBTW=$$B(FC,$P(B(3),D,10))                   ; aftrekbare BTW
	S NABTW=$$B(FC,$P(B(3),D,11))                   ; niet-aftrekbare BTW
	S BTWTYPE=$$SIG^cAFA1("CODE.9032",$P(B(2),D,12),104)
	S BTWOH=$$B(FC,$S(BTWTYPE=1000:-$P(B(3),D,13),1:""))    ; BTW onroerende heffing
	S BTWIC=$$B(FC,$S(BTWTYPE=1001:-$P(B(3),D,13),1:""))    ; intracommunotaire BTW
	S BTWMC=$$B(FC,$S(BTWTYPE=1002:-$P(B(3),D,13),1:""))    ; BTW medecontractant
	S BTWVL=$$B(FC,$S(BTWTYPE=1003:-$P(B(3),D,13),1:""))    ; BTW verlegging
	; S LREF=$P(B(1),D,24)                            ; factuurnr. lev.
	; I '$L(LREF) G AAC1
	; S QAK=$$QAK^cTN1114($$Q^cAFA10)      
	; S KCAK=KC,VM($P(B(1),D,14))=$P(B(1),D,14),VM(BF)=BF
	; D S2^cT643                                      ; Link met QAK_"TOL"
AAC1	S SWTOL=""
AAD	; ventilaties
	K ^HULP(boot,$J,0) S AFS=""
	S VENTNR=0,UI1="",DBUI1I1=$P($$DI^cAN000(DBUI1,"")," ")
AAE	S UI1=$O(@IREFREG@(Q,"A",DBUI1I1,UI1)) G AAY:UI1=""
	S B(1)=@UREFREG@(0),B(2)=^(1)
	G AAE:$P(B(1),D,30)           ; ventilatie op niveau 2 : verwijderd
	G AAE:'$P(B(1),D,32)          ; geen manuele boeking
	S B="" I '$L(AFS) S AFS=$P(B(1),D,25) ; Afschrijving (zit in nieuwe BH op lijn-niveau)
	S $P(B,"#")=$P(B(2),D,2)_" "        ; nummer AR
	S $P(B,"#",2)=$P(B(1),D,10)         ; EC1-rekening (intern nummer project)
	S $P(B,"#",3)=""
	; S $P(B,"#",4)=$P(B(1),D,FC="C"+17)  ; bedrag
	I $P(B(1),D,17) S $P(B,"#",4)=$P(B(1),D,17) S:FC="C" $P(B,"#",4)=-$P(B,"#",4)  ; bedrag debet
	I $P(B(1),D,18) S $P(B,"#",4)=$P(B(1),D,18) S:FC="F" $P(B,"#",4)=-$P(B,"#",4)  ; bedrag credit
	S $P(B,"#",5)=""
	S $P(B,"#",6)=""
	S $P(B,"#",7)=1                     ; historiek switch
	I $L($P(B(1),D,19)) S $P(B,"#",8)=$P(B(1),D,19)        ; omschrijving
	I $L($P(B(2),D,3)) S $P(B,"#",9)=$P(B(2),D,3)_" "      ; analytische rek
	S:$L($P(B(1),D,11)) $P(B,"#",14)=$P(B(1),D,11)         ; EC2-code
	S:$L($P(B(1),D,12)) $P(B,"#",15)=$P(B(1),D,12)         ; EC3-code
	I $L($P(B(2),D,9)) D
	. S $P(B,"#",10)=$P(B(2),D,9)_" "  ; IAS-a-code 
	. S $P(B,"#",11)=$P(B(1),D,51)      ; UI1 IAS interne CGU
	. S $P(B,"#",12)=$P(B(1),D,52)      ; UI1 IAS externe CGU
	. S $P(B,"#",13)=$P(B(1),D,53)      ; UI1 IAS segment
	S VENTNR=VENTNR+1
	S ^HULP(boot,$J,0,VENTNR)=B
	G AAE
	;
AAY	S SWN2O=1  ; switch nieuw naar oud
	S R="TRANSACT" D ^cA348              ; begin transactie
	S ^(TRANSACT,0)=$T(+0)_D_Q_D_"A"_D_JRN_D_FNR_D_BJ_D_$G(BP)_D_$G(BPE)_D_$G(FDT)_D_$G(VVD)_D_$G(I1)_D
	D ^cT645 K SWN2O
	I $L(AFS),$D(@("^"_Q_"AA(BP,FNR)")) S $P(@("^"_Q_"AA(BP,FNR)"),D,35)=AFS ; Afschrijving
	S OK=1 I $D(^HULPE(TRANSACT)) S OK="0\"_$P($T(@("T1"_QT)),U,2)_TRANSACT_$P($T(@("T1"_QT)),U,3)
	I OK D S1^cT6413 ; Registratie factuurnummer leverancier
	;
	D LINK(Q,DBUI1)
	;
AAZ	K ^HULP(boot,$J,0) Q OK
	;
LINK(Q,DBUI1,SW)
	; Input: Q:     Vennootschap
	;        DBUI1: Intern nummer document
	;        SW:    Output-switch
	;               0,"": Geen output
	;               1: Ouput op het scherm
	N oQ,REF,UREF,IREF,DB,FNR,oFNR,AVREF,D2,TVENT,VENTS
	N PC,VENT,K,DC,BEDR,I1,UI1,REG,TYPE,FC
	S $ZT="TRAP^cAN000"
	;
	; Controle parameters
LINK1	I '$L($G(Q))!'$L($G(DBUI1)) G LINKZ
	I ($P(DBUI1," ")'="A"),($P(DBUI1," ")'="V") G LINKZ ; Enkel aankoop/verkoop
	S TYPE=$S($P(DBUI1," ")="A":"AA",1:"VE")
	;
	; Q(49) bepalen
LINK2	D Q1^cAFA10("REG")
	;
	; Variabelen opzetten
LINK3	S REF=$$REF^cAFA10(.Q,"REG"),IREF=$P(REF,D,3),UREF=$P(REF,D)
	I '$L(IREF)!'$L(UREF) G LINKZ
	S DB=$$SIGN^cAFA1("DB",DBUI1,0) I '$L(DB) G LINKZ
	S (FNR,oFNR)=$P(DB,D,3),BP=$P(DB,D,5) I '$L(FNR)!'$L(BP) G LINKZ
	S AVREF="^"_Q_TYPE_"(BP,FNR)",D2="#" I '$D(@AVREF) G LINKZ
	S FC=$P(@AVREF,D)
	;
	; Tabel op met ventilaties (AA\VE)
LINK4	K TVENT
LINK41	S FNR=$O(@AVREF) I $P(FNR,".")'=oFNR G LINK5
	S VENTS=^(FNR),PC=0
LINK42	S PC=PC+1 S VENT=$P(VENTS,D,PC) I '$L(VENT) G LINK41
	I +$P(VENT,D2,4)=0 G LINK42 ; 0-boekingen worden niet opgezet in de nieuwe BH
	S K=""
	S $P(K,D2)=$P(VENT,D2)     ; Grootboekrekening
	S $P(K,D2,2)=$P(VENT,D2,2) ; Project
	S $P(K,D2,3)=$P(VENT,D2,8) ; Omschrijving
	S $P(K,D2,4)=$P(VENT,D2,9) ; Analytische rekening
	S BEDR=+$TR($P(VENT,D2,4),"-")
	S DC="D" I (TYPE="AA"&(FC="C"))!(TYPE="VE"&(FC="F")) S DC="C"
	I $P(VENT,D2,4)<0 S DC=$S(DC="C":"D",1:"C")
	S $P(K,D2,5)=DC_BEDR       ; Bedrag
	S TVENT(K)=$P(FNR,".",2)_D2_PC
LINK49	G LINK42
	;
	;
	; Registraties in nieuwe BH linken
LINK5	S DBUI1=$P($$DI^cAN000(DBUI1,"")," "),I1=""
LINK51	S I1=$O(@IREF@("M1",$$Q^cAFA10(),$E(DBUI1),DBUI1,I1)) I '$L(I1) G LINKZ
	S UI1=$P(^(I1),D),REG=@UREF@(0) I $P(REG,D,30)=2 G LINK51 ; Verwijderd
	I '$P(REG,D,15),'$P(REG,D,16) G LINK51 ; 0-boeking
	I '$P(REG,D,32) G LINK51 ; Automatische boeking
	S K=""
	S $P(K,D2)=$$SIG^cAFA1("AR.A",$P(REG,D,8),150)  ; Grootboekrekening
	S $P(K,D2,2)=$P(REG,D,10) ; EC1-rekening (Project)
	S $P(K,D2,3)=$P(REG,D,19) ; Omschrijving
	S $P(K,D2,4)=$$SIG^cAFA1("ARA.A",$P(REG,D,9),150) ; Analytische rekening
	S DC="D",BEDR=+$P(REG,D,15)
	I $P(REG,D,16) S DC="C",BEDR=+$P(REG,D,16)
	S $P(K,D2,5)=DC_BEDR       ; Bedrag
	;
	; Match?
	I '$D(TVENT(K)) W:$G(SW) !,DBUI1,?15,UI1,?30,"<< Geen link >>>" G LINK51 ; Geen link gevonden = probleem!
	S $P(@UREF@(0),D,35)=TVENT(K) K TVENT(K)
	I $G(SW) W !,DBUI1,?15,UI1,?30,$P(@UREF@(0),D,35)
	;
LINK59	G LINK51
	;
LINKZ	Q
	; 
B(FC,R)	;
	I '$L(R) G BZ
	I FC="C" S R=-R
BZ	Q R
	;
WAA(Q,DBUI1,A,B)	; wijzigen aankoopdagboek
	; Q = Q-waarde
	; DBUI1 = UI1 uit ^DBH("EA","DB"
	; A = tabel met oude nodes
	; B = tabel met nieuwe nodes
	; 
WAAA	S $ZT="TRAP^cAN000"
	I $G(SWO2N) G WAAZ  ; indien opgeroepen vanuit wijzigen oud naar nieuw
	N OK,TAB,Q,I,BP,FNR,FC,KKB,NETG,NETD,NETI,NETA,MST,MSTG,MSTD,MSTI,MSTA,N,SWOPSPL,OM1,COM,SWX,OGM,VVD,MEDED,BPE,SWCUM,SWINV
	S Q=$P(B(1),D,49),Q(49)=Q,SWOPSPL=0
	S OK=2
	I $$PAR^cTN001(Q,201)=2 G WAAZ  ; enkel nog nieuwe registratie
	;
WAAB	I $P(B(1),D)'="A" G WAAZ
	F i=106,108,112,113,124,432,433,434,436 I $P(A(i\100),D,i#100)'=$P(B(i\100),D,i#100) S TAB(i)=$P(B(i\100),D,i#100)
	F i=120,501:1:509 I $P(A(i\100),D,i#100)'=$P(B(i\100),D,i#100) S TAB(i)=$P(B(i\100),D,i#100),SWOPSPL=1
	I '$D(TAB) G WAAZ  ; niets gewijzigd
WAAC	S N=$$LOCK^cTN101(.Q,DBUI1,1) I 'N S OK=0 G WAAZ
	S KCI1=$$SIG^cAFA1("LE.A",$P(B(1),D,10),150)    ; link leverancier
	;S KCQ=$P(^(0),D,49)
	S BP=$P(B(1),D,5)                               ; boekingsmaand
	S BPE=$P(B(1),D,6)                              ; periode
	S FNR=$P(B(1),D,3)                              ; factuurnummer
	S FC=$P(B(1),D,23)                              ; factuurcode (F/C)
	;S OM1=$P(B(1),D,13)                             ; omschrijving
	;S COM=$P(B(1),D,12)                             ; factuurnummer leverancier
	S COM=$P(B(1),D,24)                             ; factuurnummer leverancier
	S OM1=$P(B(1),D,12)                             ; omschrijving (= nieuwe referte, indien leeg = nieuwe omschrijving)
	I '$L(OM1) S OM1=$P(B(1),D,13)
	S SWX=U_'$P(B(4),D,33)                          ; vermelden op betalingsvoorstel
	S OGM=$S('$P(B(4),D,34):"",1:$P(B(4),D,32))     ; gestructureerde mededeling
	S MEDED=$S($P(B(4),D,34):"",1:$P(B(4),D,32))    ; mededeling (niet gestructureerd)
	S VVD=$P(B(1),D,8)                              ; vervaldatum
	S SWINV=$P(B(4),D,36)                           ; IC-investering: 0=Goed, 1=Dienst, ""=n.v.t.
	S NETG=$$B(FC,$P(B(4),D))                       ; netto bedrag goederen
	S NETD=$$B(FC,$P(B(4),D,2))                     ; netto bedrag diensten
	S NETI=$$B(FC,$P(B(4),D,3))                     ; netto investeringen
	S NETA=$$B(FC,$P(B(4),D,4))                     ; netto andere
	S MST=$$B(FC,$P(B(4),D,5))                      ; maatstaf van heffing
	S MSTG=$$B(FC,$P(B(4),D,6))                     ; maatstaf goederen
	S MSTD=$$B(FC,$P(B(4),D,7))                     ; maatstaf diensten
	S MSTI=$$B(FC,$P(B(4),D,8))                     ; maatstaf investeringen
	S MSTA=$$B(FC,$P(B(4),D,9))                     ; maatstaf andere
WAAD	I '$D(@("^"_Q_"AA(BP,FNR)")) S OK=0 G WAAY  ; aankoopdagboek in oud bestaat niet
	S N=^(FNR) S SWCUM=0 I $P(N,D,23)'=BPE S SWCUM=1
	I 'SWOPSPL G WAAF
	; wijzigen opsplitsing
WAAE	S I=$G(@("^"_Q_"AALOG(BP,FNR)"),1),^(FNR)=I+1,^(FNR,I)=N
	S $P(N,D,6)=+$P(N,D,6)_"#"_MST,$P(N,D,7)=NETG_"#"_MSTG,$P(N,D,14)=NETD_"#"_MSTD,$P(N,D,13)=NETI_"#"_MSTI,$P(N,D,15)=NETA_"#"_NETA
WAAF	S $P(N,D,3)=VVD     ; vervaldatum
	S $P(N,D,18)=COM    ; referte (factuurnr lev.)
	S $P(N,D,19)=OM1    ; omschrijving
	S $P(N,D,20)=BPE    ; periode
	S $P(N,D,23)=BPE    ; periode
	S $P(N,D,29)=OGM    ; gestructureerde mededeling
	S $P(N,D,40)=MEDED  ; mededeling
	S $P(N,D,41)=SWINV  ; IC-investering
	I SWCUM D ECUM^cTA180("AA",BP,FNR,"",1) ; Boeking uit ^DBH halen
	S @("^"_Q_"AA(BP,FNR)")=N
	I SWOPSPL S @("^"_Q_"BA(BP,111)")=$H
	I SWCUM D 
	. N SWN2O S SWN2O=1 D ECUM^cTA180("AA",BP,FNR,"") ; Boeking in ^DBH zetten
	;
	; wijzigen openstaande factuur
WAAG	;I '$D(@("^"_$S($L(KCQ):KCQ,1:Q)_"LE(KCI1,FNR)")) G WAAY	
	I '$D(@("^"_Q_"LE(KCI1,FNR)")) G WAAY ; GM 22.04.08 - In "oude" BH zitten de boekhoudgegevens steeds onder dezelfde Q.
	S N=@$ZR
	S $P(N,D,3)=VVD          ; vervaldatum
	S $P(N,D,7)=COM          ; referte (factuurnr lev.)
	S $P(N,D,8)=$P(SWX,U,2)  ; vermelden op betalingsvoorstel
	S $P(N,D,15)=OGM         ; gestructureerde mededeling
	S @$ZR=N
WAAY	S N=$$LOCK^cTN101(.Q,DBUI1,0)
WAAZ	Q OK
	;
BPEC	Q
	;
WREG(UI1,N) ; Wijzigen AA-registratie
	; Input: UI1: UI1 registratie
	;        N:   <optioneel> Node-0 van de registratie
	N BP,S2,FNR,R,AA,R,FNR,LINK,PC
	S $ZT="TRAP^cAN000"
	;
	; Controle parameters
WREG1	S R=2 I '$L($G(UI1)) G WREGZ
	I '$L($G(N)) S N=$$SIGN^cAFA1("REG",UI1,0) I '$L(N) G WREGZ
	S FNR=$$SIG^cAFA1("DB",$P(N,D,3),103) I '$L(FNR) G WREGZ
	S BP=$P(N,D,5) I '$L(BP) G WREGZ
	;
	; Aankoop-registratie bepalen
WREG2	S LINK=$P(N,D,35) I '$L(LINK) G WREGZ
	S S2=FNR_"."_$P(LINK,"#"),PC=$P(LINK,"#",2)
	S AA="^"_Q_"AA(BP,S2)" I '$D(@AA) G WREGZ  ; AA-node bestaat niet
	;
	; Wijzigbare velden
WREG3	S VENT=$P(@AA,D,PC)
	S $P(VENT,"#",2)=$P(N,D,10)   ; EC1-code \ Project
	S $P(VENT,"#",8)=$P(N,D,19)   ; Omschrijving
	S $P(VENT,"#",10)=$S($L($P(N,D,24)):$$SIG^cAFA1("ARA.A",$P(N,D,24),101)_" ",1:"") ; IAS-code 
	S $P(VENT,"#",14)=$P(N,D,11)  ; EC2-code
	S $P(VENT,"#",15)=$P(N,D,12)  ; EC3-code
	S $P(@AA,D,PC)=VENT
	;
WREGZ	Q R
	;
ZZ	; 29.04.08 - 15 u 00 * V9.01