cTN8820(BM,MAP,DMS)	; Proef - balans naar PDF ;       [ 01/12/09  10:13:19 ]
	;
T0	;Proefbalans
T1	; Nummer\ Naam van de rekening\ Totaal saldo\ Debet maand\ Credit maand\ Debet jaar\ Credit jaar\ Beginsaldo
T2	; Totaal groep; Eindtotaal;
T3	;Totaal groep 
T4	;Proefbalans
	;
T0F	;Bilan de vérification
T1F	; Numéro\ Nom du compte\ Solde total\ Débit mensuel\ Crédit mensuel\ Débit annuel\ Crédit annuel\ Solde init.
T2F	; Total groupe; Total final;
T3F	;Total groupe 
T4F	;Bilan de vérification
	;
T0E	;Trial balance
T1E	; Number\ Acount Name\ Total Bal.\ Debit Month\ Credit Month\ Debit Year\ Credit Year\ Start Bal.
T2E	; Total group; Sum total;
T3E	;Total group 
T4E	;Trial balance
	;
1	N VNR
	S $ZT="TRAP^cAN000"
	S KEUID=$$SELPAR^cAFVBA01("",D_1)
	D SEL^cAFVBA01(KEUID,DMS,4)
	;
	; opbouwen ^mtemp99(... met bedragen
	S GRIDID=$$BTEMP^cTN107("",DMS,BM,BM,KEUID,0)
	;
	; sorteren data op rekeningnummer
	S VNR="" K ^TEMP(boot,$J,"BALANS")
	F  S VNR=$O(^mtemp99(GRIDID,"COMMON",VNR)) Q:VNR=""  D
	. S UI1ARA=$P(^mtemp99(GRIDID,"COMMON",VNR,1),D)
	. S BJ=$P(^(0),D,8)
	. S REKNR=$$SIG^cAFA1(DMS,UI1ARA,101)_" "
	. M ^TEMP(boot,$j,"BALANS",REKNR)=^mtemp99(GRIDID,"COMMON",VNR)
	;
	S TITEL=$P($T(@("T4"_QT)),U,2)
	S HD(1)=D
	S HD(2)=D_TITEL_";C;F82" 
	S HD(3)=D_^cBA(2,$E(QT_"N"),+$P(BM,".",2))_" "_BJ_" ;C;F82"
	;
	; afdrukken cijfers vanuit ^TEMP(boot,$J,"BALANS",
	S TAB="9\41\56\71\86\101\116\131",TIT(1)=$P($T(@("T1"_QT)),U,2,99)
	F I=0:1:3 S @("J"_I)="" F X=3:1:8 S T(I,X)=0
	S I1=0 F  S I1=$O(^TEMP(boot,$J,"BALANS",I1)) D  Q:I1=""
	. I $L(I1) S B(1)=^TEMP(boot,$J,"BALANS",I1,0),B(2)=^(1)
	. I J1="" S J1=$E(I1)
	. I J2="" S J2=$E(I1,1,2)
	. I J3="" S J3=$E(I1,1,3)
	. I $E(I1,1,3)'=J3 D S1(3) 
	. I $E(I1,1,2)'=J2 D S1(2)
	. I $E(I1)'=J1 D S1(1)
	. I I1="" Q
	. S TXT(1)=$$SIG^cAFA1(DMS,$P(B(2),D),101)
	. S TXT(2)=$$SIG^cAFA1(DMS,$P(B(2),D),102)
	. S TXT(1)=TXT(1)_"\\\1",TXT(2)=TXT(2)_"\\1"
	. F I=3:1:8 S TXT(I)=$P(B(1),D,I-1)
	. F X=3:1:8 S TXT(X)=TXT(X)_"\\\\1\"_QD_"\\1"
	. S SW=0 F X=3:1:8 I TXT(X) S SW=1 Q
	. S N=$L($P(TXT(1),D)) I N>3 S N=3
	. F X=3:1:8 S T(N,X)=T(N,X)+TXT(X)
	. K:I1'="" AFS I N'=1 D ^cA334
	. F X=1:1:N S @("J"_X)=$E(I1,1,X)
	F I=4:1:7 I $G(TXT(I)),+$P(TXT(I),D)=0 S $P(TXT(I),D)=""
	S TXT(1)="",TXT(2)=$P($T(@("T2"_QT)),U,3)
	F X=3:1:8 S TXT(X)=T(0,X)_"\\\\1\"_QD
	K AFS D ^cA334
	S END=1 D ^cA334
	;
	K ^TEMP(boot,$J,"BALANS")
	;
YZ	Q
	;
	; totaal groep op N cijfers
S1(N)	S SW=0 F X=3:1:8 I T(N,X) S SW=1 Q
S1A	I SW D
	. S TXT(1)="",TXT(2)=$P($T(@("T3"_QT)),U,2)_@("J"_N) I N=3 D
	.. S TXT(2)=TXT(2)_" ---------------"
	. F X=3:1:8 S TXT(X)=T(N,X)_"\\\\1\"_QD S T(N-1,X)=$G(T(N-1,X))+T(N,X)
	. D ^cA334 S END=$S(N=3:132,N=2:145,I1="":161,1:4) K:I1'="" AFS D ^cA334
S1B	S @("J"_N)=$E(I1,1,N) F X=3:1:8 S T(N,X)=0
S1Z	Q
	;
ZZ	; 18.05.09 - FB/GM