#include PRGACNTs
#include APPS.TBXWeb
 
	// Munt pariteit tov. de EURO. 
	// Om een bedrag in EUR om te zetten naar de de resp. munt :  bedrag / MuntPar 
GetMuntPar(Munt) 
	Quit:(Munt="CHF") $$$MuntParCHF
	Quit 1
PrijsConvert(Munt,Prijs)
	Quit:(Munt="")||(Munt="EUR") Prijs
	Quit Prijs/$$GetMuntPar(Munt)
 
	// GetUserMunt is DEPRECATED.  
	// Use method TBXContext.GeefUserMuntEenheid(VERW) 
	// 
	// Deze implementatie blijft enkel staan voor Backward compatibility 
GetUserMunt(sDomVERW,VERW)
	Quit $S($G(VERW)="VHEPN":"EUR", sDomVERW="SFS":"CHF", 1:"EUR")
 
IsInternIPAdres(IPAdres)
	Quit (IPAdres?1(1"192.168."1.3N1"."1.3N,1"127.0.0.1"))
	
IsIctUserIPAdres(IPAdres)
	Quit:(IPAdres?1(1"127.0.0.1")) 1
	Quit ($$IsInternIPAdres(IPAdres)) && ($$$IctUserFromIP(IPAdres)'="")
 
	
AppIsEnabled(App,SubApp,IPAddress)
#define IP4   $P(IPAddress,".",4)
	Quit:('$D(^UI.Settings(App,SubApp))) 1   ; Enabled if global/nodes not defined
	New arEnable
	Merge arEnable=^UI.Settings(App,SubApp,"Enable")
	Quit:($G(arEnable("ALL"),1)) 1           ; Enabled for all users
	Quit:($G(arEnable("IP",$$$IP4),0)) 1     ; internal IP address
	Quit:($G(arEnable("IP",IPAddress),0)) 1   ; any IP address
	Quit 0
	
RedirectPage(RedirURL)
	Set RedirURL=$G(RedirURL,"/Under Construction.htm")
	Set %response.Redirect=RedirURL
	;Set %response.ServerSideRedirect=RedirURL
	Quit
	
RedirectSpamRobots(IPAdres)
	Set RedirectSpamRobots=(IPAdres?1(1"87.249.110.180"))   ; IP-addresses worden manueel onderhouden door WimV (last modified on 16/11/2011)
	If RedirectSpamRobots {
		Do %response.Reset()
		Set %response.Status="400 Bad Request"
	}
	Quit RedirectSpamRobots
 
 
SesDataFromRq(SesKey,RqKey,DflVal)
	Set RqKey=$G(RqKey,SesKey)
	Quit $$SetSesData^cspBasis.Library($Name(%session.Data(SesKey)),$Name(%request.Data(RqKey,1)),.DflVal)
 
SesDataFromLocal(SesKey,Local,DflVal)
	Quit $$SetSesData^cspBasis.Library($Name(%session.Data(SesKey)),$Name(Local),.DflVal)
 
SetSesData(SesRef,NewValRef,DflVal)
	If $D(@NewValRef) Do
	. Set @SesRef=@NewValRef
	Else  Do
	. Set:('$$$aHasData(@SesRef)) @SesRef=$G(DflVal)
	Quit @SesRef
 
DataFromRqOrSes(RqKey,SesKey,DflVal)
	Set SesKey=$G(SesKey,RqKey)
	Quit $$drsGetData^cspBasis.Library($Name(%request.Data(RqKey,1)),$Name(%session.Data(SesKey)),.DflVal)
drsGetData(RqRef,SesRef,DflVal)   ; GetRqOrSesData
	Quit:($$$aHasData(@RqRef)) @RqRef
	Quit $G(@SesRef,$G(DflVal))
 
	
GetURLDomain()
    New ServName,ServPort
    Set ServName=$$$LCase($G(%request.CgiEnvs("SERVER_NAME")))
    Set ServPort=$G(%request.CgiEnvs("SERVER_PORT"),80)
    Set:(ServName="") ServName="www.tandem-box.com"
    Set:(ServPort'=80) ServName=ServName_":"_ServPort
	Quit ServName
 
TBXDomainCVT(Domain)
 	if ##class(TECH.Config.ConfigMgr).Instance().GetBoolean("cspBasis.Library_TestDomeinenOmzetten") {
		set $ZTRAP = "OnErrorTBXDomainCVT"
	 	set TBXDomainCVT = ##class(APPS.TBXWeb.Utils.TestUtils).GeefDomeinNaam(Domain)
	 	set $ZTRAP = ""
	} else {
		set TBXDomainCVT = $piece(Domain,":",1)
	}
	Quit TBXDomainCVT
OnErrorTBXDomainCVT
	Set TBXDomainCVT=""
	Set $ZTRAP = ""
	Set Exception = ##class(TECH.ExceptionHandler).Catch()
	Do ##class(vhLib.Logger).%New("TBXWeb").ErrorMail("Error bij omzetten van Domein "_$G(Domain),"DomeinVerwerker kon niet bepaald : "_Exception.ToString())
	Set $EC = "Error bij omzetten van Domein. Zie vhLibLogging/mail."
	Quit TBXDomainCVT
 
 
	// SendMiniMail eXtended :
	// Replace the domain "vanhoecke.be" in <From> if <lbTo> also contains "vanhoecke.be" domain(s)
SendMiniMailXtd(From,lbTo,Subject,Body,BodyIsStream,Args6,Args7,Args8,lbAttachments,Args10)   ; ,Args11,Args12)
	#define MailsViaNotes01   1
	Do:('$$$MailsViaNotes01) smxSenderFakeDomain^vhLib.Mail(.From,lbTo,,)
	Quit $$SendMiniMail^vhLib.Mail(.From,.lbTo,.Subject,.Body,.BodyIsStream,.Args6,.Args7,.Args8,.lbAttachments,.Args10)   ; ,.Args11,.Args12)
	Quit ""
 
 
	/// Ophalen van de vertaalde waarde van de interne code en omzetten naar HTML-code.
	/// lbFlags om extra conversies te doen (zoals Uppercase, Lowercase, ...)
WebTextValue(VtlGroep,Intern,Taal,TextType,VervangWaarde,lbFlags)
	; Ter info:
	; lbFlags is optioneel (later toegevoegd). 
	; Is dus by default leeg ==> Immediate conversion to HTML (zoals voorheen)
	; Als lbFlags waarde(n) bevat ==> GetVertaling moet plainText teruggeven -> eerst conversie voor lbFlags -> dan convert to HTML
	Quit:($G(Intern)="") ""
	New Val,blnPlainText,ReturnsHTML,FlgItem
	Set Taal=$G(Taal,"N")
	Set TextType=$G(TextType,"L")
	Set lbFlags=$G(lbFlags,"")
	Set blnPlainText=(lbFlags'="")
	Set Val=##class(Res.Vertaling).GetVertalingPlus(VtlGroep,Intern,TextType,Taal,.VervangWaarde,blnPlainText,.ReturnsHTML)
	Quit:(Val="") Intern_" ("_TextType_"-"_Taal_")"
	; Else
	If $L(lbFlags) Do
	. Do wtvBeforeHTML   ; First item of lbFlags
	Quit $S($G(ReturnsHTML):Val, 1:$$ConvertToHTML^vhRtn1(Val))
wtvBeforeHTML
	Quit:($LG(lbFlags,1)="")
	Set FlgItem=$LG(lbFlags,1)
	If FlgItem="L"  Set Val=$$$LCase(Val)
	Else  If FlgItem="U"  Set Val=$$$UCase(Val)
	Else  If FlgItem="F"  Set Val=$$$FCase(Val)
	Else  If '$$$IsList(FlgItem)  Quit
	Else  If ($LG(FlgItem,1)="X")&&($L($LG(FlgItem,2))) Do
	. X "Set Val="_$$$Replace($LI(FlgItem,2),"%v","Val")
	Quit