BLPUTZ2 ;BLUM PRIJSUITZONDERING LIJST; DMS-ES ;[ 11/05/2001  2:22 PM ]
 
 New NoSa,TypeList,AddStat,X,Y,BLKLNr,KLList
 If '$D(Q) S Q="K" D ^cA604
 Write @F11,@F1
 Set FP=202 Write @F,@F4,$P($T(+1),U,2)_" "_QN_" ",@F5
 
 ; Type van lijst
SEL2 Set TypeList=$$ASKL^vhINP("BLPUTZ","LIJSTTYPE")
 Quit:'$L(TypeList)!("KIV"'[TypeList)
 Set NoSa=""
SEL3 Set:"KI"[TypeList NoSa=$$ASKL^vhINP("BLPUTZ","LIJSTNOSA")
 Goto SEL2:NoSa="-" Quit:NoSa="."  Goto SEL3:"V"'[NoSa
 Set NoSa=$S("V"=NoSa:"S",1:"")
 Set AddStat=""
SEL4 Set:"KI"[TypeList AddStat=$$ASKL^vhINP("BLPUTZ","LIJSTSTAT")
 Goto SEL3:AddStat="-" Quit:AddStat="."  Goto SEL4:"J"'[AddStat
 Set AddStat=AddStat="J"
 Set FP=1901 Write @F,@F1
 
 ; Welke klant
 Set KLList=$$SELECT^BLKLANT("M",10,"","Blum klanten, meerdere klanten selecteren door spatiebalk, [] voor afdruk")
 Quit:$L(KLList)<2
 Set FP=1001 Write @F,@F1
 Do PRINT(KLList,TypeList,NoSa,AddStat)
 Quit
 
PRINT(KLList,TypeList,NoSa,AddStat) ;Verwerken van de klanten
 New BLKLNr,SaNo,%J,EM,BM
 Set %J=$$%J^vhRtn1()
 Set NoSa=$G(NoSa)
 Set AddStat=$G(AddStat)
 Kill ^HULP(%J)
 Set BM=$$CALCDATE^vhDTyp($H,"M",-13,"LD")
 Set EM=$$CALCDATE^vhDTyp($H,"M",-1,"LD")
 Set NoSa=$S(NoSa="S":"RPS",1:"RP")
 Set SaNo=$S(NoSa["S":"RP",1:"RPS")
 For  Quit:KLList=""  Do
 .Set BLKLNr=$P(KLList,";"),KLList=$P(KLList,";",2,99)
 .Do VKLANT(BLKLNr)
 If TypeList="K" Do LKLANT
 If TypeList="I" Do LINTERN
 If TypeList="V" Do LINTERN
 Kill ^HULP(%J)
 Do ADD^vhScherm(1,24)
 Quit
 
VKLANT(BLKLNr) 
 New VHKLNr,IsNet,AlgRab,FromStat,IDNr,RA,RB,GO,Temp
 Set VHKLNr=+$P($G(^BLBeri("K",BLKLNr)),D,3)
 ;Set IList="0;1;2;8"
 ;Set:BLKLNr#1000=250&(BLKLNr'=212250) IList="1;2;0;8"
 Set AlgRab=$P(^BLProd("R",BLKLNr),D,1)*100
 Set IsNet=$P(^BLProd("R",BLKLNr),D,2)
 ; Aflopen van de produkten in de prijzuitzondering
 Set FromStat=0
 Set IDNr=""
 For  Set IDNr=$O(^BLProd(NoSa,BLKLNr,IDNr)) Quit:IDNr=""  Do
 .Set (RA,RB)=^BLProd(NoSa,BLKLNr,IDNr)
 .Set:TypeList="V" RB=$G(^BLProd(SaNo,BLKLNr,IDNr))
 .Do VPROD(BLKLNr,IDNr,RA,RB)
 ; Aflopen van de produkten in de schaduw prijzuitzondering
 If TypeList="V" For  Set IDNr=$O(^BLProd(SaNo,BLKLNr,IDNr)) Quit:IDNr=""  Do
 .Quit:$D(^BLProd(NoSa,BLKLNr,IDNr))
 .Set RB=^BLProd(SaNo,BLKLNr,IDNr)
 .Set RA=""
 .Do VPROD(BLKLNr,IDNr,RA,RB)
 ; Bijvoegen statistiek
 Set FromStat=1
 If AddStat For  Set IDNr=$O(^BLStat("D",BLKLNr,IDNr)) Quit:IDNr=""  Do
 .Quit:$D(^BLProd(NoSa,BLKLNr,IDNr))
 .Set GO=$P($G(^BLProd(D,IDNr)),D,12)
 .Set RA="\"_GO_"\\\P\"
 .Do VPROD(BLKLNr,IDNr,RA,RA)
 ; Eerste lijn
 Set Temp=BLKLNr_D_$P(^BLBeri("K",BLKLNr),D)_D_IsNet_D_$S(IsNet&(BLKLNr=452250):"Netto prijzen in BEF (100 BEF = 34 ATS; 100 ATS = 294,12 BEF)",IsNet:"Netto prijzen in ATS"_$S(TypeList'="K":" (P24 - "_AlgRab_"%)",1:""),1:"Bruto prijzen")
 Set ^HULP(%J,$S(BLKLNr=212250:"",1:BLKLNr)_"  "," "," "," "," ")=Temp
 Quit
 
 ;
VPROD(BLKLNr,IDNr,RecPR,ORecPR) 
 New PRNr,ESPrijs,ESGrOr,ESKort,ROG,KortT,HoofdGr,Groep,SubGroep,VHProd,DiffPr,VHPRijs,VHGrOr,VHKort,BPrijs,ESNet,IsBPr,AMenge,BMenge,Exist,ComMax,ROGKL
 New TempId,NetATS,OldNet,OldKort,OldBrut,VGLBrut,VGLNet,VHNet,VHPRec,StatVal,VHPrijs,ANet,APrijs,BGrOr,BKort,BLRec,BNP,BNet,Com
 Set Exist=""
 Set:RecPR="" Exist="S",RecPR=ORecPR
 Set:ORecPR="" Exist="N",ORecPR=RecPR
 Set (VGLBrut,ESPrijs)=$P(RecPR,D),ESGrOr=$P(RecPR,D,2),ESKort=$P(RecPR,D,3)
 Set (VGLNet,ESNet)=$P(RecPR,D,4)
 Set OldNet=$P(ORecPR,D,4),OldBrut=$P(ORecPR,D,1),OldKort=$P(ORecPR,D,3)
 If 'VGLNet Set VGLNet=$J(ESPrijs*(1-ESKort)+0.004,0,2)
 If 'OldNet Set OldNet=$J(OldBrut*(1-OldKort)+0.004,0,2)
 Set BNP=$P(RecPR,D,5)
 If BNP="B" Set ESNet=ESPrijs*(1-ESKort)
 Set (HoofdGr,Groep,SubGroep)="~",KortT="",VHProd="*"
 If '$D(^BLProd("D",IDNr)) Set KortT="~~~ Onbekend in P24 ~~~",BLRec="",PrijsRec=""
 Else  Set BLRec=$G(^BLProd("D",IDNr)),KortT=$P(BLRec,D),PrijsRec=$$PRIJS^BLPRGEG(IDNr,,,1)
 Set ROGKL=$P(BLRec,D,16)
 Set IsBPr=0,VHProd=0
 If BLKLNr'=212250 Set IsBPr=$P(RecPR,D,9)
 ; Nakijken of produkt voor die BLUM klant bestaat in ^PRPUTZ
 Set PRNr=$$GETVH^BLPROD(IDNr,BLKLNr)
 Set KLRef=""
 If PRNr Do
 .Set KortT=$P(^KPR(PRNr,0),D)
 .Set $E(IDNr)=$E($P(^KPR(PRNr,2),D,25))
 .Set R=$O(^KPR(PRNr,"I"))
 .Set VHProd=1
 .If $E(R)="I" Set R=^KPR(PRNr,R),HoofdGr=$P(R,D),Groep=$P(R,D,2),SubGroep=$P(R,D,3)
 .Set:'$L(KortT) KortT=$P(^KPR(PRNr,0),D)
 .Set R=$O(^KPR(PRNr,"J"))
 .If BLKLNr=212250,$E(R)="J" Set R=^KPR(PRNr,R),IsBPr=$P(R,D,18)
 .If TypeList="K",$D(^PAKKET("IP",PRNr,VHKLNr)) Do
 ..Set PakNr=""
 ..For  Set PakNr=$O(^PAKKET("IP",PRNr,VHKLNr,PakNr)) Quit:PakNr=""  Do
 ...Set KLRef=KLRef_"; "_$P(^PAKKET("D",PakNr),D,2)
 ..Set $E(KLRef,1,2)=""
 Set APrijs=$P(PrijsRec,D,1)
 Set BPrijs=""
 Set VHGrOr=$P(PrijsRec,D,2)
 Set AMenge=$P(PrijsRec,D,7)
 Set BMenge=""
 Set ROG=$$ROG^BLPRGEG(ROGKL,0,BLKLNr)
 Set VHKort=$P(PrijsRec,D,3)
 Set ComMax=$P(ROG,D,4)
 Set ROG=$P(ROG,D)
 If APrijs Set ESPrijs=APrijs,ESGrOr=VHGrOr
 If IsBPr,BPrijs Set ESPrijs=BPrijs,ESGrOr=VHGrOr
 ;Set ESPrijs=ESPrijs*$S(BLKLNr=452250:299.94/100,1:1)
 If BNP="P" Set ESNet=ESPrijs*(1-VHKort),ESKort=VHKort
 If BNP="B" Set ESNet=ESPrijs*(1-ESKort)
 If IsNet Set ESNet=$J(ESNet+.004,0,2)
 Set DiffPr=0
 ;Set DiffPr=VGLNet-.02>ESNet!(VGLNet+.02<ESNet)&VGLNet&(BNP'="P")
 If 'DiffPr,BNP="B",+VGLBrut'=+ESPrijs Set DiffPr=DiffPr+1
 If 'DiffPr,BNP'="P",+VGLNet'=+OldNet Set DiffPr=DiffPr+2
 Set NetATS=ESNet*$S(BLKLNr="044260":13.7603,BLKLNr=452250:34/100,1:1)
 Set Com=$$COMMIS(ROG,$S(IsBPr:BPrijs,1:APrijs),NetATS,ComMax)
 If 'ESPrijs Set ESKort=""
 If ESPrijs,BNP="N" Do
 .Set ESKort=1-(NetATS/ESPrijs)
 .Set T1=$J(ESKort+.0004,0,3)
 .Set T2=$J(ESPrijs*(1-T1)+.004,0,2)
 .Set:+T2=NetATS ESKort=T1
 If 'IsNet,BNP'="N" Set (ESNet,ESGrOr)=""
 ;Set VHPrijs=$S(IsBPr:BPrijs,1:APrijs)
 ;Set VHNet=$J(VHPrijs*(1-VHKort)+.004,0,2)
 Set (VHPrijs,VHNet,ANet)=""
 Set (BNet,BKort,BGrOr)=""
 Set StatVal=$P($$STAT(BLKLNr,IDNr,BM,EM),D)
 Set TempId=$S($L(IDNr):$E(IDNr)_"."_$E(IDNr,2,4)_"."_$E(IDNr,5,7)_"."_$E(IDNr,8),1:"")
 Set VHPRec=""
 Set:VHProd&VHKLNr VHPRec=$$KLANTPR^KPRIJS(VHKLNr,PRNr)
 If 'VHProd Set $E(TempId)="*"
 Set R=D_TempId_D_KortT_D_ESNet_D_(ESKort*100)_D_ESGrOr_D_(ROG*100)_D_VHGrOr_D_APrijs_D_(VHKort*100)_D_VHGrOr_D_DiffPr_D_BPrijs_D_AMenge_D_BMenge_D_IsBPr_D_$S(FromStat:"S",1:BNP)_D_BNet_D_BKort_D_BGrOr_D_StatVal_D_Com_D_(VGLNet'=ESNet)
 Set R=R_D_$P(VHPRec,D,1)_D_$P(VHPRec,D,3)
 Set $P(R,D,26)=$G(KLRef)
 ;Set:IsNet R=D_IDNr_D_KortT_D_ESNet_D_ESKort_D_ESGrOr_D_ROG_D_VHProd_D_ANet_D_VHKort_D_VHGrOr_D_DiffPr_D_BNet_D_AMenge_D_BMenge_D_IsBPr_D_BNP_D_D_D_BLKLNr
 Set ^HULP(%J,$S(BLKLNr=212250:"",1:BLKLNr)_"   "," "," ",KortT,IDNr_" ")=R
 If DiffPr!$L(Exist) Do
 .Set R=""
 .If $L(Exist) Do  
 ..Set $P(R,D,2)="Bijvoegen"
 ..Set:Exist="N" $P(R,D,3)="NV of verwijderen Blum"
 ..Set:Exist="S" $P(R,D,3)="Blum of verwijderen NV"
 .Else  Do
 ..Set $P(R,D,2)="Verschil "
 ..If 'Exist,DiffPr=1 Do
 ...Set $P(R,D,3)="ES - P24 Bruto -->"
 ...Set:'IsBPr $P(R,D,9)=VGLBrut,$P(R,D,8)=VHGrOr
 ...Set:IsBPr $P(R,D,13)=VGLBrut,$P(R,D,11)=VHGrOr,$P(R,D,16)=1
 ..If 'Exist,DiffPr=2 Do
 ...Set:BNP="N" $P(R,D,3)="netto -->",$P(R,D,4)=OldNet,$P(R,D,6)=ESGrOr
 ...If BNP="B" Do
 ....Set $P(R,D,3)="bruto & korting -->"
 ....Set $P(R,D,5)=OldKort*100
 ....Set:'IsBPr $P(R,D,9)=OldBrut,$P(R,D,8)=VHGrOr
 ....Set:IsBPr $P(R,D,13)=OldBrut,$P(R,D,11)=VHGrOr,$P(R,D,16)=1
 .Set ^HULP(%J,$S(BLKLNr=212250:"",1:BLKLNr)_"   "," "," ",KortT,IDNr_"~")=R
 Quit
 ;
LKLANT New DL,List,IsNet
 Do INIT^PROC("BLPUTZK","List")
 Set List(10)="CB^BLPUTZ2"
 Set List(2,1)="4;C;L;;;;""1"""
 ;Set List(2,1)="1;C;L;6;; ;""1""\2;C;L;;;  *  ;""1""\4;C;L;;;;""1"""
 Do RENUMBER
 Set BLKLNr="-1"
 Do ^OUTPUT("","-","S")
 Quit
 
LINTERN New DL,List,IsNet
 Do INIT^PROC("BLPUTZI","List")
 Set List(10)="CB^BLPUTZ2"
 Set List(2,1)="4;C;L;;;;""1"""
 ;Set List(2,1)="1;C;L;6;; ;""1""\2;C;L;;;  *  ;""1""\4;C;L;;;;""1"""
 Do RENUMBER
 Set BLKLNr="-1"
 Do ^OUTPUT("","-","S")
 Quit
 
CB(Ref) Quit:Ref?1U ""
 Set FL(3,1)=""
 If $P(@Ref,D) Do  Quit "PB\;1\BL;1"
 .Set IsNet=$P(@Ref,D,3)
 .Set BLKLNr=$P(@Ref,D)
 .Set:TypeList="K" sTitel="Prijslijst"_D_BLKLNr_" "_$P(^BLBeri("K",BLKLNr),D)
 .Set:TypeList'="K" sTitel="Externe specificaties"_D_$S(TypeList="V":"Verschillen",NoSa="RP":"Normaal (Blum)",1:"Schaduw (NV)")_D_BLKLNr_" "_$P(^BLBeri("K",BLKLNr),D)
 .Set Print("BLZ")=0
 Quit ""
 
COMMIS(ROG,Bruto,Netto,ComMax) 
 New Prijs,Com,Check,Lim,Rec,BBruto
 If 'Bruto!'ROG Quit D_D
 Set Com=""
 Set BBruto=Bruto
 Set Prijs=Bruto*(1-ROG)*.9998
 If 'Com,Netto>Prijs  Set Com=1,Lim=0
 Set Prijs=Bruto*(1-ROG)*(1-.0375)*.9998
 If 'Com,Netto>Prijs  Set Com=.8,Lim=ROG
 Set Prijs=Bruto*(1-ROG)*(1-.075)*.9998
 If 'Com,Netto>Prijs  Set Com=.6,Lim=(1-(1-ROG*(1-.0375)))
 Set:'Com Com=.4,Lim=(1-(1-ROG*(1-.075)))
 Set Com=ComMax*Com
 Set Rec=Com_D_Lim
 If BBruto'=Bruto,Lim Do  ; Recalc naar BPrijs
 .Set Prijs=Bruto*(1-Lim),Lim=Prijs/BBruto-1 
 Set Check=0
 If Lim Do  ; Nakijken of dat limiet interressant is 
 .Set Prijs=Bruto*(1-Lim)*(1-(Com+1/100))
 .Set Netto=Netto*(1-(Com/100))
 .Set Check=Prijs<Netto
 Quit Rec_D_Check
 
STAT(BLKLNr,IDNr,BM,EM) 
 New Qty,Val
 Set (Qty,Val)=0
 Set $E(IDNr)=0
 For  Set BM=$O(^BLStat("D",BLKLNr,IDNr,BM)) Quit:BM=""!(BM>EM)  Do
 .Set Qty=Qty+$P(^(BM),D)
 .Set Val=Val+$P(^(BM),D,2)
 Quit Qty_D_Val
 
RENUMBER 
 New Count,HoofdGr,Groep,SubGroep,IDNr,KortT
 Set Count=0,HoofdGr=""
 For  Set HoofdGr=$O(^HULP(%J,HoofdGr)) Quit:HoofdGr=""  Do
 .Set Groep=""
 .For  Set Groep=$O(^HULP(%J,HoofdGr,Groep)) Quit:Groep=""  Do
 ..Set SubGroep=""
 ..For  Set SubGroep=$O(^HULP(%J,HoofdGr,Groep,SubGroep)) Quit:SubGroep=""  Do
 ...Set KortT=""
 ...For  Set KortT=$O(^HULP(%J,HoofdGr,Groep,SubGroep,KortT)) Quit:KortT=""  Do
 ....Set IDNr=""
 ....For  Set IDNr=$O(^HULP(%J,HoofdGr,Groep,SubGroep,KortT,IDNr)) Quit:IDNr=""  Do
 .....Set R=^HULP(%J,HoofdGr,Groep,SubGroep,KortT,IDNr) Kill ^(IDNr)
 .....Set Count=Count+1,^HULP(%J,Count)=R