BA186	; Aanpassingen BTW 01.01.10; BA186;                              [ 07/12/09  12:25:06 ]
	;
YZ	Q
	;
NA	; Xecutes na update BA186
	N qq,q,VV,VERS,UQC,USC
	S $ZT="TRAP^cAN000"
	; Ophalen versie
	S VV=$P(^cLOG(0,"VERS","%A"),D,2)
	S VERS=$E($TR(VV,"V.")*100,1,4)
	K ^DPAR(0,"BA.VAK","1019 200401 93",0)
	K ^DPAR(0,"BA.VAK","1019 201001 93",0)
NAA	D DMS^cAN000("UQC","USC","BA.VAK",1) I '$L(UQC)!'$L(USC) G NAA1
	D S1^cAN002(0,"BA.VAK",24)
NAA1	D DMS^cAN000("UQC","USC","ICKW",1) I '$L(UQC)!'$L(USC) G NAA2	
	D S1^cAN002(0,"ICKW",24)
	;
NAA2	D DMS^cAN000("UQC","USC","TEXT.VV",1) I '$L(UQC)!'$L(USC) G NAB
	S BEHEER=1 D S1^cAN002(0,"TEXT.VV",24)
NAA3	D DMS^cAN000("UQC","USC","TEXT.9082",1) I '$L(UQC)!'$L(USC) G NAA4
	D S1^cAN002(0,"TEXT.9082",24)
NAA4	D DMS^cAN000("UQC","USC","TEXT.9083",1) I '$L(UQC)!'$L(USC) G NAB
	D S1^cAN002(0,"TEXT.9083",24)
	;
NAB	s qq=^cLOG(boot,"Q",$ZU(5))
	F i=1:1:$l(qq,D) s q=$p(qq,D,i) i q'="DAM",$l(q) d
	. I $P($G(@("^"_q_"BA(""MENU"",10,11)")),D)'="BTW-listing en kwartaalopgave" q
	. S $P(@("^"_q_"BA(""MENU"",10,11)"),D)="BTW-listing en IC-opgave"
	. S $P(@("^"_q_"BA(""MENU"",10,11)"),D,11)="Listing TVA + Relevé IC"
	I VERS<9040 G NAD
	;
NAC	D UPDI^cABVBD1
	D UPDI^cABVBP18("G","PROG.BH.DBAA\PROG.TEKSTEN.TEXT9083")
	D UPDI^cABVBP18("F","PROG.TECH.DBAA")
	D UPDI^cABVBP18("DC","10311\10312\10060\10052")
	D UPD^cABVBK1("",Q,"10311\10312\10060\10052","",0)
	D UPDI^cABVBP18("G","PROG.BH.ICKW\PROG.TEKSTEN.TEXT9083\PROG.TECH.ICKWDET\PROG.TECH.ICKWDETC")
	D UPDI^cABVBP18("F","PROG.BH.ICKW")
	D UPDI^cABVBP18("DC","10312\10311\10060\10052\10172\10173\10174\10175")
	D UPD^cABVBK1("",Q,"10312\10311\10060\10052\10172\10173\10174\10175","",0)	
	;
NAD	D CONV
	D CONVBTW
	D CONVBTWS
	D CNVBTWT
	;
NAE	; X "ZL cT645 zi $c(9)_""S $P(@(""""^""""_Q_""""AA(BP,FNR)""""),D,41)=$G(SWINV)"":41+1 zs cT645"
	;
NAZ	Q
	;
	;
CONV	; Conversie bij IC-opgave
	N UI1,REF,UREF,DMS,NODE1,NODE0,LOGREF,I1,I2
	S $ZT="TRAP^cAN000"
	S DMS="ICKW",UI1=""
	S REF=$$REF^cAFA10(Q,DMS),UREF=$P(REF,D) I '$L(UREF) G CONVZ
	S LOGREF=$P(REF,D,6)
	W "Conversie bij IC-opgave",!
	S R=$$CONT() I 'R W "Conversie reeds gelopen",! G CONVZ
	S ^DMC(0,DMS,"LOGGING","NOT",101)=1
	S ^DMC(0,DMS,"LOGGING","NOT",102)=1
CONV1	S UI1=$O(@UREF) I '$L(UI1) G CONV2
	S NODE0=$G(^(UI1,0)),NODE1=$G(^(1)) I '$L(NODE0) G CONV1
	I $P(NODE0,D,30) G CONV1 
	;
	W "IC-opgave aanpassen: "_UI1,!
	; K TAB
	; S TAB(101)=""
	; S TAB(102)=$P(NODE0,D)
	; D B^cAN220(DMS,"",UI1,"TAB") I K'="" W "Probleem IC-opgave aanpassen bij: "_UI1,!
	S $P(NODE0,D,2)=$P(NODE0,D)
	S $P(NODE0,D)=""
	S @UREF@(0)=NODE0
	G CONV1
CONV2	D S1^cAN002(0,"ICKW",24)
	W "Einde conversie bij IC-opgave",!
	K ^DMC(0,DMS,"LOGGING","NOT",101)
	K ^DMC(0,DMS,"LOGGING","NOT",102)
	; Conversie logging
CONV3	I '$L(LOGREF) G CONVZ
	S I1=""
CONV31	S I1=$O(@LOGREF@(I1))
	I I1="" G CONVY
	S I2=""
CONV32	S I2=$O(@LOGREF@(I1,I2))
	I I2="" G CONV31
	S INH=^(I2)
	I $P(INH,D)'="W" G CONV32
	I $P(INH,D,2)'="101" G CONV32
	I $P($P(INH,D,8),"~")'="Kwartaal" G CONV32
	S $P(INH,D,2)="102"
	S @LOGREF@(I1,I2)=INH
	G CONV32
CONVY	W !,"Einde conversie logging IC-opgave"
CONVZ	Q
	;
	;
CONVBTW	; Conversie bij BTW-types
	N UI1,REF,UREF,DMS,NED,NODE0,PERC,DEEL1,DEEL2
	S $ZT="TRAP^cAN000"
	S DMS="CODE.9032",UI1=""
	S REF=$$REF^cAFA10(Q,DMS),UREF=$P(REF,D) I '$L(UREF) G CONVBTWZ
	W !,"Conversie bij BTW-types"
	;
CONVBTW1	S UI1=$O(@UREF) I '$L(UI1) G CONVBTWZ
	S NODE0=$G(^(UI1,0)),NODE1=$G(^(1)) I '$L(NODE0) G CONVBTW1
	I $P(NODE0,D,30)=2 G CONVBTW1
	S NED=$$UC^cAFA1($P(NODE0,D,2))
	S DEEL1=$P(NED," "),DEEL2=$P(NED," ",2)
	I DEEL1="MEDECONTRACTANT",(DEEL2="BUITENLAND") G CONVBTW2
	I DEEL1="MEDECONTRACTANT",(DEEL2="BINNENLAND") G CONVBTW3
	G CONVBTW1      ; BTW-type is geen Medecontractant dus volgende ophalen
	;
	; 'Medecontractant buitenland' wordt aangepast naar 'Medecontractant'
CONVBTW2	S PERC=$P(NED," ",3)
	K TAB
	S TAB(102)="Medecontractant "_PERC
	S TAB(112)="Cocontractant "_PERC
	S TAB(132)="Co-contractor "_PERC
	W !,"Aanpassen van : "_NED_" - "_UI1,!
	ZW TAB
	D B^cAN220(DMS,"",UI1,"TAB") I K'="" W !,"Probleem BTW-type aanpassen bij: "_UI1,!
	G CONVBTW1
	;
	; 'Medecontractant binnenland' wordt buitengebruik geplaatst
CONVBTW3	W !,"Buiten gebruikt zetten van : "_NED_" - "_UI1
	D W^cAN220(DMS,"",UI1,130,1) I K'="" W !,"Probleem aanpassen BTW-type bij: "_UI1,!
	G CONVBTW1
	;
CONVBTWZ W !,"Einde conversie bij BTW-types",!
	Q
	;
	;
CNVBTWT	; Buiten gebruik zettten BTW-types IC0, MC0, OH0 en VL0
	N DMS,REF,UREF,UI1,NODE0
	S $ZT="TRAP^cAN000"
	S DMS="CODE.9032",UI1=""
	S REF=$$REF^cAFA10(Q,DMS),UREF=$P(REF,D) I '$L(UREF) G CNVBTWTZ
	W !,"Correctie bij BTW-types"
	;
CNVBTWTA	S UI1=$O(@UREF) I '$L(UI1) G CNVBTWTY
	S NODE0=$G(^(UI1,0)) I '$L(NODE0) G CNVBTWTA
	I $P(NODE0,D)'="IC0",($P(NODE0,D)'="MC0"),($P(NODE0,D)'="OH0"),($P(NODE0,D)'="VL0") G CNVBTWTA
	I $P(NODE0,D,30) G CNVBTWTA
	D W^cAN220(DMS,"",UI1,130,1) I K="-" W !,"Probleem correctie BTW-type :"_UI1
	G CNVBTWTA
CNVBTWTY	W !,"Einde correctie bij BTW-types"
CNVBTWTZ	Q
	;
	;
CONVBTWS	; Conversie bij BTW-soorten
	N UI1,REF,UREF,DMS,NODE0
	S $ZT="TRAP^cAN000"
	S DMS="CODE.9031",UI1=""
	S REF=$$REF^cAFA10(Q,DMS),UREF=$P(REF,D) I '$L(UREF) G CONVBTWSZ
	W !,"Conversie bij BTW-soorten"
	;
CONVBTWS1 ; BTW-soort 'Onroerende heffing buiten gebruikt zetten'
	S UI1=$O(@UREF) I '$L(UI1) G CONVBTWSZ
	S NODE0=$G(^(UI1,0)),NODE1=$G(^(1)) I '$L(NODE0) G CONVBTWS1
	I $P(NODE0,D,30) G CONVBTWS1
	I $P(NODE0,D)'=0 G CONVBTWS1
	;
	W !,"Buiten gebruikt zetten van : "_$P(NODE0,D,2)_" - "_UI1
	D W^cAN220(DMS,"",UI1,130,1) I K'="" W !,"Probleem aanpassen BTW-soort bij: "_UI1,!
	G CONVBTWS1
	;
CONVBTWSZ W !,"Einde conversie bij BTW-soorten",!
	Q
	;
	;
	;
CONT()	; Controle of conversie bij IC-opgave moet uitgevoerd worden
	N UI1,REF,UREF,DMS,NODE0
	S $ZT="TRAP^cAN000"
	S DMS="ICKW",UI1="",R=1
	I $D(^DOCU("BA186")) S R=0 G CONTZ
	S REF=$$REF^cAFA10(Q,DMS),UREF=$P(REF,D) I '$L(UREF) G CONTZ
CONT1	S UI1=$O(@UREF) I '$L(UI1) G CONTZ
	S NODE0=$G(^(UI1,0)) I '$L(NODE0) G CONT1
	I $P(NODE0,D,30) G CONT1
	I $P(NODE0,D,2) S R=0 G CONTZ            ; Indien er op B102 iets ingevuld is dan heeft de conversie al gelopen
CONT2	G CONT1
	;
CONTZ	Q R
	;
	;
ZZ	; 17.11.09 - 11 u 45