zbclean ; Opkuisen van bestanden ;
 ;
 New
 Set Q="K"
 Do ^cA604
 Write @F11,@F1
 Set FP=103
 Write @F,@FMTI,$P($T(+1),";",2),QN," ",@FMTi
 If $ZU(5)="DEV-ADMIN1" Do
 . For I=1:1 Set R=$P($T(@("T"_I)),";",2,99) Quit:R=""  Do
 .. Set FP=$P(R,";",2)*100+$P(R,";",3)
 .. Write @F,$J(I,2)," ",@FMTU,$P(R,";"),@FMTu
 .. Set FP=$P(R,";",2)*100+$P(R,";",4)
 .. Write @F,":"
 . Set CleanWhat="2"
 . For I=1:1:$L(CleanWhat,",") Set Clean=$P(CleanWhat,",",I) Quit:Clean=""  Do
 .. Set Clean=$P($T(@("T"_Clean)),";",2,99)
 .. Set FP=$P(Clean,";",2)*100+$P(Clean,";",4)+2
 .. Write @F,"Wacht"
 . For  Set Clean=$P(CleanWhat,",") Quit:Clean=""  Do
 .. Set CleanWhat=$P(CleanWhat,",",2,99),Clean=$P($T(@("T"_Clean)),";",2,99)
 .. Set FP=$P(Clean,";",2)*100+$P(Clean,";",4)+2
 .. Write @F,"Bezig"
 .. Do @$P(Clean,";",5)
 .. Set FP=$P(Clean,";",2)*100+$P(Clean,";",4)+2
 .. Write @F,"Klaar"
 Else  Do
 . Set FP=2401
 . Write @F,"Dit prgramma mag niet lopen op ",$ZU(5)
 . Read R
 Quit
 
ProdWNode
 Do:$ZU(5)="DEV-ADMIN1"
 . New R,LEVNr,TOENr,TLNr,KLNr,ORDNr,OLNr,PRNr,WNode
 . Set LEVNr=0
 . For  Set LEVNr=$O(^KTO(LEVNr)) Quit:LEVNr=""  Do
 .. Set TOENr=""
 .. For  Set TOENr=$O(^KTO(LEVNr,TOENr)) Quit:TOENr=""  Do
 ... Set TLNr=100
 ... For  Set TLNr=$O(^KTO(LEVNr,TOENr,TLNr)) Quit:TLNr=""  Do
 .... Set R=^KTO(LEVNr,TOENr,TLNr),PRNr=$P(R,D,2)
 .... Quit:'PRNr
 .... If '$D(^KPR(PRNr)) Kill ^KTO(LEVNr,TOENr,TLNr)
 .... Else  Do KWNODE^FLOWTOE(LEVNr,TOENr,TLNr)
 . Set KLNr=0
 . For  Set KLNr=$O(^KOD(KLNr)) Quit:KLNr=""  Do
 .. Set ORDNr=""
 .. For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 ... Set OLNr=100
 ... For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:OLNr=""  Do
 .... Set R=^KOD(KLNr,"F",ORDNr,OLNr),PRNr=$P(R,D,2)
 .... Quit:'PRNr
 .... If '$D(^KPR(PRNr)) Kill ^KOD(KLNr,"F",ORDNr,OLNr)
 .... Else  Do KWNODE^FLOWORD(KLNr,ORDNr,OLNr)
 . Kill ^ORD,^TO
 . Set PRNr=0
 . For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
 .. Set R=^KPR(PRNr,0),$P(R,D,17)="",^KPR(PRNr,0)=R
 .. Set R=^KPR(PRNr,2),$P(R,D,9)="",^KPR(PRNr,2)=R
 .. Set WNode="W"
 .. Kill ^KPR(PRNr,WNode)
 .. For  Set WNode=$O(^KPR(PRNr,WNode)) Quit:$E(WNode)'="W"  Kill ^KPR(PRNr,WNode)
 . Set LEVNr=0
 . For  Set LEVNr=$O(^KTO(LEVNr)) Quit:LEVNr=""  Do
 .. Set TOENr=""
 .. For  Set TOENr=$O(^KTO(LEVNr,TOENr)) Quit:TOENr=""  Do
 ... Set TLNr=100
 ... For  Set TLNr=$O(^KTO(LEVNr,TOENr,TLNr)) Quit:TLNr=""  Do
 .... Set R=^KTO(LEVNr,TOENr,TLNr),PRNr=$P(R,D,2)
 .... Do:PRNr SWNODE^FLOWTOE(LEVNr,TOENr,TLNr)
 . Set KLNr=0
 . For  Set KLNr=$O(^KOD(KLNr)) Quit:KLNr=""  Do
 .. Set ORDNr=""
 .. For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 ... Set OLNr=100
 ... For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:OLNr=""  Do
 .... Set R=^KOD(KLNr,"F",ORDNr,OLNr),PRNr=$P(R,D,2)
 .... Do:PRNr SWNODE^FLOWORD(KLNr,ORDNr,OLNr)
 Quit
 
ProdIndex
 Do:$ZU(5)="DEV-ADMIN1"
 . Kill ^KPR1,^KPR2,^KPL,^KPM,^KPH
 . Set PRNr=0
 . For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do BLDIND^PRODUKT2(PRNr)
 Quit
 
T1 ;Produkten W-node;15;3;25;ProdWNode
T2 ;Producten Indexen;16;3;25;ProdIndex