vhTXTPOP(sGrp,sId,sNoRefr,sP1,sP2,sP3,sP4,sP5,sP6,sP7,sP8,sP9,sP10) ;Tonen van een tekst met buttons [ 11/24/2003  8:14 AM ]
 New sY,sX,sI,sJ,sMLen,D
 New sTop,sBot,sLeft,sRight,sHfd,sInp
 New sB,sBPerL,sBQtyL,sChars,sBBegin,sBSel,sBLen
 Do INIT,FETCH,WRITE,INP:$D(sB),CLEAN
 Quit sInp
 
JaNee(Titel,Tekst)
 New Btn
 Set Btn(1)="Ja&1",Btn(2)="Neen&*"
 Quit $$WordWrapPopup(Titel,Tekst,.Btn)
 
Boodschap(Tekst)
 New Btn
 Set Btn(1)="Ok&1"
 Quit $$WordWrapPopup("",Tekst,.Btn)
  
WordWrapPopup(Titel,Tekst,Btn,AantalColumns="")
 New TekstLijnen,TekstLijn,TekstWordWrap,TestWordWrapIt
 Set TekstLijnen="TekstLijnen"
 Set TekstLijn = 1
 Set:AantalColumns="" AantalColumns = 75
 Set TekstWordWrap = ##class(TECH.StringUtils).WordWrap(Tekst,AantalColumns)
 Set TekstWordWrapIt = ##class(TECH.ListIterator).%New(TekstWordWrap)
 While TekstWordWrapIt.HasNext(){
	Set TekstLijnen(TekstLijn) = TekstWordWrapIt.Next()
	Set TekstLijn = TekstLijn +1	 
 }
 Quit $$WILD^vhTXTPOP("C;C",Titel,TekstLijnen,"Btn",2)  
 
 ;*** Formatering Text ***
 ;&WLocal : WildCard, de local wordt er tussen gevoegd
 ;&S : Separator lijn
 ;&Ix. : Include van de lijn x slaat op de sPx, 0 = Not include, 1 = Include, -1 of * disable voor buttons
 ;&C. : Centrering van de tekstlijn
 ;&L. : Links
 ;&R. : Rechts
 ;&B : Plaats waarde de buttons moeten ingevoegd worden
 ;.ªK.,ªk,ªB,ªb,ªU,ªu : Formatering in de tekst Knipper,Bold,Underline
 ;.#x. : Parameter transformatie #x wordt vervangen door de waarde in sPx
 ;.$. : Het char na $ is het karakter waarmee de button kan geselekteerd worden 
 ;.&Kode* : Returnval voor de button, de * slaat op de default selectie
 ;
 ;Opmerking : Het . geeft aan vervolg tekst ervoor of erachter
 
WARN(Tekst,sTitel,Muet) 
 ; Tekst : Tekstlijnen met "`" of "~" gescheiden
 ; Optie : sTitel
 ; Optie : Muet (1 = geen interactieve waarschuwing)
 
 if '##class(vhLib.TerminalDevice).IsCurrentSessionATerminalSession() {
	new Exception set Exception = ##class(TECH.Exceptions.GeneralErrorException).%New(Tekst)
	do ##class(TECH.ExceptionHandler).Throw(Exception)
 }
 
 New sTxt,sButLoc,I,MailId
 Set sTxt=0
 Set Tekst=$TR(Tekst,"`","~")
 For I=1:1:$L(Tekst,"~") Do
 .Set sTxt=sTxt+1
 .Set sTxt(sTxt)=$P(Tekst,"~",I)_$S($G(Muet):"~",1:"")
 If $G(Muet) Do
 . Set:$G(sTitel)="" sTitel=sTxt(1)
 . Set sTitel=$E("WARN:"_$TR(sTitel,"\","/"),1,40)
 . Set sTxt=sTxt+1,sTxt(sTxt)="~"_$STACK($STACK-3,"PLACE")_"~"
 . Set sTxt=sTxt+1,sTxt(sTxt)=$STACK($STACK-3,"MCODE")
 . Set MailId=$$SYSTEM^vhMAIL("",sTitel,"","PV;CW",.sTxt,,"U","A")
 Else  If $G(Muet)="DISPONLY" Do
 . Set Tekst=$$WILD("C;C",$G(sTitel,"Waarschuwing"),"sTxt","",-1,-1)
 Else  Set Tekst=$$WILD("C;C",$G(sTitel,"Waarschuwing"),"sTxt")
 Quit
  
 ;Toont alleen de tekst, naderhand REFRESH^vhTERMINA() oproepen om de textpop te wissen
DISPONLY(Tekst,sTitel,sNoRefr) 
 ; Tekst : Tekstlijnen met "`" of "~" gescheiden
 ; Optie : sTitel
 New sTxt,sButLoc,I,MailId
 Set sTxt=0
 Set Tekst=$TR(Tekst,"`","~")
 For I=1:1:$L(Tekst,"~") Do
 .Set sTxt=sTxt+1
 .Set sTxt(sTxt)=$P(Tekst,"~",I)_$S($G(Muet):"~",1:"")
 Set Tekst=$$WILD("C;C",$G(sTitel,"Waarschuwing"),"sTxt","",-1,-1,.sNoRefr)
 Quit
 
WILD(sPos,sTitel,sTxtLoc,sButLoc,sButAli,sTimeO,sNoRefr,sP1,sP2,sP3,sP4,sP5) 
 ; sTxtLoc en sButLoc oproepen via "Local"
 ; Indien sButAli=-1 geen buttons, het scherm wordt getekend en wacht op de timeout
 New sY,sX,sI,sJ,sMLen,D
 New sTop,sBot,sLeft,sRight,sHfd,sInp
 New sB,sBPerL,sBQtyL,sChars,sBBegin,sBSel,sBLen
 New sGrp,sId
 If $G(QW),$ZV["MSM" Do ZWINT^vhRtn2(1,$P(sPos,";"),$P(sPos,";",2))
 If $G(sButAli)=-1 Set sId="WILDNOBUT",sButAli=""
 Else  Set sId="WILD"
 Set sGrp="SYS"
 Set:'$L($G(sButLoc)) sButLoc(1)="OK&1",sButLoc="sButLoc"
 Do INIT
 Set sHfd=sPos_D_D_sTitel_D_$G(sButAli)_D_$S($G(sTimeO)=-1:0,1:$G(sTimeO))
 Do FETCH
 Do WRITE
 Do:$G(sTimeO)'=-1 INP,CLEAN
 Write:$G(sTimeO)=-1 @FMTi
 If $G(QW),$ZV["MSM" Do
 .New sInp
 .Do ZWINT^vhRtn2(0)
 Quit $G(sInp)
 
INIT Do:'$G(sNoRefr) STORE^vhTERMINA()
 Do FMTPARAM
 Quit:'$D(^RES(sGrp,"TP",sId))
 Set D="`"
 Set sHfd=$P(^RES(sGrp,"TP",sId),"`",5,99)
 Set sMLen=0
 Set sBQtyL=0,sChars="",sBSel=1,sBLen=0
 Set sInp=""
 Quit
 
FMTPARAM ; Initieel formateren van de paramters
 New sI,sRec,sDec,sFmt,sLen,sAlign
 Set sI=""
 For  Set sI=$O(^RES(sGrp,"TP",sId,"P",sI)) Quit:sI=""  Do
 .Set sRec=^RES(sGrp,"TP",sId,"P",sI)
 .Set X=$G(@("sP"_sI))
 .Set sFmt=$P(sRec,"`",1)
 .Set sDec=$P(sRec,"`",4)
 .Set sLen=$P(sRec,"`",3)
 .Set sAlign=$P(sRec,"`",2)
 .Set:'sLen!'$L(sAlign) sAlign="L"
 .Do EXEC^vhRES($P(sRec,"`",5),$P(sRec,"`",6),"X","(X,sFmt)")
 .If '$L(sFmt) Set @("sP"_sI)=X
 .Else  Set @("sP"_sI)=$$CEL^vhFMT(0,X,sFmt,sAlign,sLen,sDec,"","","","")
 Quit
 
FETCH New sRec,sLijn,sLen,sCnt
 Set sCnt=0,sBBegin=0
 For sI=1:1:$O(^RES(sGrp,"TP",sId,"T",""),-1) Set sRec=^RES(sGrp,"TP",sId,"T",sI) For sJ=1:1:4 Do 
 .Set sLijn=$P(sRec,D,sJ)
 .Quit:'$L(sLijn)
 .Do LIJN(sLijn)
 ; Titel
 Set sLijn=$P(sHfd,D,3),sY(0)=""
 If sLijn["º" Do PARAM
 Set sY(0)=""
 If $L(sLijn) Do
 .Set sLen=$L(sLijn)+2-($L(sLijn,"ª")-1*2)
 .Set sY(0)=" "_sLijn_" "_D_"C"_D_sLen
 .Set:sMLen<sLen sMLen=sLen
 Set sBPerL=$P(sHfd,D,4)
 Set:sBPerL&(sMLen<(sBPerL*(sBLen+3)-1)) sMLen=sBPerL*(sBLen+3)-1
 Set:'sBPerL sBPerL=sMLen-2\(sBLen+3)
 Set:'sBPerL sBPerL=1
 Set sBQtyL=$O(sB(""),-1)/sBPerL+.999\1
 Quit
 
PARAM ; Invoegen van sPx in de lijn/button
 New sOLijn
 Set sOLijn=sLijn,sLijn=""
 For  Quit:sOLijn'["º"  Do 
 .Set sLijn=sLijn_$P(sOLijn,"º")
 .Set $P(sOLijn,"º")=""
 .Set sLijn=sLijn_$G(@("sP"_$E(sOLijn,2)))
 .Set $E(sOLijn,1,2)=""
 Set sLijn=sLijn_sOLijn
 Quit
 
INCLUDE() ; Nakijken of dat de lijn/button mag geincluded worden volgens sPx
 New sR
 Set sR=$G(@("sP"_$E(sLijn,3)))
 Set $E(sLijn,1,3)=""
 Quit sR
 
WILDTXT ; Om eigen geformateerde locals/globals in te voegen in de tekst
 New sKey,sLocal
 Set sLocal=@$E(sLijn,3,99) 
 
 Set sKey=""
 For  Set sKey=$O(@sLocal@(sKey)) Quit:sKey=""  Do LIJN(@sLocal@(sKey))
 Quit
 
LIJN(sLijn) 
 New sAlign
 If sLijn?1"&I"1N.E Quit:$$INCLUDE()'=1
 If sLijn="&B" Do FETCHBUT Set sBBegin=sCnt Quit
 If sLijn?1"&W".E Do WILDTXT Quit
 If sLijn["º" Do PARAM
 Set sAlign="L"
 If $E(sLijn)="&","LRCS"[$E(sLijn,2) Set sAlign=$E(sLijn,2),$E(sLijn,1,2)=""
 Set sLen=$L(sLijn)-($L(sLijn,"ª")-1*2)
 Set:sMLen<sLen sMLen=sLen
 Set sCnt=sCnt+1
 Set sY(sCnt)=sLijn_D_sAlign_D_sLen
 Quit
 
FETCHBUT 
 New sI,sJ,sRec,sLijn,sLen,sCnt,sKode,sLijn,sChar,sPoint,sEnable
 Set sCnt=0
 For sI=1:1:$O(^RES(sGrp,"TP",sId,"B",""),-1) Set sRec=^RES(sGrp,"TP",sId,"B",sI) For sJ=1:1:6 Do 
 .Set sLijn=$P(sRec,D,sJ)
 .Quit:sLijn=""
 .Do BUTTON(sLijn)
 Quit
 
WILDBUT ; Om eigen geformateerde locals/globals in te voegen in de buttons
 New sKey,sLocal
 Set sLocal=@$E(sLijn,3,99) 
 Set sKey=""
 For  Set sKey=$O(@sLocal@(sKey)) Quit:sKey=""  Do BUTTON(@sLocal@(sKey))
 Quit
 
BUTTON(sLijn) 
 Set sEnable=1
 ;0=Hide,1=Enable,* of -1=Disable
 Set:sLijn?1"&I"1N.E sEnable=$$INCLUDE()
 If sLijn?1"&W".E Do WILDBUT Quit
 If sLijn["º" Do PARAM
 Set sKode=$P(sLijn,"&",2)
 Set sLijn=$P(sLijn,"&",1)
 Quit:sEnable=0
 Set sPoint=$Find(sLijn,"$")
 Set sChar=$$UPCASE^vhRtn1($E(sLijn,$S(sPoint:sPoint,1:1)))
 Set:sEnable'=1 sChar=""
 If sPoint Do
 .Set sLijn=$TR(sLijn,"$","")
 .Set:sEnable=1 $E(sLijn,sPoint-1)="ªU"_$E(sLijn,sPoint-1)_"ªu"
 Set sChars=sChars_sChar
 Set sLen=$L(sLijn)+2-($L(sLijn,"ª")-1*2)
 Set:sBLen<sLen sBLen=sLen
 Set sCnt=sCnt+1
 If sKode["*" Set sBSel=sCnt,sKode=$TR(sKode,"*","")
 Set sB(sCnt)=sLijn_D_sKode_D_sChar
 Quit
 
WRITE New sPos,sLen,sBut,sCnt,sAlign
 Set sPos=$P(sHfd,D)
 Set sTop=$P(sPos,U,1)
 Set sBot=$P(sPos,U,2)
 Set sCnt=$O(sY(""),-1)
 If 'sTop,'sBot Set sTop=sScr("ROW")-sCnt-sBQtyL-2\2 Set:'sTop sTop=1
 Set:'sTop sTop=sBot-sCnt-sBQtyL-2+1
 Set:'sBot sBot=sTop+sCnt+sBQtyL+2-1
 Set sLeft=$P(sPos,U,3)
 Set sRight=$P(sPos,U,4)
 If 'sLeft,'sRight Set sLeft=sScr("KOL")-sMLen-4\2 Set:'sLeft sLeft=1
 Set:'sLeft sLeft=sRight-sMLen-4+1
 Set:'sRight sRight=sLeft+sMLen+4-1
 Set sInp=$$IN^vhKEY(sChars,0) Quit:sInp="ENTER"!($L(sInp)=1&(sChars[sInp))
 Do RECT^vhTERMINA(sTop,sLeft,sBot,sRight)
 If (##class(TECH.Config.ConfigMgr).Instance().GeefBoolean("ToonPopupID"))
 {
 	Set FP=sBot*100+sLeft+1
 	Write @F,sGrp_"-"_sId
 }
 Set sBut=0
 For sI=0:1:sCnt Do
 .Set sLen=$P(sY(sI),D,3)
 .Set sAlign=$P(sY(sI),D,2)
 .Set FP=sTop+sI+sBut*100+sLeft+2+$S(sAlign="R":sMLen-sLen,sAlign="C":sMLen-sLen\2,1:0) Write @F 
 .Do:sAlign="S" WSEPAR
 .Do WTXT^vhRES($P(sY(sI),D))
 .If sI=sBBegin Do WBUT Set sBut=sBQtyL
 If $D(sB) Do:sBBegin WSELECT(sBSel,1)
 Quit
 
WSEPAR Do HLIJN^vhTERMINA(sTop+sI+sBut,sLeft,sRight,"M","M",0)
 Quit
 
WBUT New sCnt
 If $D(sB) For sCnt=1:1:$O(sB(""),-1) Do WONE(sCnt)
 ;Write @FMTI
 Quit
 
WSELECT(sBP,Select)     
 New Pos
 Set Pos=sTop+sBBegin+(sBP-1\sBPerL+1)
 Write $C(27,91),Pos,";",sLeft+2+(sBLen+3*(sBP-1#sBPerL)),";",Pos,";",sLeft+2+(sBLen+3*(sBP-1#sBPerL))+sBLen,";7$t"
 Quit
 
WONE(sBP) 
 New sT,sI,sJ
 Set sT=$P($G(sB(sBP)),D)
 Quit:$G(sT)=""
 Set FP=sTop+sBBegin+(sBP-1\sBPerL+1)*100+sLeft+2+(sBLen+3*(sBP-1#sBPerL))
 Write @F Do WTXT^vhRES(" "_sT_" ")
 Quit
 
INP New sBP
 For  Do  Quit:$L(sInp)
 .Set:'$L(sInp) sInp=$$IN^vhKEY(sChars,$P(sHfd,D,5))
 .If sInp="" Set sInp=0 Quit  ; Via timeout
 .Set sBP=sBSel
 .If sInp="ENTER" Set sInp=sBSel Quit
 .If sChars[sInp Do  Set:'sInp sInp="" Quit  ; Volgens karakter
 ..For sI=1:1:$O(sB(""),-1) If $P(sB(sI),D,3)=sInp Set sInp=sI Quit
 .If "HO"=sInp Do  ; Home
 ..For sI=1:1:$O(sB(""),-1) If $L($P(sB(sI),D,3)) Set sBP=sI Quit
 .If "EN"=sInp Do  ; End
 ..For sI=$O(sB(""),-1):-1:1 If $L($P(sB(sI),D,3)) Set sBP=sI Quit
 .If "DO;RI"[sInp Do  ; Volgend
 ..For sI=sBSel+1:1:$O(sB(""),-1) If $L($P(sB(sI),D,3)) Set sBP=sI Quit
 .If "LE;UP"[sInp Do  ; Vorig
 ..For sI=sBSel-1:-1:1 If $L($P(sB(sI),D,3)) Set sBP=sI Quit
 .If sBP'=sBSel Do  ; Display 
 ..Do WSELECT(sBSel,0)
 ..Set sBSel=sBP
 ..Do WSELECT(sBSel,1)
 .Set sInp=""
 
 Set sInp=$S(sInp:$P($G(sB(sInp)),D,2),1:"")
 
 Quit 
 
CLEAN Write @FMTi
 Do:$G(sNoRefr) ADD^vhScherm(sTop,sBot)
 Do:'$G(sNoRefr) REFRESH^vhTERMINA(sTop,sBot)
 Quit