CEURKLAS ; Conversie produktklassifikatie naar Euro ;[ 05/17/2001  10:34 AM ]
 Quit
 ;
T1 ;Wenst u de produktklassifikatie naar Euro te converteren?
T2 ;Conversie produktklassifikatie naar Euro (^KPGR1)
 ;
RUN(TxtPop) 
 New (TxtPop)
 Do
 .New TxtPop
 .Do INIT^vhTERMINA
 Set TxtPop=$G(TxtPop,1),Run=1
 Do:TxtPop
 .Write @F11,@F1
 .Set Txt(1)=$P($T(T1),";",2),Run=$$TXTPOP^CEUR(.Txt)
 Do:Run
 .Write !,$ZN,?10,$P($T(T2),";",2)
 .Kill ^CEURERR($ZN)
 .Do CONVGRP
 Quit
 ;
CONVGRP 
 New I,R,Groep,FromMunt,ToMunt
 Set FromMunt="BEF",ToMunt="EUR"
 Set Groep=""
 For  Set Groep=$O(^KPGR1(Groep)) Quit:Groep=""  Do
 .Set R=^KPGR1(Groep)
 .For I=4 Set $P(R,D,I)=$$BEDRAG^CEUR($P(R,D,I),FromMunt,ToMunt,2)
 .Set ^KPGR1(Groep)=R
 Quit
 ;
DOC 
 ;Conversie produktklassifikatie
 ;
 ;
 ;Routine: RUN^CEURFA()
 ;
 ;
 ;Geconverteerde nodes:
 ;
 ;^KPGR1(Groep)
 ;  Veld 4 in BEF omrekenen naar EUR
 ;***
 New L,R
 Write !,$ZN,!
 For L=1:1 Set R=$T(DOC+L) Quit:R=""!($P(R,";",2)="***")  Do
 .If $E(R)=" " Write !?5,$P(R,";",2,99)
 .Else  Xecute $P(R,";")_$P(R,";",2,99)
 Quit
 ;