BLPRNEW ;BLUM nieuwe produkten lijst [ 04/11/96  4:17 PM ]
 Do INIT
 If 'BLPRNEW(9) Do TXT^vhINP("Er zijn geen nieuwe BLUM-produkten") Quit
 Do COMMAND,CLEAN
 Quit
 
COMMAND ; Lus voor het uitvoeren van de opdrachten
 Set Input=""
 For  Quit:Input="-"!(Input=".")  Do
 .Set DL(3)=3
 .Do REFRESH,SL^PROC
 .Set Input=R
 .If Input="HELP" Do HELP
 .If Input="ENTER" Do RAADPL
 .If Input="V" Do DELETE
 .If Input="A" Do DELALL
 Quit
 
INIT ; Opbouw hulpbestand 
 New SortKey,IDNr
 Kill Y
 Write @F11,@F1
 Do INIT^PROC("BLPRNEW")
 Set %J=$$%J^vhRtn1()
 Do SORT(%J)
 Set SortKey="",Cnt=0
 For  Set SortKey=$O(^HULP(%J,"S",SortKey)) Quit:SortKey=""  Set IDNr=^HULP(%J,"S",SortKey),Cnt=Cnt+1,^HULP(%J,"N",Cnt)=IDNr
 Kill ^HULP(%J,"S")
 Set BLPRNEW(9)=Cnt
 Do ADD^vhScherm(1,24)
 Quit
 
SORT(%J)
 New IDNr,SortKey,LastUpdate,DelDate
 Kill ^HULP(%J,"S")
 Set DelDate=$$CALCDATE^vhDTyp(,"M",-12,"FD"),IDNr=""
 For  Set IDNr=$O(^BLProd("N",IDNr)) Quit:IDNr=""  Do
 . Set LastUpdate=$$INTDATE^vhDTyp($P(^BLProd("D",IDNr),D,17))
 . If LastUpdate,LastUpdate<DelDate Kill ^BLProd("N",IDNr) Quit
 . Set SortKey=(99999-LastUpdate)_IDNr
 . Set ^HULP(%J,"S",SortKey)=IDNr
 Quit
 
REFRESH ; Herstellen scherm
 If sRT<2 Write @F11,@FMTI,"BLUM Nieuwe produkten - "_QN,@FMTi
 Kill DL Set DL(1)="BLPRNEW"
 If sRB>2 Set DL(2)=sRT,DL(3)=sRB Do WL^PROC Kill DL(2),DL(3)
 Do RESET^vhScherm
 Quit
 
HELP ; Tonen van menu en help
 Set R=""
 Do POP^MN("BLPRNEW")
 Set Input=R
 If Input'="HELP" Do REFRESH Quit
 New HLP
 Set HLP(1)="BLPRNEW"
 Set HLP(3)=9
 Do ^HELP
 Do ADD^vhScherm(9,24)
 Quit
 
CLEAN ; Opkuis en unlock
 Kill ^HULP(%J)
 Quit
 
RAADPL Set IDNr=^HULP(%J,"N",BLPRNEW(6))
 Set Locals("PARAM")=IDNr
 Do DO^vhPROGRAM("^BLPRGEG")
 Write @F11,@F1
 Do ADD^vhScherm(1,24)
 Quit
 
DELETE Set IDNr=^HULP(%J,"N",BLPRNEW(6))
 Kill ^BLProd("N",IDNr)
 Do DELETE^PROC3
 Quit
 
DELALL S R=$$ASK^vhINP("Bent U zeker dat U deze lijst wenst te verwijderen : ",1,"","V[] = Ganse lijst verwijderen")
 Quit:R'="V"
 Kill ^BLProd("N")
 Set Input="-"
 Quit