CEUR ; Conversie naar Euro ;[ 10/31/2001  2:27 PM ]
 Quit
 ;
ONECUST(KLNr) 
 Set KLNr=$G(KLNr) Set:'KLNr KLNr=$$SELECT^KLANT6()
 Do:KLNr ONECUST^CEURKL(KLNr,,,,,1)
 Quit
 ;
BEDRAG(Bedrag,FromMunt,ToMunt,Decimals) 
 Set Decimals=$G(Decimals,4)
 Set:Bedrag Bedrag=$J($$MUNT^vhRtn1(FromMunt,5,Bedrag,,ToMunt),0,Decimals)
 Quit Bedrag
 ;
ERRLOG(Prog,ZR) 
 New Rec,Next
 Set Rec=@ZR,Next=$O(^CEURERR(Prog,""),-1)+1,^CEURERR(Prog,Next)=ZR_"="""_Rec_""""
 Quit
 ;
TXTPOP(Txt,NoBut) 
 New R,Btn
 Set Btn(1)="Ja&1",Btn(2)="Neen&*"
 Set R=$$WILD^vhTXTPOP("C;C","","Txt",$S($G(NoBut):"",1:"Btn"),2)
 Quit R
 ;
COMPRESS(Global) 
 ;-Deze routine mag niet worden uitgevoerd
 ; omdat dit geen oplossing bregt voor DKRES
 ;-INT^OLC neemt eerst een copy van Global in ^UTILITY($J)
 ; zodat het bij grote bestanden niet mogelijk is om te compresseren
 ;New Vol,UCI,Compr
 ;Write ?52,"Compressie -> "
 ;Set Vol=$P($ZU(5),",",2),Uci=$P($ZU(5),",")
 ;Do M^vhSW
 ;Set Compr=$$INT^OLC(Vol,Uci,Global)
 ;Do L^vhSW
 ;Write ?66,$S('Compr:"Ok",1:"Not Ok"),?74,"Job ",$P(Compr,",",2)
 Quit
 ;
RUNNR ;SEN,ATN,DATM,CHK,BA,PORT,PR,PRO,KLAS,SPW,BON,FA,FAP,COFA,STKL,STPR,KAAR,LKAN,MBST,KOV,HAD
RUN 
 New I,R,Routine,Run,RunNr,Txt,Start
 Do STORE^vhTERMINA()
 Set Start=$H,Txt(1)="Wenst u de Van Hoecke Euro conversie door te voeren?"
 Do:$$TXTPOP(.Txt)
 .Do ZWINT^vhRtn2(1)
 .Kill ^CEURERR
 .Set Routine="CEUR"
 .For  Set Routine=$O(^$ROUTINE(Routine)) Quit:$E(Routine,1,4)'="CEUR"  Do
 ..Xecute "Set Run=$T(RUN^"_Routine_")"
 ..Quit:Run=""
 ..Set RunNr=0
 ..For I=1:1 Quit:$P($P($T(RUNNR),";",2),",",I)=""  If $P($P($T(RUNNR),";",2),",",I)=$E(Routine,5,99) Set RunNr=I Quit
 ..Set:'RunNr RunNr=999 Set Routine(RunNr,Routine)=""
 .Set RunNr=""
 .For  Set RunNr=$O(Routine(RunNr)) Quit:'RunNr  Do
 ..Set Routine=""
 ..For  Set Routine=$O(Routine(RunNr,Routine)) Quit:Routine=""  Do
 ...Do @("RUN^"_Routine_"(0)")
 .Set Txt(1)="De Van Hoecke Euro conversie is doorgevoerd"
 .Set Txt(2)=""
 .Set Txt(3)="Begin : "_$$EXTTIME^vhDTyp(Start)
 .Set Txt(4)="Einde : "_$$EXTTIME^vhDTyp()
 .Set R=$$TXTPOP(.Txt,1)
 .Do ZWINT^vhRtn2(0)
 Do REFRESH^vhTERMINA()
 Quit
 ;
DOCNR ;SEN,ATN,DATM,CHK,BA,PORT,PR,PRO,KLAS,SPW,BON,FA,FAP,COFA,STKL,STPR,KAAR,LKAN,MBST,KOV,HAD
DOC 
 New I,Routine,Doc,DocNr
 Set Routine="CEUR"
 For  Set Routine=$O(^$ROUTINE(Routine)) Quit:$E(Routine,1,4)'="CEUR"  Do
 .Xecute "Set Doc=$T(DOC^"_Routine_")"
 .Quit:Doc=""
 .Set DocNr=0
 .For I=1:1 Quit:$P($P($T(DOCNR),";",2),",",I)=""  If $P($P($T(DOCNR),";",2),",",I)=$E(Routine,5,99) Set DocNr=I Quit
 .Set:'DocNr DocNr=999 Set Routine(DocNr,Routine)=""
 Set DocNr=""
 For  Set DocNr=$O(Routine(DocNr)) Quit:'DocNr  Do
 .Set Routine=""
 .For  Set Routine=$O(Routine(DocNr,Routine)) Quit:Routine=""  Do
 ..Write !!
 ..Do @("DOC^"_Routine)
 ..Write #
 Quit
 ;
COPYCEUR 
 New ToUci,ToVol,Routine
 Set ToUci="LVH",ToVol=$S($P($ZU(5),",",2)="EUR":"DEV",1:"EUR")
 Write !,"Copy to ",ToUci,",",ToVol,!!,"Merge globals"
 If ToVol="DEV" Do
 .For Global="DMA","DMC","DMH","DMM","DMS" Do
 ..Set ToGlobal=$$LOCASE^vhRtn1(Global)
 ..Write !?5,"^",Global," naar ^|""",ToUci,",",ToVol,"""|",ToGlobal
 ..Kill @("^|"""_ToUci_","_ToVol_"""|"_ToGlobal)
 ..Merge @("^|"""_ToUci_","_ToVol_"""|"_ToGlobal)=@("^"_Global)
 .Write !?5,"^cLOG naar ^|""",ToUci,",",ToVol,"""|cwlog"
 .Kill @("^|"""_ToUci_","_ToVol_"""|cwlog")
 .Merge @("^|"""_ToUci_","_ToVol_"""|cwlog")=^cLOG
 .Write !?5,"^KBA(""MENU"" naar ^|""",ToUci,",",ToVol,"""|kba(""MENU"""
 .Kill @("^|"""_ToUci_","_ToVol_"""|kba(""MENU"")")
 .Merge @("^|"""_ToUci_","_ToVol_"""|kba(""MENU"")")=^KBA("MENU")
 .Write !?5,"^DAMBA(""MENU"" naar ^|""",ToUci,",",ToVol,"""|DAMBA(""MENU"""
 .Kill @("^|"""_ToUci_","_ToVol_"""|DAMBA(""MENU"")")
 .Merge @("^|"""_ToUci_","_ToVol_"""|DAMBA(""MENU"")")=^DAMBA("MENU")
 .Write !?5,"^HULP(""EURO"" naar ^|""",ToUci,",",ToVol,"""|HULP(""EURO"""
 .Kill @("^|"""_ToUci_","_ToVol_"""|HULP(""EURO"")")
 .Merge @("^|"""_ToUci_","_ToVol_"""|HULP(""EURO"")")=^HULP("EURO")
 Else  Do
 .For Global="dma","dmc","dmh","dmm","dms" Do
 ..Set ToGlobal=$$UPCASE^vhRtn1(Global)
 ..Write !?5,"^",Global," naar ^|""",ToUci,",",ToVol,"""|",ToGlobal
 ..Kill @("^|"""_ToUci_","_ToVol_"""|"_ToGlobal)
 ..Merge @("^|"""_ToUci_","_ToVol_"""|"_ToGlobal)=@("^"_Global)
 .Write !?5,"^cwlog naar ^|""MGR,",ToVol,"""|%LOG"
 .Kill @("^|""MGR,"_ToVol_"""|%LOG")
 .Merge @("^|""MGR,"_ToVol_"""|%LOG")=^cwlog
 .Write !?5,"^kba(""MENU"" naar ^|""",ToUci,",",ToVol,"""|KBA(""MENU"""
 .Kill @("^|"""_ToUci_","_ToVol_"""|KBA(""MENU"")")
 .Merge @("^|"""_ToUci_","_ToVol_"""|KBA(""MENU"")")=^kba("MENU")
 .Write !?5,"^DAMBA(""MENU"" naar ^|""",ToUci,",",ToVol,"""|DAMBA(""MENU"""
 .Kill @("^|"""_ToUci_","_ToVol_"""|DAMBA(""MENU"")")
 .Merge @("^|"""_ToUci_","_ToVol_"""|DAMBA(""MENU"")")=^DAMBA("MENU")
 .Write !?5,"^HULP(""EURO"" naar ^|""",ToUci,",",ToVol,"""|HULP(""EURO"""
 .Kill @("^|"""_ToUci_","_ToVol_"""|HULP(""EURO"")")
 .Merge @("^|"""_ToUci_","_ToVol_"""|HULP(""EURO"")")=^HULP("EURO")
 Write !!,"Copy routines"
 Set Routine=$O(^$ROUTINE("CEUR"),-1)
 For  Set Routine=$O(^$ROUTINE(Routine)) Quit:$E(Routine,1,4)'="CEUR"  Do
 .Write !?5,Routine
 .Do c^cR(Routine,ToUci,ToVol,1)
 Quit
 ;