vhMAIL2 ;Mail [ 08/09/1999  1:23 PM ]
 ;
 ; Nazicht van het mailbestand
CHKFILE 
 If '$D(Q) Set Q="SYS" Do ^cA604
 New R,UserId,MailId,LinkSend,EffSend,Read,NotRead,Filed,Delete,Urgentie,Kreatie,Quit,ArchTyp
 Do MAILD,MAILIZ,MAILIN,MAILIR,MAILIF
 Quit
 ;
MAILD 
 Write !!,"Index ""D"""
 New R,MailId,TUserId
 Set MailId=""
 For  Set MailId=$O(^vhMAIL("D",MailId)) Quit:'MailId  Do
 .Set R=^vhMAIL("D",MailId),FUserId=$P(R,D,6)
 .Set TUserId=""
 .For  Set TUserId=$O(^vhMAIL("D",MailId,"N",TUserId)) Quit:TUserId=""  Do
 ..Set R=^vhMAIL("D",MailId,"N",TUserId),Aktie=$P(R,D,3)
 ..If $D(^vhMAIL("IN",TUserId,MailId)),$D(^vhMAIL("IR",TUserId,MailId)) Do
 ...Set R=^vhMAIL("D",MailId,"N",TUserId)
 ...Write !,"Index ""IR"" en ""IR"" - ",$ZR
 ..If Aktie="G",'$D(^vhMAIL("IR",TUserId,MailId)),$D(^vhMAIL("IN",TUserId,MailId)) Do
 ...Set R=^vhMAIL("D",MailId,"N",TUserId)
 ...Write !,"Index ""IN"" -> ""IR"" - ",$ZR
 Quit
 ;
MAILIZ 
 New R,TUserId
 Write !!,"Index ""IZ"""
 Set UserId=""
 For  Set UserId=$O(^vhMAIL("IZ",UserId)) Quit:UserId=""  Do
 .Set MailId=""
 .For  Set MailId=$O(^vhMAIL("IZ",UserId,MailId)) Quit:MailId=""  Do
 ..If '$D(^vhMAIL("D",MailId)) Write !,"Mail onbekend - ",$ZR
 ..Else  Do
 ...Set R=^vhMAIL("D",MailId),FUserId=$P(R,D,6)
 ...Write:UserId'=FUserId !,"FromUser verschillend - ",$ZR," - ",UserId," <--> ",FUserId
 Quit
 ;
MAILIN 
 Write !!,"Index ""IN"""
 Set UserId=""
 For  Set UserId=$O(^vhMAIL("IN",UserId)) Quit:UserId=""  Do
 .Set MailId=""
 .For  Set MailId=$O(^vhMAIL("IN",UserId,MailId)) Quit:MailId=""  Do
 ..If '$D(^vhMAIL("D",MailId)) Write !,"Mail onbekend - ",$ZR
 ..Else  Write:'$D(^vhMAIL("D",MailId,"N",UserId)) !,"Mail ""N"" onbekend - ",$ZR
 Quit
 ;
MAILIR 
 Write !!,"Index ""IR"""
 Set UserId=""
 For  Set UserId=$O(^vhMAIL("IR",UserId)) Quit:UserId=""  Do
 .Set MailId=""
 .For  Set MailId=$O(^vhMAIL("IR",UserId,MailId)) Quit:MailId=""  Do
 ..If '$D(^vhMAIL("D",MailId)) Write !,"Mail onbekend - ",$ZR
 ..Else  Write:'$D(^vhMAIL("D",MailId,"N",UserId)) !,"Mail ""N"" onbekend - ",$ZR
 Quit
 ;
MAILIF 
 Write !!,"Index ""IF"""
 Set UserId=""
 For  Set UserId=$O(^vhMAIL("IF",UserId)) Quit:UserId=""  Do
 .Set ArchTyp=""
 .For  Set ArchTyp=$O(^vhMAIL("IF",UserId,ArchTyp)) Quit:ArchTyp=""  Do
 ..Set MailId=""
 ..For  Set MailId=$O(^vhMAIL("IF",UserId,ArchTyp,MailId)) Quit:MailId=""  Do
 ...If '$D(^vhMAIL("D",MailId)) Write !,"Mail onbekend - ",$ZR
 ...Else  If '$D(^vhMAIL("D",MailId,"N",UserId)),$P(^vhMAIL("D",MailId),D)'="T" Write !,"Mail ""N"" onbekend - ",$ZR
 Quit
 ;