ATKCUST ; Afstand-toegang voor klanten [ 05/31/2002  10:19 AM ]
 ;
KLINIT(KLNr) 
 Job KLINIT^ATKJOB(%J,$G(KLNr),UserName,WachtW,$G(SuperV),$G(NewKLNr))::LTimeOut
 If $T Set Time=$P($H,",",2) Do
 .For  Quit:$P($H,",",2)-Time>LTimeOut!$G(^HULP(%J,"KLINIT"))
 .If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT^ATK
 If $G(^HULP(%J,"KLINIT")) Do
 .Set R=^HULP(%J,"KLINIT",0),Naam=$P(R,D,2),AanSpr=$P(R,D,4),Straat=$P(R,D,5)
 .Set PostNr=$P(R,D,6),WoonPl=$P(R,D,7),Taal=$P(R,D,9)
 .Set R=^HULP(%J,"KLINIT",1),FaxNr=$P(R,D,24)
 .Set Menu=^HULP(%J,"KLINIT","M") Set:$E(Menu)'=D Menu=D_Menu Set:$E(Menu,$L(Menu))'=D Menu=Menu_D
 .Set LvhKlRef=^HULP(%J,"KLINIT","R")
 Else  Set KLNr=""
 Quit KLNr
 ;
KLDISP 
 New R,FP
 Set FP=202
 Set R=AanSpr Set:$L(R) R=R_" " Set R=R_Naam
 Write @F,R
 Set FP=FP+100
 Write @F,Straat
 Set R=PostNr Set:$L(R) R=R_"   " Set R=R_WoonPl,FP=FP+100
 Write @F,R
 Quit
 ;
RPLKL   
 New R,RplKLNr
 Set FP=2301
 Write @F,@F1
 Set RplKLNr=$$SELECT(KLNr,UserName)
 If $P(RplKLNr,D,2) Set NewKLNr=$P(RplKLNr,D) Quit
 If RplKLNr Do
 .New (sJC,RplKLNr,UserName,WachtW,DefInput)
 .Do
 ..New sJC,RplKLNr,UserName,WachtW
 ..Do INIT^ATK
 .Set KLNr=RplKLNr
 .Set SuperV=1
 .If '$$KLINIT(KLNr) Do NOJOB^ATK Quit
 .Set FP=201
 .Write @F,@F1
 .Do ADD^vhScherm(1,24),COMMAND^ATK
 .Do LOGOFF^ATKLOGOF(),CLEAN^ATK
 Set DefInput=$S(RplKLNr:"?",1:"-")
 Do RESET^vhScherm,ADD^vhScherm(1,24)
 Set FP=201
 Write @F,@F1
 Quit
 ;
LEVADR 
 New R
 Quit:$G(DL(1))="LEVADR"
 Do LDINIT^ATK(Input,Taal)
 Set FP=501
 Write @F,@F1
 If '$D(^HULP(%J,"LEVADR")) Do
 .Do SCRNTYP^ATK("?",Taal)
 .Job LEVADR^ATKJOB(%J,KLNr)::LTimeOut
 .If $T Set Time=$P($H,",",2) Do
 ..For  Hang HangTime Quit:$P($H,",",2)-Time>LTimeOut!($O(^HULP(%J,"LEVADR",""),-1)>LEVADR(4))!$G(^HULP(%J,"LEVADR"))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT^ATK
 If $D(^HULP(%J,"LEVADR")) Do
 .Do SCRNTYP^ATK(Input,Taal)
 .Do ADD^vhScherm(LEVADR(3)-1,24)
 Do LLINIT
 Quit
 ;
DISPLEVA 
 New R,Comlom
 Do DISPLAY^vhScherm("ATKLEVADR","","","","",1)
 Quit
 ;
RUBRIEK(Rubr,Value) 
 Set Rubr=$$GETTXT^ATK("ATKCUST",Rubr,Taal)
 Set Value=Rubr_$J("",Colom-$L(Rubr)+1)_$S($L(Rubr):":",1:" ")_" "_Value
 Quit Value
 ;
LLINIT 
 New LevAdr
 Set LevAdr=$G(^HULP(%J,"LEVADR"))
 Set:LEVADR(4)>LevAdr LEVADR(4)=LevAdr,LEVADR(3)=24-LevAdr
 Quit
 ;
SINIT 
 New I,R
 For I=1:1 Quit:'$D(sScrnDef(I))  Do
 .Quit:$P(sScrnDef(I),"`",4)["H"
 .Set R=$P(sScrnDef(I),"`",15) Set:$L(R) R=$$GETTXT^ATK("ATKCUST",R,Taal)
 .Set:$L(R)>$G(Colom) Colom=$L(R)
 Quit
 ;
SLINIT 
 Set sFL(1)=^HULP(%J,"LEVADR",LEVADR(6))
 Do SINIT
 Quit
 ;
SELECT(SuperV,UserName) 
 New KLNr,Kl,DL,KLSEL,Prompt,Comment1,Comment2,zb,NoKill
 Do ADD^vhScherm(21,24)
 Do INIT^PROC("ATKCUST","KLSEL")
 Set KLSEL(8)=$$GETTXT^ATK("ATKCUST","SELECT",Taal)
 Set KLNr="",NoKill=$D(^HULP(%J,"KLSEL"))
SEL2 Goto SEL3:NoKill
 Kill ^HULP(%J,"KLSEL")
 Set Prompt=$$GETTXT^ATK("ATKCUST","KLANT",Taal)_" : "
 Set Comment1=$$GETTXT^ATK("ATKCUST","INGAVE",Taal),Comment2=$$GETTXT^ATK("ATKCUST","EXIT",Taal)
 Set Kl=$$ASK^vhINP(Prompt,20,"",Comment1,Comment2,"","",ITimeOut)
 Set:$G(zb)=-1 Kl="-",zb=""
 Goto SEL2:Kl=""!zb
 Quit:Kl="-"!(Kl=".") Kl
 Set Kl=$$UPTRIMAN^vhRtn1(Kl)
 Job KLSELECT^ATKJOB(%J,$G(SuperV),$G(UserName),Kl)::LTimeOut
 If $T Set Time=$P($H,",",2) Do
 .For  Quit:$P($H,",",2)-Time>LTimeOut!($O(^HULP(%J,"KLSEL",""),-1)>KLSEL(4))!$G(^HULP(%J,"KLSEL"))
 ..If $P($H,",",2)-Time>LTimeOut Goto TIMEOUT^ATK
SEL3 If $O(^HULP(%J,"KLSEL",1))="" Set KLNr=$P($G(^HULP(%J,"KLSEL",1)),D)
 Goto EXIT:KLNr
 Do WL^PROC
 For  Do  Quit:R="-"!(R="ENTER")
 .Set DL(3)=-ITimeOut
 .Do SL^ATK
 .Kill DL(3)
 .If $G(zb)="",$G(R)="" Set R="-"
 If $D(^HULP(%J,"KLSEL")) For  Quit:$G(^HULP(%J,"KLSEL"))
 Set:R="ENTER" KLNr=+$G(^HULP(%J,"KLSEL",KLSEL(6)))
 If 'NoKill Goto SEL2:'KLNr,EXIT
EXIT Kill:'NoKill ^HULP(%J,"KLSEL")
 If KLNr,NoKill Set KLNr=KLNr_"\1"
 Quit KLNr
 ;
KLMUNT(Old) 
 New Munt
 Set Munt=$G(^HULP(%J,"KLINIT","Munt"),$P(^HULP(%J,"KLINIT",0),D,11))
 Quit $P(Munt,D,'$G(Old)+1)
 ;
TEXT   
 New I,Text,Count,Length,Top,Left,Bottom,Right
 Set Count=0
 If $D(^HULP(%J,"KLINIT","B")) Do
 .Do WRAP^vhRtn1(75,"^HULP(%J,""KLINIT"",""B"",","",.Text)
 .Kill ^HULP(%J,"KLINIT","B")
 .Quit:'$G(Text)
 .Set Length=0
 .For Count=$O(Text(""),-1):-1 Quit:$L(Text(Count))  Kill Text(Count)
 .For Count=1:1:Count Set:$L(Text(Count))>Length Length=$L(Text(Count))
 .Set Top=6,Left=80-Length\2,Bottom=Top+Count-1,Right=Left+Length
 .Write @FMTI
 .For Count=1:1:Count Set FP=Top+Count-1*100+Left Write @F,Text(Count),$J("",Length-$L(Text(Count)))
 .Write @FMTi
 Quit
 ;
RPLMENU() 
 New R
 Set R=$G(^HULP(%J,"KLSEL"))=1
 If R Set R=$P(^HULP(%J,"KLSEL",1),D,2)
 Else  Set R=$$GETTXT^ATK("ATKCUST","MENU",Taal)
 Quit R
 ;