cZBCS ;VERZENDEN VAN BERICHTEN ;%ZBCS; [ 06/23/2003  11:10 AM ]
 G 1
 ;
T1 ;Poortnummer\"xx,xx,...,xx[] of [] = alle"
T2 ;Poort
T3 ;Op lijnnummer
T4 ;Lijn
T5 ;Op positie
T6 ;Positie
T7 ;Tekst
T8 ;Attrib
T9 ;ALLE
 ;
1 S K=$P($T(+1),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
 W !!!! F I=2,4,6,7,8 w !!?2,$P($T(@("T"_I)),U,2),?10,":"
11 S R="DEV\22\3\"_$P($T(T1),U,2)_"\10" D R0 G YZ:K="-"
 I K="" S (K,DEV)=$$INUSE^cS()
 D WRITE(813)
13 S R="LIJN\22\3\"_$P($T(T3),U,2)_"\\2\\K?.N&K&(K<25)!(K=""-"")" D R0
 G 11:K="-" D WRITE(1013)
15 S R="POS\22\3\"_$P($T(T5),U,2)_"\\2\\K?.N&K&(K<80)!(K=""-"")" D R0
 G 13:K="-" D WRITE(1213)
17 S R="TXT\22\3\"_$P($T(T7),U,2)_"\\"_(80-POS) D R0
 G 15:K="-" D WRITE(1413)
19 S R="K\22\3\"_$P($T(T8),U,2)_"\C1\7" D R0
 G 17:K="-" D WRITE(1613)
 ;
2 S ATR="" F I=1:1 Q:$P(K,",")=""  S:"BIUK"[$E(K) ATR=ATR_"@FMT"_$E(K)_"," S K=$P(K,",",2,9)
 S ATR=$E(ATR,1,$L(ATR)-1)
 S FP=LIJN*100+POS
 D SEND(DEV,TXT,FP,ATR)
 ;
YZ Q
 ;
R0 S R7=1 S:$P(R,D,8)'="" R7=R7_"&("_$P(R,D,8)_")" S:$P(R,D,7)'="" R7=R7_"&("_$P($T(@$P(R,D,7)),U,2,99)_")"
R0A S R2=$P(R,D,2),R3=$P(R,D,3),R4=$P(R,D,4),R5=$P(R,D,5),R6=$P(R,D,6),R8="",$P(R8,".",R6)="."
R0B S R0=$L(R4)+R3+3 S FP=R2*100+R3+F60 W @F W:R3<4 @F1 W @F2,R4," : " I R5'="" W:R5["""" !?2,@F2,@R5 D:R5'["""" @R5
R0C S FP=R2*100+R0+F60 W @F,@F2,R8,@F,@F0 R K W @F2 I $L(K)'>R6,K'["""",K'[D,K'?.E1C.E,@R7 S @$P(R,D)=K
R0D E  G R0C
R0E S FP=$P(R,D,9)*100+$P(R,D,10) I FP W @F,$J("",R6),@F,K
R0Z K R,R0,R2,R3,R4,R5,R6,R7,R8 Q  ;V8 05.07.88
 ;
WRITE(FP) 
 W @F,@F2,K
 Q
 ;
C1 W !?2,"x,...,x[]"
 W !?2,"(B = ",@FMTB,"Bold",@FMTb,", I = ",@FMTI,"invers",@FMTi,", U = ",@FMTU,"onderlijnd",@FMTu,", K = ",@FMTK,"knipperen",@FMTk," of een ",@FMTB,@FMTI,@FMTU,@FMTK,"kombinatie",@FMTb,@FMTi,@FMTu,@FMTk,")"
 Q
 ;
CONVDEV(Devices) 
 New I
 For I=$L(Devices,","):-1:1 Set $P(Devices,",",I)=$$DDB^cS($P(Devices,",",I))
 Quit Devices
 ;
SEND(DEV,TXT,FP,ATR) 
 Set DEV=$$CONVDEV(DEV),K=$$INUSE^cS()
 For I=1:1:$L(DEV,",") If (","_K_",")'[(","_$P(DEV,",",I)_",") Set $P(DEV,",",I)=""
 Set FP=FP-1
 Set:$E(TXT,1)'="""" TXT=""""_TXT
 Set:$E(TXT,$L(TXT))'="""" TXT=TXT_""""
 For I=1:1:$L(DEV,",") Quit:DEV=""  IF $L($P(DEV,",",I)) Do
 .ZU @$P(DEV,",",I) Write *27,7
 .If $L(ATR) Xecute "Write "_ATR
 .Write @F
 .Xecute "Write *7,"" "","_TXT_","" """
 .Write *27,8
 .Hang 1
 Q
 ;
MESSAGE(Users,Text,Line,Position,Attrib) 
 New I,UserId,UserIds,Devices
 Set Attrib=$TR($G(Attrib),",","")
 Set UserIds=$$USERID^vhUSER(Users)
 If $L(UserIds) Do
 .For  Set Devices=$G(Devices)_";"_$$USERDEV^vhUSER($P(UserIds,";")),UserIds=$P(UserIds,";",2,99) Quit:UserIds=""
 .Set $E(Devices)=""
 .Set Position=Line*100+Position
 .For I=$L(Attrib):-1:1 Do
 ..If $D(@("FMT"_$E(Attrib,I))) Set $E(Attrib,I)=",@FMT"_$E(Attrib,I)
 ..Else  Set $E(Attrib,I)=""
 .Set $E(Attrib)=""
 .Do SEND($TR(Devices,";",","),Text,Position,Attrib)
 Quit
 ;
JOB(DEV,TXT,FP,ATR) 
 N (DEV,TXT,FP,ATR)
 D INIT,SEND(DEV,TXT,FP,ATR)
 Q
 ;
SYSTEM(UCI,VOL,DEV,TXT,FP,ATR) 
 N %TC,MSG
 S $ZT="ERROR^cZBCS"
 S MSG="Can't create a job on remote system."
 D @("ADD^vhLock("""_UCI_VOL_""")")
 I '%TC
 E  D
 .J JOB^cZBCS(DEV,TXT,FP,ATR)[UCI,VOL]::5
 .I $T S MSG=""
 .D @("REMOVE^vhLock("""_UCI_VOL_""")")
 I $L(MSG) ZU 1 W !,TXT,!,MSG
 Q
 ;
INIT 
 N DEV,TXT,FP,ATR
 D ^cA604
 Q
 ;
ERROR 
 ZU 1 Write *7,!,"*** ERROR MESSAGE FROM ",$ZN," *** ",$ZE
 Quit
 ;