cTN9202	; Verkoop : documenten begin boekhouding ; cTN9202  ; Compiled December 8, 2011 12:06:25
	;
T1	;Documenten begin BH: ;
	;
YZ	Q
 	;
CONV(Q,BP)	; Conversie van documenten begin BH naar nieuwe structuur (^DBH)
	; Input: Q: Gewoon doorgeven, niet als referentie!
	;        BP: Boekingsmaand (JJJJ.MM of JJJMM)
	N GRIDID,RZR,OK,OBP,DG,REFDT,TEMP,UI1,OFID,I3,N,i,KLREF,KL,c
	S $ZT="TRAP^cAN000"
	;
	; Opzetten Q49
CONV1	S Q(49)=$$Q49^cAFVBA03(Q,"DB")
	; Onthouden last reference
CONV2	D S1^cAFA1
	;
	; Laatste dag van de vorige maand bepalen
CONV3	I $L(BP)=6 S BP=$E(BP,1,4)_"."_$E(BP,5,6)
	S OBP=BP,BP=BP-.01 I $L(BP)=4 S BP=BP-.88
	S DG=$$LDM^cAFD1($E(BP,1,4),$P(BP,".",2))
	S REFDT=DG_"."_$P(BP,".",2)_"."_$E(BP,3,4)
	S TEMP="^mtemp99(OFID,""COMMON"",I3)",OK=1,c=0
	;
	; Openstaande documenten opvragen op referentiedatum
CONV4	W !,$P($T(@("T1")),U,2)
	S UI1=0,KLREF=$P($$REF^cAFA10(.Q,"KL"),D) I '$L(KLREF) G CONVY
CONV41	 S UI1=$O(@KLREF) I '$L(UI1) G CONV6
	I $P(@KLREF@(0),D,30)=2 G CONV41 ; Verwijderd
	S KL=$P(@KLREF@(0),D,48) I '$L(KL) W "X" G CONV41
	S OFID=$$BTMPOFDT^cAFVBF03($G(OFID),Q,"KL",UI1,QU,REFDT),I3=""
CONV42	S I3=$O(@TEMP) I '$L(I3) G CONV41
	M N=@TEMP 
	; 
	; Tekens van de bedragen aanpassen (F=+, C=-)
CONV43	I ($P(N(0),D,2)="?")!($P(N(0),D,4)>"990000") D ; Voorschotten
	. I $P(N(2),D)'<0 S $P(N(0),D,2)="F"
	. I $P(N(2),D)<0 S $P(N(0),D,2)="C"
	I $P(N(0),D,2)="F" D ; Factuur
	. F i=1:1:5 S $P(N(2),D,i)=+$TR($P(N(2),D,i),"-") 
	. S $P(N(2),D,5)=+$P(N(2),D,5)*-1 ; Korting contant
	I $P(N(0),D,2)="C" D ; CN
	. F i=1:1:5 S $P(N(2),D,i)=+$TR($P(N(2),D,i),"-")*-1 
	. S $P(N(2),D,5)=+$TR($P(N(2),D,5),"-") ; Korting contant
	;
	; Extra aanpassingen
CONV44	S $P(N(0),D,9)=KL       ; Klant
	S $P(N(0),D,10)=""      ; Leverancier
	S $P(N(0),D,11)="V"     ; Type dagboek
	;
	; Hoofding opzetten
CONV45	S GRIDID=$$DOCBB^cTN9102($G(GRIDID),.N)
	;
	; Mtemp99 verwerken
CONV47	S OK=$$DB^cTN101(GRIDID,,D_1) W $S(OK:".",1:"x")
	I OK D LOG^cTN9201($P(OK,D,3),"") S c=c+1
	;
CONV49	G CONV42
	;
	; Opkuis
CONV6	W " "_c
	I $L($G(GRIDID)) K ^mtemp99(GRIDID,"DB")
	I $L($G(OFID)) K ^mtemp99(OFID,"DB")
	;
	; Controle
CONV7	S OK=$$OPEN^cTN9102(Q,"V",OBP)
	;
	; Terugzetten last reference
CONVY	D S2^cAFA1
	;
CONVZ	Q OK
 	;
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09