cTN8838(BM,MAP,DMS)	; Financieel dagboek ; cTN8838                      [ 01/12/09  08:53:52 ]
	;
T0	;Financieel dagboek
T1	;Diversen;
T2	;  **      Saldo     **;
T3	;  **Uittreksel ;  ** Wissel ;
T4	;Blz :;
T5	;Financieel dagboek ;Ingeboekte wissels ;
T6	; ( bedragen in ;
T7	;Datum Nummer-naam/rekening             \ D-------Klanten------C \ D----Leveranciers----C \ D------Grootboek-----C \ Referentie    \;An.rek.;
T8	;Overdracht:;Eindtotaal:;
T9	;  Totaal debet;
T10	;             Totaal credit;
T11	;Financieel dagboek ;  Debet\  Credit
T12	;Klanten;Leveranciers;Totaal
	;
T0F	;Journal financier/O.D. ;
T1F	;Operations diverses;
T2F	;  **      Solde     **;
T3F	;  **Extrait ;  ** Traite ;
T4F	;Page:;
T5F	;Journal financier ;Traites enregistrés ;
T6F	; ( montants en ;
T7F	;Date  Numéro-nom/compte                \ D-------Clients------C \ D----Fournisseurs----C \ D------Cpte g.l.-----C \ Référence     \;C.Anal.;
T8F	;Transfert:;Total final:;
T9F	;Total débit;
T10F	;Total crédit;
T11F	;Journal financier ; Débit\  Crédit
T12F	;Clients;Fournisseurs;Total
	;
T0E	;Financial journal ;
T1E	;Miscellaneous transactions;
T2E	;  **     Balance    **;
T3E	;  **Statement  ;  ** Bill of exchange ;
T4E	;Pge :;
T5E	;Financial journal ;Registered bills of exchange ;
T6E	; ( amounts in ;
T7E	;Date  Number-name/account              \ D------Customers-----C \ D-----Suppliers------C \ D-------General------C \ Reference     \;An.acc.;
T8E	;Transfer:;Final total:;
T9E	;Total debit;
T10E	;Total credit;
T11E	;Financial journal ; Debit\  Credit
T12E	;Customers;Suppliers;Total
	;
T0D	;Finanzjournal ;
T1D	;Diverse;
T2D	;  **      Saldo     **;
T3D	;  **Auszug ;  ** Wissel ;
T4D	;Pag :;
T5D	;Finanzjournal ;Ingeboekte wissels ;
T6D	; ( Betrage in ;
T7D	;Datum Nummer-Name/Konto                \ D-------Kunden-------C \ D----Lieferanten-----C \ D------Konten--------C \ Referentie    \;An.rek.;
T8D	;Übertrag:;Schlusstotal:;
T9D	;Total Soll;
T10D	;Total Haben;
T11D	;Finanzjournal ;  Soll\  Haben
T12D	;Kunden;Lieferanten;Total
	;
1	S REFREG=$$REF^cAFA10(Q,"REG")
	S UREFREG=$P(REFREG,D),IREFREG=$P(REFREG,D,3)     ; UREF/IREF voor ^DBH(Q,"REG"
	S UREFREG=$$REPL^cAFA10(UREFREG,"UI1","UI1REG")
	S REFKLA=$$REF^cAFA10(Q,"KL.A")
	S UREFKLA=$P(REFKLA,D)                            ; UREF voor ^DKL(,"KL.A"
	S UREFKLA=$$REPL^cAFA10(UREFKLA,"UI1","UI1KLA")
	S REFLEA=$$REF^cAFA10(Q,"LE.A")
	S UREFLEA=$P(REFLEA,D)                            ; UREF voor ^DLE(,"LE.A"
	S UREFLEA=$$REPL^cAFA10(UREFLEA,"UI1","UI1LEA")
	S REFJRN=$$REF^cAFA10(Q,"JRN")
	S UREFJRN=$P(REFJRN,D)                            ; UREF voor ^DBH(,"JRN"
	S UREFJRN=$$REPL^cAFA10(UREFJRN,"UI1","UI1JRN")
	S REFDAR=$$REF^cAFA10(Q,"AR.A")
	S UREFDAR=$P(REFDAR,D)                            ; UREF voor ^DAR(Q,"AR.A"
	S UREFDAR=$$REPL^cAFA10(UREFDAR,"UI1","UI1DAR")
	S REFDB=$$REF^cAFA10(Q,"DB")
	S UREFDB=$P(REFDB,D)                             ; UREF voor ^DBH(Q,"DB"
	S UREFDB=$$REPL^cAFA10(UREFDB,"UI1","UI1DB")
	S SRT="A"
	S LN=0
	K ^HULP(boot,$J),^HULP(boot,$J+.01)
	;
	S BP=BM ;  $E(BM,1,4)_"."_$E(BM,5,6)
	S BM=$TR(BM,".")
	;
	S UI1REG=" "
11	S UI1REG=$O(@IREFREG@("M18",Q,BM,UI1REG)) G 13:UI1REG=""
	S TYPE=$P(UI1REG," ")
	I TYPE'="D",TYPE'="F" G 11           ; alleen diversen en financieel beschouwen
	S NULREG=@UREFREG@(0),EENREG=^(1)
	S UITTR=$P(NULREG,D,3)
	S UI1JRN=$P(NULREG,D,2),JRN=$P(@UREFJRN@(0),D,3)  ; journaalnummer
	S DATUIT=$P(NULREG,D,36),DATUITC=$$DC^cAFD1(DATUIT)
	S ^HULP(boot,$J+.01,$E(UI1REG)_" "_JRN,DATUITC_" "_UI1REG)=@UREFREG@(0)
	;
	G 11
	;
	; aflopen ^HULP(boot,$J+.01 voor afdrukken per journaal
13	S JRN=""
	S BP=$E(BM,1,4)_"."_$E(BM,5,6)
	S MNM=$P($T(@("T0"_QT)),U,2)_": "_^cBA(2,$E(QT_"N"),BP#1*100)_" "_(BP\1)
	S HD(1)=D_MNM_";C;F82",HD(2)="",HD(3)=""
2	S TIT(1)=$P($T(@("T7"_QT)),U,2)
	S TAB="40\65\90\115\131"
	S (DK,CK,DL,CL,DG,CG,DA,CA)=0
	;
	S JRN=$O(^HULP(boot,$J+.01,JRN)) G Y:JRN=""
	K ^HULP(boot,$J)
	S EERSTI4=$O(^HULP(boot,$J+.01,JRN,"")) S EERSTINH=^(EERSTI4)
	S UI1JRN=$P(EERSTINH,D,2)
	S JRNCO=$P(@UREFJRN@(0),D),JRNOMS=$P(@UREFJRN@(0),D,2+((QTU-1)*10))
	S HD(2)=D_JRNCO_" - "_JRNOMS_";C"
	S SAL=0
	I $E(EERSTI4)'="D" D
	. S UI1JRN=$P(EERSTINH,D,2)
	. S UI1DAR=$P(@UREFJRN@(0),D,7)        ; intern nr AR.A van financiële rekening
	. S SAL=$$SALDO^cTN004(Q,UI1DAR,BP)    ; saldo fin.rek in periode BP
	S UTR=""
	D SALDO(SAL)
	S I4=""
21	S I4=$O(^HULP(boot,$J+.01,JRN,I4)) S REGINH="" I $L(I4) S REGINH=^(I4)
	I $P(REGINH,D,3)'=UTR&$L(UTR) D SALDO(SAL) I I4="" G 23
	S TEKST11=$P($P(REGINH,D,36),".",1,2)   ; datum zonder jaartal
	S GLO=$P(REGINH,D,7)                    ; K(lanten),L(everanciers) of G(rootboekrekening)
	S UI1DAR=$P(REGINH,D,8),UI1KLA=$P(REGINH,D,13),UI1LEA=$P(REGINH,D,14)
	;
	; tegenboeking op financiële rekening niet afdrukken, maar wel meetellen voor eindoverzicht
	S UI1JRN=$P(REGINH,D,2) I $P(@UREFJRN@(0),D,7)=UI1DAR S DA=DA+$P(REGINH,D,15),CA=CA+$P(REGINH,D,16) G 21
	;
	S DEBET=$$IP^cAFA1($P(REGINH,D,15),QD,14),CREDIT=$$IP^cAFA1($P(REGINH,D,16),QD,12)
	S TEKST12=""
	I GLO="K" D
	. S TEKST12=$P(@UREFKLA@(0),D)_"-"_$P(^(0),D,2)
	. S TXT(3)="",TXT(4)=""
	. S TXT(2)=$S($P(REGINH,D,15):DEBET,1:$E(BLANCO,1,11)_CREDIT)
	. S DK=DK+$P(REGINH,D,15),CK=CK+$P(REGINH,D,16)
	. S $P(^HULP(boot,$J,"KL"),D)=$P($G(^HULP(boot,$J,"KL")),D)+$P(REGINH,D,15)
	. S $P(^HULP(boot,$J,"KL"),D,2)=$P($G(^HULP(boot,$J,"KL")),D,2)+$P(REGINH,D,16)
	I GLO="L" D
	. S TEKST12=$P(@UREFLEA@(0),D)_"-"_$P(^(0),D,2) 
	. S TXT(2)="",TXT(4)=""
	. S TXT(3)=$S($P(REGINH,D,15):DEBET,1:$E(BLANCO,1,11)_CREDIT)
	. S DL=DL+$P(REGINH,D,15),CL=CL+$P(REGINH,D,16)
	. S $P(^HULP(boot,$J,"LE"),D)=$P($G(^HULP(boot,$J,"LE")),D)+$P(REGINH,D,15)
	. S $P(^HULP(boot,$J,"LE"),D,2)=$P($G(^HULP(boot,$J,"LE")),D,2)+$P(REGINH,D,16)
	I GLO="G" D
	. S TEKST12=$P(@UREFDAR@(0),D)_"-"_$P(^(0),D,2)
	. S TXT(2)="",TXT(3)=""
	. S TXT(4)=$S($P(REGINH,D,15):DEBET,1:$E(BLANCO,1,11)_CREDIT)
	. S DG=DG+$P(REGINH,D,15),CG=CG+$P(REGINH,D,16)
	. S $P(^HULP(boot,$J,UI1DAR),D)=$P($G(^HULP(boot,$J,UI1DAR)),D)+$P(REGINH,D,15)
	. S $P(^HULP(boot,$J,UI1DAR),D,2)=$P($G(^HULP(boot,$J,UI1DAR)),D,2)+$P(REGINH,D,16)
	S TXT(1)=TEKST11_" "_TEKST12_D_D_1
	S TXT(5)=$P(REGINH,D,34)
	S (UI1DB,UTR)=$P(REGINH,D,3)
	D ^cA334
	S LNMAX=70
	S LN=LN+1
	S SAL=SAL-$P(REGINH,D,15)+$P(REGINH,D,16)
	I LN>65 D SUBTOT S LN=0
	G 21
	;
	; einde journaal
23	S END=145
	D ^cA334
	S TXT(1)=$P($T(@("T8"_QT)),U,3)_$P($T(@("T9"_QT)),U,2)_D_D_1
	S TOTDEB=DK+DL+DG
	S TOTCRE=CK+CL+CG
	F VAR="DK","CK","DL","CL","DG","CG" S @VAR=$$IP^cAFA1(@VAR,QD,14)
	S TXT(2)=DK
	S TXT(3)=DL
	S TXT(4)=DG
	S TXT(5)=""
	D ^cA334
	S TXT(1)=$P($T(@("T10"_QT)),U,2)_D_D_1
	S TXT(2)=$E(BLANCO,1,10)_CK
	S TXT(3)=$E(BLANCO,1,10)_CL
	S TXT(4)=$E(BLANCO,1,10)_CG
	S TXT(5)=""
	D ^cA334
	S END=4
	D ^cA334
	; 
	; overzicht journaal
	S TIT(1)=$P($T(@("T11"_QT)),U,2)_" "_JRNOMS_D_$P($T(@("T11"_QT)),U,3)
	S TAB="40\55\70\131"
	K AFS
	S END=8 D ^cA334
	S I3="",TXT(4)=""
	F  S I3=$O(^HULP(boot,$J,I3)) Q:I3=""  D
	. S UI1DAR=I3
	. Q:I3="KL"!(I3="LE")
	. S TXT(1)=$P(@UREFDAR@(0),D)_" "_$P(^(0),D,2)_D_D_1
	. S TXT(2)=$P(^HULP(boot,$J,I3),D)_D_1_D_D_D_1_D_QD
	. S AFS(1,2)=$G(AFS(1,2))+$P(^HULP(boot,$J,I3),D)
	. S TXT(3)=$P(^HULP(boot,$J,I3),D,2)_D_1_D_D_D_1_D_QD
	. S AFS(1,3)=$G(AFS(1,3))+$P(^HULP(boot,$J,I3),D,2)
	. D ^cA334
	;
	; rekening klanten
	S TXT(1)=$P($T(@("T12"_QT)),U,2)_D_D_1
	S TXT(2)=$P($G(^HULP(boot,$J,"KL")),D)_D_1_D_D_D_1_D_QD
	S AFS(1,2)=$G(AFS(1,2))+$P($G(^HULP(boot,$J,"KL")),D)
	S TXT(3)=$P($G(^HULP(boot,$J,"KL")),D,2)_D_1_D_D_D_1_D_QD
	S AFS(1,3)=$G(AFS(1,3))+$P($G(^HULP(boot,$J,"KL")),D,2)
	S TXT(4)=""
	D ^cA334
	;
	; rekening leveranciers
	S TXT(1)=$P($T(@("T12"_QT)),U,3)_D_D_1
	S TXT(2)=$P($G(^HULP(boot,$J,"LE")),D)_D_1_D_D_D_1_D_QD
	S AFS(1,2)=$G(AFS(1,2))+$P($G(^HULP(boot,$J,"LE")),D)
	S TXT(3)=$P($G(^HULP(boot,$J,"LE")),D,2)_D_1_D_D_D_1_D_QD
	S AFS(1,3)=$G(AFS(1,3))+$P($G(^HULP(boot,$J,"LE")),D,2)
	D ^cA334
	;
	; financiële/diverse rekening zelf
	I $E(JRN)="D" D
	. S TXT(1)=$P($T(@("T1"_QT)),U,2)_D_D_1
	. S TXT(2)=0_D_1_D_D_D_1_D_QD
	. S TXT(3)=0_D_1_D_D_D_1_D_QD
	I $E(JRN)'="D" D
	. S TXT(1)=JRNOMS_D_D_1
	. S TXT(2)=DA_D_1_D_D_D_1_D_QD
	. S AFS(1,2)=$G(AFS(1,2))+TOTCRE
	. S TXT(3)=CA_D_1_D_D_D_1_D_QD
	. S AFS(1,3)=$G(AFS(1,3))+TOTDEB
	D ^cA334
	S END=145 D ^cA334
	S TXT(1)=$P($T(@("T12"_QT)),U,4)_D_D_1
	S TXT(2)=AFS(1,2)_D_1_D_D_D_1_D_QD
	S TXT(3)=AFS(1,3)_D_1_D_D_D_1_D_QD
	D ^cA334
	K AFS S END=4 D ^cA334
	G 2
	;
Y	S END=6 D ^cA334 K ^HULP(boot,$J),^HULP(boot,$J+.01)
YZ	Q
	;
SALDO(SAL)	 ; afdrukken "saldo of uittreksel- lijn"
	F I=1:1:5 S TXT(I)=""
	S TEKST1=$S(UTR="":$P($T(@("T2"_QT)),U,2),1:$P($T(@("T3"_QT)),U,2)_$P(@UREFDB@(0),D,3))
	S TEKST2=$$IP^cAFA1(SAL,QD,0)
	S BLANCO=" ",$P(BLANCO," ",40)=" "
	S TXT(1)=TEKST1_$E(BLANCO,1,39-$L(TEKST1)-$L(TEKST2))_TEKST2_D_D_1
	F I=2:1:5 S TXT(I)=""
	D ^cA334
	F I=1:1:5 S TXT(I)=""
	D ^cA334
SALDOZ	Q
	;
	; afdrukken totalen bij overgang bladsprong
SUBTOT	S END=145
	D ^cA334
	S TXT(1)=$P($T(@("T8"_QT)),U,2)_$P($T(@("T9"_QT)),U,2)_D_D_1
	S TXT(2)=$$IP^cAFA1(DK,QD,14)
	S TXT(3)=$$IP^cAFA1(DL,QD,14)
	S TXT(4)=$$IP^cAFA1(DG,QD,14)
	S TXT(5)=""
	D ^cA334
	S TXT(1)=$P($T(@("T10"_QT)),U,2)_D_D_1
	S TXT(2)=$E(BLANCO,1,10)_$$IP^cAFA1(CK,QD,14)
	S TXT(3)=$E(BLANCO,1,10)_$$IP^cAFA1(CL,QD,14)
	S TXT(4)=$E(BLANCO,1,10)_$$IP^cAFA1(CG,QD,14)
	S TXT(5)=""
	D ^cA334
	S END=4
	K AFS
	D ^cA334
SUBTOTZ	Q
	;
ZZ	; 18.05.09 - FB/GM