cTN901 	; Conversie oude naar nieuwe structuur ; cTN901
	;
T1	;Analytisch niet geventileerd;
T2	;Analytische rekening ;NIET ;aangemaakt.;
T3	;Aanmaken;
	;
T1F	;Pas ventilé analytiquement;
	;
T1E	;Analytically not booked;
	;
T1D	;Analytisch nicht ventiliert;
	;
YZ	Q
	;
ABTW(Q)	; Vult de basisrekeningen in bij de BTW-types (aankoop)
	; Input: Q: Vennootschap (als ref. doorgeven : .Q)
	N @$$INITVAR^cAFVBA01("")
	S $ZT="TRAP^cAN000"
	;
	; Referentie ophalen
ABTW1	S D="\",REF=$$REF^cAFA10(.Q,"CODE.9032",149),UREF=$P(REF,D),IREF=$P(REF,D,3) 
	I '$L(IREF) W !,"Geen licentie voor BTW-types (CODE.9032)" G ABTWZ
	;
	; Basisrekeningen ophalen
ABTW2	M BREK=@("^"_$$Q^cAFA10()_"BA(15)")
	;
	; Basisrekeningen bij BTW-types invullen
ABTW3	S i=""
ABTW31	S i=$O(@IREF@($$Q^cAFA10(),i)) I '$L(i) G ABTWY
	S UI1=$P(^(i),D),OK=0 S N0=@UREF@(0),TYPE=$P(N0,D,4) I $P(N0,D,3)'="A" G ABTW31 ; Voorlopig enkel aankoop
	I TYPE=1000 F j=0:1:1 S $P(N0,D,6+j)=$$SIG^cAFA1("AR",$P(BREK(6+j),D)_" ",148),OK=1 ; Onroerende heffing
	I TYPE=1001 F j=0:1:1 S $P(N0,D,6+j)=$$SIG^cAFA1("AR",$P(BREK(4+j),D)_" ",148),OK=1 ; Intracommunautair
	I TYPE=1002 F j=0:1:1 S $P(N0,D,6+j)=$$SIG^cAFA1("AR",$P(BREK(6+j),D)_" ",148),OK=1 ; Medecontractant
	I TYPE=1003 F j=0:1:1 S $P(N0,D,6+j)=$$SIG^cAFA1("AR",$P(BREK(8+j),D)_" ",148),OK=1 ; Verlegging
	I TYPE=1004 F j=0:1:1 S $P(N0,D,6+j)=$$SIG^cAFA1("AR",$P(BREK(2+j),D)_" ",148),OK=1 ; Aftrekbare BTW
	I 'OK G ABTW31
ABTW38	W !,$P(N0,D)_" "_$P(N0,D,2)_":",?30,$P(N0,D,6)_" ("_$$SIG^cAFA1("AR.A",$P(N0,D,6),101),") - "_$P(N0,D,7)_" ("_$$SIG^cAFA1("AR.A",$P(N0,D,7),101)_")"
ABTW39	S @UREF@(0)=N0 G ABTW31
	;
ABTWY	W !,!,"DONE"
ABTWZ	Q
	;
JRN(Q,JRN,DEFN)	; Conversie journaal naar nieuwe structuur (^DBH)
	; Input: Q: Firma (als ref. doorgeven : .Q)
	;	 JRN: Journaal in de vorm
	;	      Xyyy
	;	      ||_ journaalnummer met leidende nullen (""=zonder)
	;	      |_ X: Type journaal (A,V,D,E,F)
	;	 DEFN: Default node (voor divers en analytisch journaal)
	N JRNN,NUI1,TAB,BTAB,i
	S $ZT="TRAP^cAN000"
	;
	; Journaal in oude structuur ophalen
JRN1	S JRNN=$G(@("^"_$$Q^cAFA10()_"BA(""%T"",JRN)")) I '$L(JRNN) S JRNN=$G(DEFN)
	I '$L(JRNN) G JRNZ
	;
	; Journaal samenstellen
JRN2	S $P(TAB(1),D)=$S($L($P(JRNN,D,2)):$P(JRNN,D,2),$E(JRN)="D":"DV",$E(JRN)="E":"DVA",1:"ALG") ; 1.  Journaalcode (afkorting)
	S $P(TAB(1),D,2)=$P(JRNN,D)                  ; 2.  Omschrijving NL
	S $P(TAB(1),D,3)=+$E(JRN,2,4)                ; 3.  Journaalnummer
	S $P(TAB(1),D,4)=$E(JRN)                     ; 4.  Soort journaal
	S $P(TAB(1),D,5)=$S($P(JRNN,D,3)="2":1,1:0)  ; 5.  Type
	S $P(TAB(1),D,6)=$P(JRNN,D,4)                ; 6.  BTW-nummer facturerende VN
	S $P(TAB(1),D,7)=$S($E(TYPE)="F":"..",1:"")  ; 7.  Financiele rekening
	; ...
	S $P(TAB(1),D,12)=$P(JRNN,D)                 ; 12. Omschrijving FR
	S $P(TAB(1),D,22)=$P(JRNN,D)                 ; 22. Omschrijving DU
	S $P(TAB(1),D,30)=$S($P(JRNN,D,3)=1:1,1:0)   ; 30. Operationeel
	S $P(TAB(1),D,32)=$P(JRNN,D)                 ; 32. Omschrijving EN
	S $P(TAB(1),D,49)=$$Q^cAFA10()               ; 49. Q(49)
	;
	; Bestaat journaal reeds?
	S NUI1=$$UI1OP^cAFA1("JRN","M9","",$$Q^cAFA10(),$E(JRN),+$E(JRN,2,4)) I $L(NUI1) G JRN4
	;
	; Journaal openen
JRN3	S NUI1=$$JRNUI1^cTN201($P(TAB(1),D,4)) I '$L(NUI1) X "STOP"
	D P^cAN220("JRN","",NUI1,"TAB","") I $L(K) X "STOP"
	G JRNZ
	;
	; Journaal wijzigen
JRN4	F i=1:1:7,12,22,30,31,49 S BTAB(100+i)=$P(TAB(1),D,i)
	D B^cAN220("JRN","",NUI1,"BTAB") I $L(K) X "STOP"
	;
JRNZ	Q
 	;
FNR(Q,SRT,BJ)	; conversie factuurnummers
	; Input: Q:   Vennootschap
	;        SRT: Type
	;        BJ:  Boekjaar, indien "" alle boekjaren
	S $ZT="TRAP^cAN000"
	N JRN,A,NUI1,TAB,K,LOOP,OUTP,oQ
	;
	D Q1^cAFA10("JRN")
	;
	I SRT="D" G FNRE
	;
	; Aankoop/Verkoop
FNRA	I $L($G(BJ)) G FNRB0
	S LOOP=1,BJ=1900
FNRA2	G:'$G(LOOP) FNRY S BJ=$O(@("^"_Q_"BA(BJ)")) G:'$L(BJ) FNRY G:BJ'?4N FNRA2 
FNRB0	S JRN=SRT,OUTP=""
FNRB1	S JRN=$O(@("^"_Q_"BA(BJ,JRN)")) G FNRA2:$E(JRN)'=SRT
	S A=^(JRN) I '$L(OUTP) W BJ_" " S OUTP=BJ
	S NUI1=$$UI1OP^cAFA1("JRN","M9","",$G(Q(49)),$E(JRN),+$E(JRN,5,$L(JRN))) I '$L(NUI1) X "STOP"
	S TAB(1)=NUI1_D_BJ_D_$P(A,D,2)_D_$P(A,D,3)_D_$P(A,D),$P(TAB(1),D,28)=$P(A,D,7),$P(TAB(1),D,29)=$P(A,D,8)
	I $L($$SIGN^cAFA1("DOCNR",NUI1_" "_BJ,0)) G FNRD
	; openen
FNRC	D P^cAN220("DOCNR","",NUI1_" "_BJ,"TAB","") I K="-" X "STOP"
	G FNRB1
	; wijzigen
FNRD	F i=3:1:49 S TAB(100+i)=$P(TAB(1),D,i)
	D B^cAN220("DOCNR","",NUI1_" "_BJ,"TAB") I K="-" X "STOP"
	G FNRB1
	;
	; Divers
FNRE	S JRNGL="^"_Q_"BA(4,JRN)",JRN="D",JRN=$O(@JRNGL,-1)
FNRE1	S JRN=$O(@JRNGL) I $E(JRN)'="D" G FNRY
	W !,JRN_": " S JR=1900 I $L($G(BJ)) S JR=BJ-1
FNRE2	S JR=$O(@JRNGL@(JR)) I $L(JR)'=4 G FNRE1
	I $L($G(BJ)) I JR'=BJ G FNRE1
	S A=$G(@JRNGL@(JR)) I '$L(A) G FNRE2
	S NUI1=$$UI1OP^cAFA1("JRN","M9","",Q(49),$E(JRN),+$E(JRN,2,$L(JRN))) I '$L(NUI1) X "STOP" ; Journaal niet gevonden
	S TAB(1)=NUI1_D_JR_D_1_D_D_($P(A,D)+1) W JR_" "
	I $L($$SIGN^cAFA1("DOCNR",NUI1_" "_JR,0)) G FNRE4
	; openen
FNRE3	D P^cAN220("DOCNR","",NUI1_" "_JR,"TAB","") I K="-" X "STOP"
	G FNRE2
	; wijzigen
FNRE4	F i=3:1:49 S TAB(100+i)=$P(TAB(1),D,i)
	D B^cAN220("DOCNR","",NUI1_" "_JR,"TAB") I K="-" X "STOP"
FNRE9	G FNRE2
	; 
FNRY	D Q2^cAFA10
FNRZ	Q
	;
BJ(Q)	; conversie boekjaren
	S $ZT="TRAP^cAN000"
	N BA2,I,LM,FM,BJ,K,TAB
	S BA2=$G(@("^"_Q_"BA(2)")),I=0
BJA	S LM=$P(BA2,D,2),FM=$P(BA2,D,3),BA2=$P(BA2,D,4,999)
	I '$L(LM) G BJZ
BJB	S BJ=$E(LM,1,4)
	S TAB(1)=BJ_D_D_(''I)
	S $P(TAB(1),D,49)=$$Q^cAFA10()
BJC	D P^cAN220("BKJ","",Q_" "_BJ,"TAB","") I K="-" X "STOP"
	S I=I+1
BJD	S FM=FM+.01,FM=$J(FM,0,2) S:FM#1>.12 FM=FM+.88
	I FM>LM G BJA
	S TAB(1)=BJ_D_FM_D_''($G(@("^"_Q_"BA(7)"))'<FM)
	S $P(TAB(1),D,49)=$$Q^cAFA10()
BJE	D P^cAN220("BKJ.MND","",Q_" "_BJ_" "_$TR(FM,"."),"TAB","") I K="-" X "STOP"
	G BJD	
BJZ	Q
	;
DATAQ(Q,TNV,TBES,NQ)	; conversie naar ^DATA("EA","Q"
	; Input: Q:  Vennootschap (als ref. doorgeven : .Q)
	;        TVN: Type vennootschap
	;             0 = Boekhouding
	;             1 = Aankoop
	;             2 = Technische Dienst
	;        TBES: Type bestandsstructuur
	;              1 = zowel oude als nieuwe bestandsstructuur
	;              2 = enkel nieuwe
	;        NQ: 1: Geen vragen
	N BA39
	S $ZT="TRAP^cAN000"
DATAQA	S TAB(101)=Q
	S TAB(102)=$G(@("^"_Q_"BA(99,1)"))   ; naam firma
	S TAB(104)=+$G(TNV)                  ; type
	S TAB(202)=$P(@("^"_Q_"BA(39)"),D)   ; munt firma
	S TAB(203)=@("^"_Q_"BA(34)")         ; aantal decimalen
	S BA39=^(39)
	S TAB(204)=$P(BA39,D,2)             ; taalcode
	S TAB(205)=$P(BA39,D,15)            ; taalcode ivm printen landcode
	S TAB(206)=$$UI1OP^cAFA1("ISO.LAND",101,"",$P(BA39,D,3))             ; landcode
	I $L($P(BA39,D,14)) S TAB(122)=$P(BA39,D,14) ; EAN-code
	I $L($P(BA39,D,4)) S TAB(214)=$P(BA39,D,4)   ; kenletters BTW-nummer
	S TAB(130)=0
	S TAB(149)="" ; Q                    ; Q-waarde
	S TAB(201)=+$G(TBES,1)               ; oude en nieuwe bestandsstructuur
	S TAB(208)=$G(@("^"_Q_"BA(25)"),8)   ; Maximaal aantal openstaande boekingsmaanden
	S TAB(209)=$P($P($G(@("^"_Q_"BA(2)")),D,5),".")  ; laatst afgesloten boekjaar
	S TAB(210)=$G(@("^"_Q_"BA(7)"))      ; laatst afgesloten boekingsmaand
	S TAB(211)=$G(^(7,0))                ; laatst afgesloten boekingsmaand klantenboekhouding
	S TAB(212)=TAB(205)                  ; laatst afgesloten boekingsmaand leveranciersboekhouding
	S TAB(213)=$G(^(3))                  ; laatst afgesloten boekingsmaand financieel
	S TAB(301)=$G(@("^"_Q_"BA(99,1.1)")) ; firmagegevens
	F i=2:1:10 S TAB(300+i)=$G(^(i))
	S REF=$$REF^cAFA10(Q,"AR") I '$L(REF) G DATAQAA
	S TAB(401)=$$UI1("AR",$P($G(@("^"_Q_"BA(14,0)")),D))  ; basisrek. klant
	S TAB(403)=$$UI1("AR",$P($G(@("^"_Q_"BA(14,2)")),D))  ; Verkoop : rekening BTW facturen
	S TAB(404)=$$UI1("AR",$P($G(@("^"_Q_"BA(14,3)")),D))  ; Verkoop : rekening BTW creditnota's
	S TAB(402)=$$UI1("AR",$P($G(@("^"_Q_"BA(15,0)")),D))  ; basisrek. leveranciers
	; S TAB(405)=$$UI1("AR",$P($G(@("^"_Q_"BA(15,2)")),D))  ; Aankoop : rekening aftrekbare BTW facturen
	S TAB(405)=""  ; Aankoop : rekening aftrekbare BTW facturen : niet meer nodig : zie BTW-types
	; S TAB(406)=$$UI1("AR",$P($G(@("^"_Q_"BA(15,3)")),D))  ; Aankoop : rekening verschuldigde BTW creditnota’s
	S TAB(406)=""  ; Aankoop : rekening verschuldigde BTW creditnota’s : niet meer nodig : zie BTW-types
	S TAB(407)=$$UI1("AR",$P($G(@("^"_Q_"BA(10,0)")),D))  ; Rekening nadelig koersverschil
	S TAB(408)=$$UI1("AR",$P($G(@("^"_Q_"BA(10,1)")),D))  ; Rekening voordelig koersverschil
	S TAB(409)=$$UI1("ARA",$P($G(@("^"_Q_"BA(10,0)")),D,3))  ; Analytische rekening nadelig koersverschil
	S TAB(410)=$$UI1("ARA",$P($G(@("^"_Q_"BA(10,1)")),D,3))  ; Analytische rekening voordelig koersverschil
	S TAB(411)=$$UI1("AR",$P($G(@("^"_Q_"BA(12)")),D))  ; Rekening betalingskorting klanten
	S TAB(412)=$$UI1("ARA",$P($G(@("^"_Q_"BA(12)")),D,2))  ; Analytische Rekening betalingskorting klanten
	S TAB(413)=$$UI1("AR",$P($G(@("^"_Q_"BA(13)")),D))  ; Rekening betalingskorting leveranciers
	S TAB(414)=$$UI1("ARA",$P($G(@("^"_Q_"BA(13)")),D,2))  ; Analytische Rekening betalingskorting leveranciers
	; Analytische BH
DATAQAA	D ABH(Q,.TAB,$G(NQ))
	;
	S B0=$$SIGN^cAFA1("Q",Q,0)
DATAQB	I $L(B0) G DATAQC
	S I="" F  S I=$O(TAB(I)) Q:I=""  S $P(TAB(I\100),D,I#100)=TAB(I)
	S I=100 F  S I=$O(TAB(I)) Q:I=""  K TAB(I)
	D P^cAN220("Q","",Q,"TAB","") I K="-" X "STOP"
	G DATAQZ
DATAQC	D B^cAN220("Q","",Q,"TAB") I K="-" X "STOP"
DATAQZ	Q
	;
ABH(Q,TAB,NQ) ; Node analytische BH opzetten (node 4)
	; Input: Q: Vennootschap
	; 	 TAB: Tabel waarin node zal opgezet worden
	; 	      Opgelet: doorgeven als referentie 
	; 	 NQ: 1=Geen vragen
	S $ZT="TRAP^cAN000"
	N @$$INITVAR^cAFVBA01("TAB,NQ")
	;
	; Controle parameters
ABH1	I '$L($G(Q)) G ABHZ
	D Q1^cAFA10("ARA.A")
	;
	; Originele switchen ophalen
ABH2	S BA300=$G(@("^"_Q_"BA(300)")),D="\",U=";"
	;
	; Node opzetten
ABH3	F i=1:1:8 S TAB(500+i)=+$P(BA300,D,i)
	S ANVREK=$P(BA300,D,9)
	F i=1:1:5 S TAB(509+i)=$P(ANVREK,"#",i)
	I '$L(TAB(510)) S TAB(510)=0
	I '$L(TAB(511))	S TAB(511)=$P($T(@("T1")),U,2)  ; Omschrijving NL
	I '$L(TAB(512)) S TAB(512)=$P($T(@("T1F")),U,2) ; Omschrijving FR
	I '$L(TAB(513)) S TAB(513)=$P($T(@("T1D")),U,2) ; Omschrijving DU
	I '$L(TAB(514)) S TAB(514)=$P($T(@("T1E")),U,2) ; Omschrijving EN
	S TAB(515)=$P($G(^DPAR(Q,"PAR","DBH",0)),D) ; Startjaar samengestelde cumul (CUM)
	;
	; Startjaar vragen
ABH35	I $L(TAB(515))!'TAB(501)!$G(NQ) G ABH4
ABH351	W !,"Startjaar voor samengestelde analytische cumul? " R K
	I '(K?4N&$L(K)) G ABH351
	S TAB(515)=K ; Startjaar samengestelde cumul (CUM)
	;
	; Rekening "Analytisch niet geventileerd bepalen"
ABH4	I '$L($G(^DPAR(Q,"PAR","ARA",0))) G ABH5
	S ARA=^DPAR(Q,"PAR","ARA",0)
	S NARA=$$SIG^cAFA1("ARA",ARA,148) I '$L(NARA) G ABH5
	S TAB(509)=NARA
	G ABHY
	;
ABH5	I 'TAB(501)!$G(NQ) G ABHY ; Geen analytische boekhouding
	W !,"Analytische rekening instellen als ""Analytisch niet geventileerd""? (J\N) "
	R K I $$UC^cAFA1(K)'="J" S TAB(509)="" G ABHY
	;
	; Tekstrekening kiezen
ABH51	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T1")),U,2),0,0,7,1,1)
	S ARA=$$^cANSYN("ARA",,,1,,,"I $P(^(0),D,13)=1",,$P($T(@("T3")),U,2))
	I ARA="-" G ABH5
	D C^cA612
	I $L(ARA) S TAB(509)=$$SIG^cAFA1("ARA",$P(ARA," ")_" ",148) G ABHY
	;
	; Analytische tekstrekening aanmaken
ABH6	S CODE=0
ABH61	S ARA=$$UI1OP^cAFA1("ARA.A",101,"",CODE) I $L(ARA) S CODE=CODE+1 G ABH61
	S $P(N(1),D)=CODE         ; Nummer
	S $P(N(1),D,13)=1         ; Tekstrekening
	S $P(N(1),D,49)=$G(Q(49)) ; Vennootschap	
	S $P(N(2),D,5)=$P($T(@("T1")),U,2)   ; Omschrijving NL
	S $P(N(2),D,7)=$P($T(@("T1F")),U,2)  ; Omschrijving FR
	S $P(N(2),D,9)=$P($T(@("T1D")),U,2)  ; Omschrijving DU
	S $P(N(2),D,11)=$P($T(@("T1E")),U,2) ; Omschrijving EN
	D P^cAN220("ARA.A","","","N","") 
	W !,$P($T(@("T2")),U,2)_$S($L(K):$P($T(@("T2")),U,3),1:"")_$P($T(@("T2")),U,4) R x
	I $L(NUI1) S TAB(509)=NUI1
	;
ABHY	D Q2^cAFA10
	;
ABHZ	Q
	;
	;
UI1(DMS,K)	
	Q $$SG^cAFA1(DMS,K,148)
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09